[gentoo-commits] gentoo-x86 commit in media-gfx/tachyon: metadata.xml ChangeLog tachyon-0.98.9.ebuild

[Alexey Shvetsov (alexxy)]

alexxy      10/02/23 17:44:01

  Added:                metadata.xml ChangeLog tachyon-0.98.9.ebuild
  Log:
  [media-gfx/tachyon] Initial import per bug #293969
  (Portage version: 2.2_rc63/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  media-gfx/tachyon/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/tachyon/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/tachyon/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>sci</herd>
<maintainer>
  <email>alexxy@g.o</email>
</maintainer>
</pkgmetadata>



1.1                  media-gfx/tachyon/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/tachyon/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/tachyon/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for media-gfx/tachyon
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/tachyon/ChangeLog,v 1.1 2010/02/23 17:44:00 alexxy Exp $

*tachyon-0.98.9 (23 Feb 2010)

  23 Feb 2010; Alexey Shvetsov <alexxy@g.o> +tachyon-0.98.9.ebuild,
  +metadata.xml:
  Initial import per bug #293969




1.1                  media-gfx/tachyon/tachyon-0.98.9.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/tachyon/tachyon-0.98.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/tachyon/tachyon-0.98.9.ebuild?rev=1.1&content-type=text/plain

Index: tachyon-0.98.9.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/tachyon/tachyon-0.98.9.ebuild,v 1.1 2010/02/23 17:44:00 alexxy Exp $

EAPI=2

inherit eutils

DESCRIPTION="A portable, high performance parallel ray tracing system"
HOMEPAGE="http://jedi.ks.uiuc.edu/~johns/raytracer/"
SRC_URI="http://jedi.ks.uiuc.edu/~johns/raytracer/files/${PV}/${P}.tar.gz"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples jpeg mpi opengl png threads"

RESTRICT="mirror"

DEPEND="jpeg? ( media-libs/jpeg )
	mpi? ( virtual/mpi )
	opengl? ( virtual/opengl )
	png? ( media-libs/libpng )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${PN}/unix"

# TODO: Test on alpha, ia64, ppc
# TODO: MPI: Depend on lam or virtual ? Test MPI
# TODO: Check for threads dependencies
# TODO: add other architectures
# TODO: X, Motif, MBOX, Open Media Framework, Spaceball I/O, MGF ?

TACHYON_MAKE_TARGET=

pkg_setup() {
	if use threads ; then
		if use opengl ; then
			TACHYON_MAKE_TARGET=linux-thr-ogl
			if use mpi ; then
				eerror "tachyon does not support MPI with OpenGL and threads"
				die
			fi
		elif use mpi ; then
			TACHYON_MAKE_TARGET=linux-mpi-thr
		else
			TACHYON_MAKE_TARGET=linux-thr
		fi

		# TODO: Support for linux-athlon-thr ?
	else
		if use opengl ; then
			# TODO: Support target: linux-lam-64-ogl

			eerror "OpenGL is only available with USE=threads!"
		elif use mpi ; then
				TACHYON_MAKE_TARGET=linux-mpi
		else
			TACHYON_MAKE_TARGET=linux
		fi

		# TODO: Support for linux-p4, linux-athlon, linux-ps2 ?
	fi

	if [[ -z "${TACHYON_MAKE_TARGET}" ]]; then
		eerror "No target found, check use flags" && die
	else
		einfo "Using target: ${TACHYON_MAKE_TARGET}"
	fi
}

src_prepare() {
	if use jpeg ; then
		sed -i \
			-e "s:USEJPEG=:USEJPEG=-DUSEJPEG:g" \
			-e "s:JPEGLIB=:JPEGLIB=-ljpeg:g" Make-config \
			|| die "sed failed"
	fi

	if use png ; then
		sed -i \
			-e "s:USEPNG=:USEPNG=-DUSEPNG:g" \
			-e "s:PNGINC=:PNGINC=$(libpng-config --cflags):g" \
			-e "s:PNGLIB=:PNGLIB=$(libpng-config --ldflags):g" Make-config \
			|| die "sed failed"
	fi

	if use mpi ; then
		sed -i "s:MPIDIR=:MPIDIR=/usr:g" Make-config || die "sed failed"
		sed -i "s:linux-lam:linux-mpi:g" Make-config || die "sed failed"
	fi
	sed -i \
		-e "s:-O3::g;s:-g::g;s:-pg::g" \
		-e "s:-m32:${CFLAGS}:g" \
		-e "s:-m64:${CFLAGS}:g" \
		-e "s:-ffast-math::g" \
		-e "s:-fomit-frame-pointer::g" Make-arch || die "sed failed"
}

src_compile() {
	emake "${TACHYON_MAKE_TARGET}" || die "emake failed"
}

src_install() {
	cd ..
	dodoc Changes README

	if use doc ; then
		dohtml docs/tachyon/*
	fi

	cd "compile/${TACHYON_MAKE_TARGET}"

	dobin tachyon
	dolib libtachyon.a

	if use examples; then
		cd "${S}/../scenes"
		insinto "/usr/share/${PN}/examples"
		doins *
	fi
}