[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     cf85fccb5b812f5b75845c9dc795d755d55af3e3
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 22 02:56:38 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Apr 22 02:57:05 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cf85fccb

sys-kernel/gentoo-kernel-bin: bump to 5.10.32 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.10.32-r1.ebuild            | 114 +++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 789716dba27..2e82b574b0b 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -39,6 +39,7 @@ DIST gentoo-kernel-5.10.31-1.amd64.xpak 64337577 BLAKE2B 231e6cb5bc36bbf01f41295
 DIST gentoo-kernel-5.10.31-1.arm64.xpak 59338684 BLAKE2B 34ef0b745377ce5edfd0f00b4b0b492ecb14ff856861ca11ba9a7489af6040db0a4b8ed71430490572ecda375fe74c7d18cf872ad4b798799f78874d6c6b3997 SHA512 54a6937512f9eb7da74324a7d376be3d78ebb9293d401adabdec42ee67d236db6af9b124ab7ffef5833459ec92e5c93e574f2508233fc810af2d5017da00bca7
 DIST gentoo-kernel-5.10.31-1.x86.xpak 57256746 BLAKE2B 5c9c42e714f9b896ae2f01f602bb9409cfa210b6a75195de6ddc4213411f6e4ce86f2fd7279906360f4e33c517e1697412f7df8f3889c4e4498fe378430eba6a SHA512 04a18daa394cb2ac0cb4eddcfdad525a7d73861978e6212f152707207548561101fa0294461e43a9aeffe8f7533aebde7a13f26b46e6bd191e72a996d704bf5b
 DIST gentoo-kernel-5.10.32-1.amd64.xpak 65550906 BLAKE2B f03d5f538112a8c9628095f597264f2aebd996d9e1a62e11cb56e056e8452d718a8c7e99be835088ec38d5d863c66f296b157ad31a163f1a241f0a7d73c9aa5c SHA512 e04fc78b486ceb6e7eb26c5fccfd96d5eec16de2bcbf6f42a18725d7c1d034f0c48777ad1162b4bb9dcc031b1e781af9138233711c9bcf773714215835fc4194
+DIST gentoo-kernel-5.10.32-1.arm64.xpak 81378517 BLAKE2B 56cf9555f633da6df734902185f3c4359ee4600b1166df2fbb7327767f44523a1bb86b3022056e088fac52aba66b759626e369d637e60b693f69a04ed17f0a48 SHA512 c95226a747b29529a54e049952f9191067ee633fa94971187f89deb210055a0173c161c603ddcdafbad464dfdf34c0f126ea3f2627ed185de8295c62748cbda5
 DIST gentoo-kernel-5.10.32-1.x86.xpak 57243485 BLAKE2B 60cbb54acd5f311f1d79d997c1b030944cde923045d5f2a06fa3e260365ec1e820880129a052bf9c4e726d341e89bebb8983c240c2dd88aab74bfcf8ee5663f0 SHA512 2cc92d68c9d8622f55d11ebb6eb1364e3b626b0158745653e5430af21e4bfdce5697a94e30dd10d85103276021c4f3c0e1fe84fe03c44d66a37b96e81b61e9d2
 DIST gentoo-kernel-5.11.13-1.amd64.xpak 64685029 BLAKE2B 7d6794c5fd15434d2ad93d36678476e4a6aa3ad9ff77140a0bc8d74b0c87155898e8f1f76dfd40f72c878d9ddca7b7f1a9f0d4be2a600c5e2c18a77a3439e9d5 SHA512 d8c0fb975ee35e6d71b3b255800179805c9e70bfa7ef5299a38145c6cfd4f60720281c70f2d16a409a10c4ee6c6f26ac2e0c3151b114ced91c747371b59885b0
 DIST gentoo-kernel-5.11.13-1.arm64.xpak 59816443 BLAKE2B f3bd4b929cd103f95b91f0c0f28f324f8e316e1cc4b310742d159b8dbdb6c288d9424984e0859873924ac7eb34f12278b2086ad48fbf11da955f0b390dfda619 SHA512 6aae6cd29857eb897a167e359f9628692803bb75a0a1f235468a1b95e9c2f3d9525f33d6673b5c12edb5d9feba29210a79d8030d151a5b7260119a81eef57e1d

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.32-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.32-r1.ebuild
new file mode 100644
index 00000000000..8198cf5ace0
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.32-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}