[gentoo-commits] gentoo-x86 commit in app-portage/layman: layman-2.1.0-r2.ebuild ChangeLog layman-2.1.0-r1.ebuild

[Devan Franchini (twitch153)]

twitch153    14/07/28 19:51:26

  Modified:             ChangeLog
  Added:                layman-2.1.0-r2.ebuild
  Removed:              layman-2.1.0-r1.ebuild
  Log:
  Removes asciidoc from DEPEND
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A8C8FBCF)

Revision  Changes    Path
1.201                app-portage/layman/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/layman/ChangeLog?rev=1.201&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/layman/ChangeLog?rev=1.201&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/layman/ChangeLog?r1=1.200&r2=1.201

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v
retrieving revision 1.200
retrieving revision 1.201
diff -u -r1.200 -r1.201
--- ChangeLog	27 Jul 2014 03:17:20 -0000	1.200
+++ ChangeLog	28 Jul 2014 19:51:26 -0000	1.201
@@ -1,6 +1,12 @@
 # ChangeLog for app-portage/layman
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.200 2014/07/27 03:17:20 twitch153 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.201 2014/07/28 19:51:26 twitch153 Exp $
+
+*layman-2.1.0-r2 (28 Jul 2014)
+
+  28 Jul 2014; Devan Franchini <twitch153@g.o> +layman-2.1.0-r2.ebuild,
+  -layman-2.1.0-r1.ebuild:
+  Removes asciidoc from DEPEND
 
 *layman-2.1.0-r1 (27 Jul 2014)
 



1.1                  app-portage/layman/layman-2.1.0-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/layman/layman-2.1.0-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/layman/layman-2.1.0-r2.ebuild?rev=1.1&content-type=text/plain

Index: layman-2.1.0-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/layman-2.1.0-r2.ebuild,v 1.1 2014/07/28 19:51:26 twitch153 Exp $

EAPI="5"

PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
PYTHON_REQ_USE="xml(+)"

inherit eutils distutils-r1 prefix

DESCRIPTION="Tool to manage Gentoo overlays"
HOMEPAGE="http://layman.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~s390 ~sh ~x86 ~ppc-aix ~x86-fbsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="bazaar cvs darcs +git mercurial subversion test"

DEPEND="test? ( dev-vcs/subversion )"

RDEPEND="
	bazaar? ( dev-vcs/bzr )
	cvs? ( dev-vcs/cvs )
	darcs? ( dev-vcs/darcs )
	git? ( dev-vcs/git )
	mercurial? ( dev-vcs/mercurial )
	subversion? (
		|| (
			>=dev-vcs/subversion-1.5.4[http]
			>=dev-vcs/subversion-1.5.4[webdav-neon]
			>=dev-vcs/subversion-1.5.4[webdav-serf]
		)
	)
	sys-apps/portage[${PYTHON_USEDEP}]
	>=dev-python/ssl-fetch-0.2[${PYTHON_USEDEP}]
	"

python_prepare_all()  {
	distutils-r1_python_prepare_all
	epatch "${FILESDIR}"/${P}-local_overlay.patch
	eprefixify etc/layman.cfg layman/config.py
}

python_test() {
	for suite in layman/tests/{dtest,external}.py ; do
		PYTHONPATH="." "${PYTHON}" ${suite} \
				|| die "test suite '${suite}' failed"
	done
}

python_install_all() {
	distutils-r1_python_install_all

	insinto /etc/layman
	doins etc/layman.cfg

	doman doc/layman.8
	dohtml doc/layman.8.html

	keepdir /var/lib/layman
	keepdir /etc/layman/overlays
}

pkg_postinst() {
	# now run layman's update utility
	einfo "Running layman-updater..."
	"${EROOT}"/usr/bin/layman-updater
	einfo
}