[gentoo-commits] repo/gentoo:master commit in: dev-python/mypy/

[Michał Górny]

commit:     da5279e4c7e418a436490b45e89878db1699613a
Author:     Matoro Mahri <matoro <AT> users <DOT> noreply <DOT> github <DOT> com>
AuthorDate: Mon Sep 26 22:38:03 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Sep 27 02:03:47 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=da5279e4

dev-python/mypy: add 0.981

Closes: https://bugs.gentoo.org/854462
Signed-off-by: Matoro Mahri <matoro <AT> users.noreply.github.com>
Closes: https://github.com/gentoo/gentoo/pull/27485
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/mypy/Manifest          |  1 +
 dev-python/mypy/mypy-0.981.ebuild | 63 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/dev-python/mypy/Manifest b/dev-python/mypy/Manifest
index f119a4becb2e..db2969f375c3 100644
--- a/dev-python/mypy/Manifest
+++ b/dev-python/mypy/Manifest
@@ -1 +1,2 @@
 DIST mypy-0.971.gh.tar.gz 2808674 BLAKE2B 7f3b183a4c5342ddfc501b8091c078ac55803db86d43042220e18e3e616664ce91ddeb341b45b1d80c7686f8c2f3606af074a5dcb9c9eaacd6307578d3689981 SHA512 5088efbd74385b5a8c155ae6e756deed274bf3e597df13e57970a29c029c34c91453c45fc1d2d03b7d83cd786b8930a387a781e1b9cb72102c1f07263a346c6d
+DIST mypy-0.981.gh.tar.gz 2628442 BLAKE2B 484ba2da1e3c8988ce4bfa7681592b6ca4f409ca9078319428e11407fa2dec38deace41e77278bab835eee1e3690d8bf213c44ecb82ac5e9a5f759b030df93fe SHA512 8deb66e48b74c50027fd95533935fa6643beaa30b28d25c5783645f9efaedf6138379c262a91abbca62c6e269677f0ee1325fe93ea48d587f1aae8eec21eb15e

diff --git a/dev-python/mypy/mypy-0.981.ebuild b/dev-python/mypy/mypy-0.981.ebuild
new file mode 100644
index 000000000000..75044659afd0
--- /dev/null
+++ b/dev-python/mypy/mypy-0.981.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Optional static typing for Python"
+HOMEPAGE="
+	http://www.mypy-lang.org/
+	https://github.com/python/mypy/
+	https://pypi.org/project/mypy/
+"
+SRC_URI="
+	https://github.com/python/mypy/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# stubgen collides with this package: https://bugs.gentoo.org/585594
+RDEPEND="
+	!dev-util/stubgen
+	>=dev-python/psutil-4[${PYTHON_USEDEP}]
+	>=dev-python/typed-ast-1.4.0[${PYTHON_USEDEP}]
+	<dev-python/typed-ast-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.7.4[${PYTHON_USEDEP}]
+	>=dev-python/mypy_extensions-0.4.3[${PYTHON_USEDEP}]
+	<dev-python/mypy_extensions-0.5.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+"
+BDEPEND="
+	test? (
+		>=dev-python/attrs-18.0[${PYTHON_USEDEP}]
+		>=dev-python/filelock-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/lxml-4.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-1.18[${PYTHON_USEDEP}]
+		>=dev-python/py-1.5.2[${PYTHON_USEDEP}]
+		>=dev-python/typed-ast-1.4.0[${PYTHON_USEDEP}]
+		>=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	dev-python/furo
+distutils_enable_tests pytest
+
+# this requires packaging a lot of type stubs
+export MYPY_USE_MYPYC=0
+
+python_test() {
+	# Some mypy/test/testcmdline.py::PythonCmdlineSuite tests
+	# fail with high COLUMNS values
+	local -x COLUMNS=80
+	epytest -n "$(makeopts_jobs)"
+}