[gentoo-commits] gentoo-x86 commit in net-misc/owncloud-client: owncloud-client-1.6.3.ebuild ChangeLog

[Bernard Cafarelli (voyageur)]

voyageur    14/09/05 15:06:32

  Modified:             ChangeLog
  Added:                owncloud-client-1.6.3.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

Revision  Changes    Path
1.14                 net-misc/owncloud-client/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	5 Aug 2014 08:45:12 -0000	1.13
+++ ChangeLog	5 Sep 2014 15:06:32 -0000	1.14
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/owncloud-client
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/ChangeLog,v 1.13 2014/08/05 08:45:12 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/ChangeLog,v 1.14 2014/09/05 15:06:32 voyageur Exp $
+
+*owncloud-client-1.6.3 (05 Sep 2014)
+
+  05 Sep 2014; Bernard Cafarelli <voyageur@g.o>
+  +owncloud-client-1.6.3.ebuild:
+  Version bump
 
 *owncloud-client-1.6.2 (05 Aug 2014)
 



1.1                  net-misc/owncloud-client/owncloud-client-1.6.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/owncloud-client-1.6.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/owncloud-client/owncloud-client-1.6.3.ebuild?rev=1.1&content-type=text/plain

Index: owncloud-client-1.6.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/owncloud-client-1.6.3.ebuild,v 1.1 2014/09/05 15:06:32 voyageur Exp $

EAPI=5

inherit cmake-utils

MY_P="mirall-${PV/_/}"

DESCRIPTION="Synchronize files from ownCloud Server with your computer"
HOMEPAGE="http://owncloud.org/"
SRC_URI="http://download.owncloud.com/desktop/stable/${MY_P}.tar.bz2"

LICENSE="CC-BY-3.0 GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc samba +sftp test +qt4 qt5"

REQUIRED_USE="^^ ( qt4 qt5 )"

RDEPEND=">=dev-db/sqlite-3.4:3
	qt4? (
		dev-libs/qtkeychain[qt4]
		dev-qt/qtcore:4
		dev-qt/qtdbus:4
		dev-qt/qtgui:4
		dev-qt/qtsql:4
		dev-qt/qttest:4
		dev-qt/qtwebkit:4
	)
	qt5? (
		dev-libs/qtkeychain[qt5]
		dev-qt/linguist-tools
		dev-qt/qtcore:5
		dev-qt/qtdbus:5
		dev-qt/qtgui:5
		dev-qt/qtsql:5
		dev-qt/qttest:5
		dev-qt/qtwebkit:5[printsupport,widgets]
	)
	net-libs/neon[ssl]
	sys-fs/inotify-tools
	virtual/libiconv
	samba? ( >=net-fs/samba-3.5 )
	sftp? ( >=net-libs/libssh-0.5 )
	!net-misc/ocsync"
DEPEND="${RDEPEND}
	doc? (
		dev-python/sphinx
		dev-texlive/texlive-latexextra
		virtual/latex-base
	)
	test? ( dev-util/cmocka )"

S=${WORKDIR}/${MY_P}

src_configure() {
	local mycmakeargs=(
		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
		-DWITH_ICONV=ON
		$(cmake-utils_use_with doc DOC)
		$(cmake-utils_use test UNIT_TESTING)
		$(cmake-utils_use_find_package samba Libsmbclient)
		$(cmake-utils_use_find_package sftp LibSSH)
		$(cmake-utils_use_build qt4 WITH_QT4)
	)

	cmake-utils_src_configure
}

src_test() {
	# 1 test needs an existing ${HOME}/.config directory
	mkdir "${T}"/.config
	export HOME="${T}"
	cmake-utils_src_test
}

pkg_postinst() {
	if ! use doc ; then
		elog "Documentation and man pages not installed"
		elog "Enable doc USE-flag to generate them"
	fi
}