[gentoo-commits] repo/gentoo:master commit in: net-misc/tinc/

[Yixun Lan]

commit:     6f5a5037d151c93b9a7f36255d1d4917d7045dba
Author:     Yixun Lan <dlan <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 29 08:49:48 2016 +0000
Commit:     Yixun Lan <dlan <AT> gentoo <DOT> org>
CommitDate: Tue Nov 29 09:26:21 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6f5a5037

net-misc/tinc: version bump

bump 1.0.30, also update 1.1 upstream patch set

Package-Manager: portage-2.3.2

 net-misc/tinc/Manifest                 |  2 +
 net-misc/tinc/tinc-1.0.30.ebuild       | 48 +++++++++++++++++
 net-misc/tinc/tinc-1.1_pre14-r3.ebuild | 98 ++++++++++++++++++++++++++++++++++
 3 files changed, 148 insertions(+)

diff --git a/net-misc/tinc/Manifest b/net-misc/tinc/Manifest
index 7e5870b..3df5f02 100644
--- a/net-misc/tinc/Manifest
+++ b/net-misc/tinc/Manifest
@@ -1,4 +1,6 @@
 DIST tinc-1.0.28.tar.gz 488837 SHA256 0b502699360f09ce2128a39cf02abca07bfc699fc02ce829b3a90cf5e1e8b344 SHA512 b449f59e45b72a75271d54af1b9359f69040e81960533ca70d2a1f84b6bb913ffe1e6d11265eb1d11b5577855ed495898ef3c387d14268b159f352c8e754f5ec WHIRLPOOL 9558328fc01e9ef716330167c958bdfe45c12365dccdd3dc8c878a1dd122a0710d41e434a4ec0f5a54427b2b04fd7204f5225bef8c64ddd9fde7e6d800e7a996
 DIST tinc-1.0.29.tar.gz 493335 SHA256 0357017c6ffbbe1b2088c28fa684d2b119afa1086f363c503d06e8f6faa72a78 SHA512 230f3ff4c86d9ebed6e350f3ec92e931d83f94e6b9c4821bec745dddc2d33997e776bf3cd2a8b9e261b2f0b2df2ed8b5406bfa40bae08696304f650de9f34ef3 WHIRLPOOL 9825337a4622bd9461c027767e701b3934ef422beb10a06b801e005549b7b2ff944d4609591667efc994d14b002db937658209a8eb9f363a868373ebfdd0603e
+DIST tinc-1.0.30.tar.gz 494699 SHA256 abc17e25afc1b9e74423c78fef586b11d503cbbbe5e4a2ed323870f4a82faa73 SHA512 2e98658eeb77ceaf2973f3b77cac0c31beecd1382dc6976461da55cf22e27469d30cf6b35d5b3ce489a1809f38e82635b24a86956d62ef34e28ec43b8d09d1e6 WHIRLPOOL bd37aa99b915e6075b0ec95589f11c3f63a6d6600b566c855735bda8312a0a7957224e4f11a6fb897308b540dd5a9ccd10a13d1d07d11a51200bbf833c823b5f
 DIST tinc-1.1-upstream-patches-0.tar.xz 14936 SHA256 9a95897e50da8c213d80d024910bf8622c838ec2ef2fd23b48a7fc448ffa67e1 SHA512 c8a4ab62f9fbb6259af0fd621bfdcf6505f553478e70ef3aacf0c7c35c5070458246786f416ac8631d7f9e36ab764ea4250c6cb3e95aa8d1fee7e995d07a2d9d WHIRLPOOL e708ef24b532be48e2824cb18685aeb80c8e1053e44aaa3e82ce29ae6055abcc04fe1ebab0758d008ed5880f4d5b19e9b06b8eebfae9904cfa2b04dfee4a3d77
+DIST tinc-1.1-upstream-patches-1.tar.xz 17316 SHA256 2358b51678381a76ccc283eb04f14ad1ec426bbf2703d73f566f94dc52d17a9c SHA512 db71787e2edbfa8ca6288818536a36ee8fa158b400639ca9650d2d17a66b3968ab36d088e6dcbbf9524f3322166254ad1aad87db78b00dc64e0dc2a49ea7b44f WHIRLPOOL ed28917111cd0553ef75048c2b48b0499559e5a6ace77f49efb7d6d15743ba0d426477eeed9364bea6fba6e434442cf17d71ffb224acdd7da3b49792ff59bc09
 DIST tinc-1.1pre14.tar.gz 696109 SHA256 e349e78f0e0d10899b8ab51c285bdb96c5ee322e847dfcf6ac9e21036286221f SHA512 dfc54a91fd40826b108e9cbae43da42462eb51bb7ad16ac040cb1b262b5510eb6884b1f1dbe0541a3b1631213f70cc678593d1ba51ebdf150c3f6968030b9291 WHIRLPOOL 63c8229c667e461ad20c118d233a2abfe598cc95698b8c83e5f8b598657ca298ea0cdc20432ab2d084fd4a06129a5884e91eb445f4c7204be3798d1fb4dec2f8

