[gentoo-commits] gentoo-x86 commit in net-fs/cvmfs: cvmfs-9999.ebuild cvmfs-2.1.17.ebuild ChangeLog

[Sebastien Fabbro (bicatali)]

bicatali    14/02/05 18:00:36

  Modified:             cvmfs-9999.ebuild ChangeLog
  Added:                cvmfs-2.1.17.ebuild
  Log:
  Version bump, changed repository and branch to upstream for live ebuild
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

Revision  Changes    Path
1.3                  net-fs/cvmfs/cvmfs-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/cvmfs-9999.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/cvmfs-9999.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/cvmfs-9999.ebuild?r1=1.2&r2=1.3

Index: cvmfs-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/cvmfs/cvmfs-9999.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- cvmfs-9999.ebuild	2 Dec 2013 05:20:52 -0000	1.2
+++ cvmfs-9999.ebuild	5 Feb 2014 18:00:36 -0000	1.3
@@ -1,11 +1,12 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/cvmfs/cvmfs-9999.ebuild,v 1.2 2013/12/02 05:20:52 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/cvmfs/cvmfs-9999.ebuild,v 1.3 2014/02/05 18:00:36 bicatali Exp $
 
 EAPI=5
 
 #if LIVE
-EGIT_REPO_URI="https://github.com/sfabbro/cvmfs.git"
+EGIT_REPO_URI="https://github.com/cvmfs/cvmfs.git"
+EGIT_BRANCH="devel"
 inherit git-r3
 #endif
 
@@ -27,7 +28,7 @@
 	dev-libs/openssl
 	net-libs/pacparser
 	net-misc/curl[adns]
-	sys-libs/attr
+	sys-apps/attr
 	sys-libs/zlib
 	client? (
 		dev-cpp/sparsehash



1.10                 net-fs/cvmfs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/cvmfs/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	2 Dec 2013 05:20:52 -0000	1.9
+++ ChangeLog	5 Feb 2014 18:00:36 -0000	1.10
@@ -1,6 +1,12 @@
 # ChangeLog for net-fs/cvmfs
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/cvmfs/ChangeLog,v 1.9 2013/12/02 05:20:52 patrick Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-fs/cvmfs/ChangeLog,v 1.10 2014/02/05 18:00:36 bicatali Exp $
+
+*cvmfs-2.1.17 (05 Feb 2014)
+
+  05 Feb 2014; Sébastien Fabbro <bicatali@g.o> +cvmfs-2.1.17.ebuild,
+  cvmfs-9999.ebuild:
+  Version bump, changed repository and branch to upstream for live ebuild
 
   02 Dec 2013; Patrick Lauer <patrick@g.o> cvmfs-9999.ebuild:
   Whitespace



1.1                  net-fs/cvmfs/cvmfs-2.1.17.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/cvmfs-2.1.17.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/cvmfs/cvmfs-2.1.17.ebuild?rev=1.1&content-type=text/plain

Index: cvmfs-2.1.17.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/cvmfs/cvmfs-2.1.17.ebuild,v 1.1 2014/02/05 18:00:36 bicatali Exp $

EAPI=5

inherit cmake-utils

DESCRIPTION="HTTP read-only file system for distributing software"
HOMEPAGE="http://cernvm.cern.ch/portal/filesystem"
SRC_URI="https://ecsft.cern.ch/dist/${PN}/${P}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"

KEYWORDS="~amd64 ~x86"
IUSE="+client debug doc test server"

CDEPEND="
	dev-cpp/gtest
	dev-db/sqlite:3
	dev-libs/openssl
	net-libs/pacparser
	net-misc/curl[adns]
	sys-apps/attr
	sys-libs/zlib
	client? (
		dev-cpp/sparsehash
		dev-libs/leveldb
		sys-fs/fuse )
	server? ( >=dev-cpp/tbb-4.2 )"

RDEPEND="${CDEPEND}
	client? ( net-fs/autofs )
	server? ( www-servers/apache[ssl] )"

DEPEND="${CDEPEND}
	virtual/pkgconfig
	doc? ( app-doc/doxygen[dot] )"

src_prepare() {
	sed -i -e 's/COPYING//' CMakeLists.txt || die
	rm bootstrap.sh || die
	sed -i \
		-e "s:cvmfs-\${CernVM-FS_VERSION_STRING}:${PF}:" \
		CMakeLists.txt || die
	# hack for bundled vjson
	# vjson not worth unbundling, already upstream obsolete
	# upstream replaced by gason with a new api
	if use server; then
		sed -i \
			-e 's/g++/$(CXX)/g' \
			-e 's/-O2/$(CXXFLAGS)/g' \
			-e 's/ar/$(AR)/' \
			-e 's/ranlib/$(RANLIB)/' \
			externals/vjson/src/Makefile || die
		mkdir -p "${S}_build"/externals/build_vjson
		cp externals/vjson/src/* "${S}_build"/externals/build_vjson/ || die
	fi
	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DGOOGLETEST_BUILTIN=OFF
		-DLEVELDB_BUILTIN=OFF
		-DLIBCURL_BUILTIN=OFF
		-DPACPARSER_BUILTIN=OFF
		-DSPARSEHASH_BUILTIN=OFF
		-DSQLITE3_BUILTIN=OFF
		-DTBB_PRIVATE_LIB=OFF
		-DZLIB_BUILTIN=OFF
		$(cmake-utils_use debug BUILD_SERVER_DEBUG)
		$(cmake-utils_use server BUILD_SERVER)
		$(cmake-utils_use client BUILD_CVMFS)
		$(cmake-utils_use client BUILD_LIBCVMFS)
		$(cmake-utils_use client INSTALL_MOUNT_SCRIPTS)
		$(cmake-utils_use test BUILD_UNITTESTS)
	)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
	if use doc; then
		cd doc
		doxygen cvmfs.doxy || die
	fi
}

src_install() {
	cmake-utils_src_install
	use doc && dohtml -r doc/html/*
}

pkg_config() {
	if use client; then
		einfo "Setting up CernVM-FS client"
		cvmfs_config setup
		einfo "Now edit ${EROOT%/}/etc/cvmfs/default.local and run"
		einfo "  ${EROOT%/}/usr/init.d/autofs restart"
	fi
}