[gentoo-commits] gentoo-x86 commit in sys-freebsd/freebsd-sources: freebsd-sources-7.1.ebuild ChangeLog

[Javier Villavicencio (the_paya)]

the_paya    09/01/22 21:05:47

  Modified:             ChangeLog
  Added:                freebsd-sources-7.1.ebuild
  Log:
  Import of the 7.1 ebuilds from gentoo-bsd overlay.
  (Portage version: 2.2_rc23/cvs/FreeBSD i386)

Revision  Changes    Path
1.45                 sys-freebsd/freebsd-sources/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-freebsd/freebsd-sources/ChangeLog?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-freebsd/freebsd-sources/ChangeLog?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-freebsd/freebsd-sources/ChangeLog?r1=1.44&r2=1.45

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-freebsd/freebsd-sources/ChangeLog,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- ChangeLog	8 Jan 2009 18:35:47 -0000	1.44
+++ ChangeLog	22 Jan 2009 21:05:47 -0000	1.45
@@ -1,6 +1,19 @@
 # ChangeLog for sys-freebsd/freebsd-sources
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-freebsd/freebsd-sources/ChangeLog,v 1.44 2009/01/08 18:35:47 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-freebsd/freebsd-sources/ChangeLog,v 1.45 2009/01/22 21:05:47 the_paya Exp $
+
+*freebsd-sources-7.1 (22 Jan 2009)
+
+  22 Jan 2009; Javier Villavicencio <the_paya@g.o>
+  +files/freebsd-sources-7.0-gentoo.patch,
+  +files/freebsd-sources-7.0-tmpfs_whiteout_stub.patch,
+  +files/freebsd-sources-7.0-werror.patch,
+  +files/freebsd-sources-7.1-asm.patch,
+  +files/freebsd-sources-7.1-binutils_link.patch,
+  +files/freebsd-sources-7.1-sparc64.patch,
+  +files/freebsd-sources-7.1-subnet-route-pr40133.patch,
+  +files/freebsd-sources-7.1-types.h-fix.patch, +freebsd-sources-7.1.ebuild:
+  Import 7.1 ebuilds from gentoo-bsd overlay.
 
 *freebsd-sources-6.2-r5 (08 Jan 2009)
 



1.1                  sys-freebsd/freebsd-sources/freebsd-sources-7.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-freebsd/freebsd-sources/freebsd-sources-7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-freebsd/freebsd-sources/freebsd-sources-7.1.ebuild?rev=1.1&content-type=text/plain

Index: freebsd-sources-7.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-freebsd/freebsd-sources/freebsd-sources-7.1.ebuild,v 1.1 2009/01/22 21:05:47 the_paya Exp $

inherit bsdmk freebsd flag-o-matic

DESCRIPTION="FreeBSD kernel sources"
SLOT="${PVR}"
KEYWORDS="~sparc-fbsd ~x86-fbsd"

IUSE="symlink"

SRC_URI="mirror://gentoo/${SYS}.tar.bz2"

RDEPEND=">=sys-freebsd/freebsd-mk-defs-7.0"
DEPEND=""

RESTRICT="strip binchecks"

S="${WORKDIR}/sys"

MY_PVR="${PVR}"

