[gentoo-commits] gentoo-x86 commit in net-misc/plowshare: metadata.xml ChangeLog plowshare-0.8-r2.ebuild plowshare-0.8-r1.ebuild

[Mounir Lamouri (volkmar)]

volkmar     09/09/29 18:15:28

  Modified:             metadata.xml ChangeLog
  Added:                plowshare-0.8-r2.ebuild
  Removed:              plowshare-0.8-r1.ebuild
  Log:
  Removing megaupload USE flag as python dep was deprecated.
  (Portage version: 14420-svn/cvs/Linux ppc)

Revision  Changes    Path
1.2                  net-misc/plowshare/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/plowshare/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	28 Sep 2009 00:04:04 -0000	1.1
+++ metadata.xml	29 Sep 2009 18:15:27 -0000	1.2
@@ -7,7 +7,6 @@
 		<name>Mounir Lamouri</name>
 	</maintainer>
 	<use>
-		<flag name="megaupload">Enable megaupload module</flag>
 		<flag name="view-captcha">View captcha with aview</flag>
 	</use>
 </pkgmetadata>



1.3                  net-misc/plowshare/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/plowshare/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	28 Sep 2009 19:50:39 -0000	1.2
+++ ChangeLog	29 Sep 2009 18:15:27 -0000	1.3
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/plowshare
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/plowshare/ChangeLog,v 1.2 2009/09/28 19:50:39 volkmar Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/plowshare/ChangeLog,v 1.3 2009/09/29 18:15:27 volkmar Exp $
+
+*plowshare-0.8-r2 (29 Sep 2009)
+
+  29 Sep 2009; Mounir Lamouri <volkmar@g.o> -plowshare-0.8-r1.ebuild,
+  +plowshare-0.8-r2.ebuild, metadata.xml:
+  Removing megaupload USE flag as python dep was deprecated.
 
 *plowshare-0.8-r1 (28 Sep 2009)
 



1.1                  net-misc/plowshare/plowshare-0.8-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/plowshare-0.8-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/plowshare/plowshare-0.8-r2.ebuild?rev=1.1&content-type=text/plain

Index: plowshare-0.8-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/plowshare/plowshare-0.8-r2.ebuild,v 1.1 2009/09/29 18:15:27 volkmar Exp $

EAPI="2"

DESCRIPTION="Command-line downloader and uploader for file-sharing websites"
HOMEPAGE="http://code.google.com/p/plowshare/"
SRC_URI="http://${PN}.googlecode.com/files/${P}.tgz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~ppc ~x86"
IUSE="+javascript view-captcha"

RDEPEND="
	javascript? ( dev-lang/spidermonkey )
	view-captcha? ( media-gfx/aview )
	app-shells/bash
	app-text/recode
	app-text/tesseract
	media-gfx/imagemagick[tiff]
	net-misc/curl
	sys-apps/util-linux"
DEPEND=""

# NOTES:
# dev-lang/spidermonkey is actually any javascript interpreter using /usr/bin/js

src_prepare() {
	if ! use javascript; then
		sed -i -e "s: mediafire::" src/upload.sh src/download.sh \
			|| die "sed failed"
		sed -i -e "s: zshare::" src/upload.sh src/download.sh \
			|| die "sed failed"
		rm src/modules/{mediafire,zshare}.sh
	fi

	# removing extras/ as it's now deprecated
	rm -r src/modules/extras/ || die "rm -r failed"
}

src_test() {
	./test/test_lib.sh || die "test failed"
}

src_install() {
	insinto /usr/share/${PN}
	doins src/lib.sh || die "doins failed"

	insinto /usr/share/${PN}/modules
	doins -r src/modules/* || die "doins failed"

	exeinto /usr/share/${PN}
	doexe src/{download,upload}.sh || die "doexe failed"

	dosym /usr/share/${PN}/download.sh /usr/bin/plowdown
	dosym /usr/share/${PN}/upload.sh /usr/bin/plowup

	dodoc CHANGELOG README || die "dodoc failed"
}

pkg_postinst() {
	if ! use javascript; then
		ewarn "Without javascript you will not be able to use zshare and mediafire"
	fi
}