[gentoo-commits] gentoo-x86 commit in x11-libs/cairo: ChangeLog cairo-1.7.4.ebuild

[Doug Goldstein (cardoe)]

cardoe      08/08/28 13:43:41

  Modified:             ChangeLog
  Added:                cairo-1.7.4.ebuild
  Log:
  Add development snapshot that's masked
  (Portage version: 2.2_rc8/cvs/Linux 2.6.25-gentoo-r8 x86_64)

Revision  Changes    Path
1.192                x11-libs/cairo/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.192&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/cairo/ChangeLog?rev=1.192&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/cairo/ChangeLog?r1=1.191&r2=1.192

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v
retrieving revision 1.191
retrieving revision 1.192
diff -u -r1.191 -r1.192
--- ChangeLog	24 Aug 2008 21:01:45 -0000	1.191
+++ ChangeLog	28 Aug 2008 13:43:41 -0000	1.192
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/cairo
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.191 2008/08/24 21:01:45 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/ChangeLog,v 1.192 2008/08/28 13:43:41 cardoe Exp $
+
+*cairo-1.7.4 (28 Aug 2008)
+
+  28 Aug 2008; Doug Goldstein <cardoe@g.o> +cairo-1.7.4.ebuild:
+  Add development snapshot that's masked
 
   24 Aug 2008; Doug Goldstein <cardoe@g.o> metadata.xml:
   re-add opengl USE flag that was deleted



1.1                  x11-libs/cairo/cairo-1.7.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/cairo/cairo-1.7.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-libs/cairo/cairo-1.7.4.ebuild?rev=1.1&content-type=text/plain

Index: cairo-1.7.4.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/cairo/cairo-1.7.4.ebuild,v 1.1 2008/08/28 13:43:41 cardoe Exp $

inherit eutils flag-o-matic libtool

DESCRIPTION="A vector graphics library with cross-device output support"
HOMEPAGE="http://cairographics.org/"
SRC_URI="http://cairographics.org/snapshots/${P}.tar.gz"

LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug directfb doc glitz opengl svg test X xcb"

# Test causes a circular depend on gtk+... since gtk+ needs cairo but test needs gtk+ so we need to block it
RESTRICT="test"

RDEPEND="media-libs/fontconfig
		>=media-libs/freetype-2.1.9
		sys-libs/zlib
		media-libs/libpng
		>=x11-libs/pixman-0.10.0
		X?	(
				x11-libs/libXrender
				x11-libs/libXext
				x11-libs/libX11
				virtual/xft
				xcb? ( x11-libs/libxcb
						x11-libs/xcb-util )
			)
		directfb? ( >=dev-libs/DirectFB-0.9.24 )
		glitz? ( >=media-libs/glitz-0.5.1 )
		svg? ( dev-libs/libxml2 )"

DEPEND="${RDEPEND}
		>=dev-util/pkgconfig-0.19
		X? ( x11-proto/renderproto
			xcb? ( x11-proto/xcb-proto ) )
		doc?	(
					>=dev-util/gtk-doc-1.6
					 ~app-text/docbook-xml-dtd-4.2
				)"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# We need to run elibtoolize to ensure correct so versioning on FreeBSD
	elibtoolize
}

src_compile() {
	local use_xcb

	#gets rid of fbmmx.c inlining warnings
	append-flags -finline-limit=1200

	if use glitz && use opengl; then
		export glitz_LIBS=-lglitz-glx
	fi

	use_xcb="--disable-xcb"
	use X && use xcb && use_xcb="--enable-xcb"

	econf $(use_enable X xlib) $(use_enable doc gtk-doc) \
		$(use_enable directfb) ${use_xcb} \
		$(use_enable svg) $(use_enable glitz) $(use_enable X xlib-xrender) \
		$(use_enable debug test-surfaces) --enable-pdf  --enable-png \
		--enable-freetype --enable-ps \
		|| die "configure failed"

	emake || die "compile failed"
}

src_install() {
	make DESTDIR="${D}" install || die "Installation failed"
	dodoc AUTHORS ChangeLog NEWS README
}