diff --git a/net-misc/tinc/tinc-1.0.30.ebuild b/net-misc/tinc/tinc-1.0.30.ebuild
new file mode 100644
index 00000000..19f1e15
--- /dev/null
+++ b/net-misc/tinc/tinc-1.0.30.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+inherit systemd
+
+DESCRIPTION="tinc is an easy to configure VPN implementation"
+HOMEPAGE="http://www.tinc-vpn.org/"
+SRC_URI="http://www.tinc-vpn.org/packages/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="libressl +lzo uml vde +zlib"
+
+DEPEND="
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	lzo? ( dev-libs/lzo:2 )
+	zlib? ( sys-libs/zlib )"
+RDEPEND="${DEPEND}
+	vde? ( net-misc/vde )"
+
+src_configure() {
+	econf \
+		--enable-jumbograms \
+		--disable-tunemu  \
+		$(use_enable lzo) \
+		$(use_enable uml) \
+		$(use_enable vde) \
+		$(use_enable zlib)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodir /etc/tinc
+	dodoc AUTHORS NEWS README THANKS
+	doconfd "${FILESDIR}"/tinc.networks
+	newconfd "${FILESDIR}"/tincd.conf tincd
+	newinitd "${FILESDIR}"/tincd-r1 tincd
+	systemd_newunit "${FILESDIR}"/tincd_at.service "tincd@.service"
+}
+
+pkg_postinst() {
+	elog "This package requires the tun/tap kernel device."
+	elog "Look at http://www.tinc-vpn.org/ for how to configure tinc"
+}

diff --git a/net-misc/tinc/tinc-1.1_pre14-r3.ebuild b/net-misc/tinc/tinc-1.1_pre14-r3.ebuild
new file mode 100644
index 00000000..7a427e4
--- /dev/null
+++ b/net-misc/tinc/tinc-1.1_pre14-r3.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+MY_PV=${PV/_/}
+MY_P=${PN}-${MY_PV}
+
+PYTHON_COMPAT=( python2_7 )
+inherit eutils multilib python-any-r1
+
+DESCRIPTION="tinc is an easy to configure VPN implementation"
+HOMEPAGE="http://www.tinc-vpn.org/"
+
+UPSTREAM_VER=1
+
+[[ -n ${UPSTREAM_VER} ]] && \
+	UPSTREAM_PATCHSET_URI="https://dev.gentoo.org/~dlan/distfiles/${PN}-1.1-upstream-patches-${UPSTREAM_VER}.tar.xz"
+
+SRC_URI="http://www.tinc-vpn.org/packages/${MY_P}.tar.gz
+	${UPSTREAM_PATCHSET_URI}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="+lzo +ncurses gui libressl +readline +ssl uml vde upnp +zlib"
+
+DEPEND="
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	lzo? ( dev-libs/lzo:2 )
+	ncurses? ( sys-libs/ncurses:= )
+	readline? ( sys-libs/readline:= )
+	upnp? ( net-libs/miniupnpc )
+	zlib? ( sys-libs/zlib )"
+RDEPEND="${DEPEND}
+	vde? ( net-misc/vde )
+	${PYTHON_DEPS}
+	gui? ( $(python_gen_any_dep '
+	dev-python/wxpython[${PYTHON_USEDEP}]
+	') )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	# Upstream's patchset
+	if [[ -n ${UPSTREAM_VER} ]]; then
+		einfo "Try to apply Tinc Upstream patch set"
+		EPATCH_SUFFIX="patch" \
+		EPATCH_FORCE="yes" \
+		EPATCH_OPTS="-p1" \
+			epatch "${WORKDIR}"/patches-upstream
+	fi
+
+	eapply "${FILESDIR}"/tinc-1.1-fix-paths.patch #560528
+	eapply_user
+}
+
+src_configure() {
+	econf \
+		--enable-jumbograms \
+		--disable-silent-rules \
+		--enable-legacy-protocol \
+		--disable-tunemu  \
+		--with-systemd=/usr/$(get_libdir)/systemd/system \
+		$(use_enable lzo) \
+		$(use_enable ncurses curses) \
+		$(use_enable readline) \
+		$(use_enable uml) \
+		$(use_enable vde) \
+		$(use_enable zlib) \
+		$(use_enable upnp miniupnpc) \
+		$(use_with ssl openssl)
+		#--without-libgcrypt \
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodir /etc/tinc
+	dodoc AUTHORS NEWS README THANKS
+	doconfd "${FILESDIR}"/tinc.networks
+	newconfd "${FILESDIR}"/tincd.conf tincd
+	newinitd "${FILESDIR}"/tincd-r2 tincd
+
+	if use gui; then
+		python_fix_shebang "${ED}"/usr/bin/tinc-gui
+	else
+		rm -f "${ED}"/usr/bin/tinc-gui || die
+	fi
+}
+
+pkg_postinst() {
+	elog "This package requires the tun/tap kernel device."
+	elog "Look at http://www.tinc-vpn.org/ for how to configure tinc"
+}