[[ ${MY_PVR} == "${RV}" ]] && MY_PVR="${MY_PVR}-r0"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# This replaces the gentoover patch, it doesn't need reapply every time.
	sed -i -e 's:^REVISION=.*:REVISION="'${PVR}'":' \
		-e 's:^BRANCH=.*:BRANCH="Gentoo":' \
		-e 's:^VERSION=.*:VERSION="${TYPE} ${BRANCH} ${REVISION}":' \
		"${S}/conf/newvers.sh"

	# __FreeBSD_cc_version comes from FreeBSD's gcc.
	# on 7.0-RELEASE it's 700003.
	sed -e "s:-D_KERNEL:-D_KERNEL -D__FreeBSD_cc_version=700004:g" \
		-i "${S}/conf/kern.pre.mk" \
		-i "${S}/conf/kmod.mk" || die "Couldn't set __FreeBSD_cc_version"

	epatch "${FILESDIR}/${PN}-7.0-gentoo.patch"
	epatch "${FILESDIR}/${PN}-6.0-flex-2.5.31.patch"
	epatch "${FILESDIR}/${PN}-7.1-asm.patch"
	epatch "${FILESDIR}/${PN}-7.0-werror.patch"
	epatch "${FILESDIR}/${PN}-7.1-sparc64.patch"
	epatch "${FILESDIR}/${PN}-6.1-ntfs.patch"
	epatch "${FILESDIR}/${PN}-6.2-debug-O2.patch"
	epatch "${FILESDIR}/${PN}-7.1-types.h-fix.patch"
	epatch "${FILESDIR}/${PN}-7.1-subnet-route-pr40133.patch"

	# http://security.freebsd.org/advisories/FreeBSD-SA-07:03.ipv6.asc
	# Why did the 6.2 patch apply almoast cleanly on 7.0?
	# Because the code was suppressed.
	#epatch "${FILESDIR}/${PN}-7.0-ipv6.patch"

	# Disable SSP for the kernel
	grep -Zlr -- -ffreestanding "${S}" | xargs -0 sed -i -e \
		"s:-ffreestanding:-ffreestanding $(test-flags -fno-stack-protector -fno-stack-protector-all):g"

	# By adding -DGENTOO_LIVECD to CFLAGS activate this stub
	# vop_whiteout to tmpfs, so it can be used as an overlay
	# unionfs filesystem over the cd9660 readonly filesystem.
	epatch "${FILESDIR}/${PN}-7.0-tmpfs_whiteout_stub.patch"

	# See http://sourceware.org/bugzilla/show_bug.cgi?id=5391
	# ld doesn't provide symbols constructed as the __start_set_(s) ones
	# are on FreeBSD modules.
	# This patch adds code to generate a list of these and adds them
	# as undefined references to ld's commandline to get them.
	# Without this kernel modules will not load.
	epatch "${FILESDIR}/${PN}-7.1-binutils_link.patch"
}

src_compile() {
	einfo "Nothing to compile.."
}

src_install() {
	insinto "/usr/src/sys-${MY_PVR}"
	doins -r "${S}/"*
}

pkg_postinst() {
	if [[ ! -L "${ROOT}/usr/src/sys" ]]; then
		einfo "/usr/src/sys symlink doesn't exist; creating symlink to sys-${MY_PVR}..."
		ln -sf "sys-${MY_PVR}" "${ROOT}/usr/src/sys" || \
			eerror "Couldn't create ${ROOT}/usr/src/sys symlink."
		# just in case...
		[[ -L ""${ROOT}/usr/src/sys-${RV}"" ]] && rm "${ROOT}/usr/src/sys-${RV}"
		ln -sf "sys-${MY_PVR}" "${ROOT}/usr/src/sys-${RV}" || \
			eerror "Couldn't create ${ROOT}/usr/src/sys-${RV} symlink."
	elif use symlink; then
		einfo "Updating /usr/src/sys symlink to sys-${MY_PVR}..."
		rm "${ROOT}/usr/src/sys" "${ROOT}/usr/src/sys-${RV}" || \
			eerror "Couldn't remove previous symlinks, please fix manually."
		ln -sf "sys-${MY_PVR}" "${ROOT}/usr/src/sys" || \
			eerror "Couldn't create ${ROOT}/usr/src/sys symlink."
		ln -sf "sys-${MY_PVR}" "${ROOT}/usr/src/sys-${RV}" || \
			eerror "Couldn't create ${ROOT}/usr/src/sys-${RV} symlink."
	fi

	if use sparc-fbsd ; then
		ewarn "WARNING: kldload currently causes kernel panics"
		ewarn "on sparc64. This is probably a gcc-4.1 issue, but"
		ewarn "we need gcc-4.1 to compile the kernel correctly :/"
		ewarn "Please compile all modules you need into the kernel"
	fi
}