[gentoo-commits] gentoo-x86 commit in games-roguelike/crossfire-client: crossfire-client-1.70.0.ebuild ChangeLog

[Michael Sterrett (mr_bones_)]

mr_bones_    12/07/30 21:43:51

  Modified:             ChangeLog
  Added:                crossfire-client-1.70.0.ebuild
  Log:
  version bump (bug #410219)
  
  (Portage version: 2.1.10.65/cvs/Linux x86_64)

Revision  Changes    Path
1.29                 games-roguelike/crossfire-client/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/crossfire-client/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/crossfire-client/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/crossfire-client/ChangeLog?r1=1.28&r2=1.29

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-roguelike/crossfire-client/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog	2 May 2012 21:06:17 -0000	1.28
+++ ChangeLog	30 Jul 2012 21:43:51 -0000	1.29
@@ -1,6 +1,12 @@
 # ChangeLog for games-roguelike/crossfire-client
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-roguelike/crossfire-client/ChangeLog,v 1.28 2012/05/02 21:06:17 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-roguelike/crossfire-client/ChangeLog,v 1.29 2012/07/30 21:43:51 mr_bones_ Exp $
+
+*crossfire-client-1.70.0 (30 Jul 2012)
+
+  30 Jul 2012; Michael Sterrett <mr_bones_@g.o>
+  +crossfire-client-1.70.0.ebuild:
+  version bump (bug #410219)
 
   02 May 2012; Jeff Horelick <jdhore@g.o>
   crossfire-client-1.12.0.ebuild:



1.1                  games-roguelike/crossfire-client/crossfire-client-1.70.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/crossfire-client/crossfire-client-1.70.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-roguelike/crossfire-client/crossfire-client-1.70.0.ebuild?rev=1.1&content-type=text/plain

Index: crossfire-client-1.70.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-roguelike/crossfire-client/crossfire-client-1.70.0.ebuild,v 1.1 2012/07/30 21:43:51 mr_bones_ Exp $

EAPI=2
inherit gnome2-utils games

DESCRIPTION="Client for the nethack-style but more in the line of UO"
HOMEPAGE="http://crossfire.real-time.com/"
SRC_URI="mirror://sourceforge/crossfire/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="alsa lua oss sdl"

RDEPEND="alsa? ( media-libs/alsa-lib )
	virtual/opengl
	x11-libs/gtk+:2
	sdl? ( media-libs/libsdl[video]
		media-libs/sdl-image )
	lua? ( dev-lang/lua )
	net-misc/curl
	media-libs/freeglut
	media-libs/libpng:0
	sys-libs/zlib"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	sed -ri -e '/^.TH/s:$: 6:' $(find . -name "*man") || die
}

src_configure() {
	# bugs in configure script so we cant use $(use_enable ...)
	local myconf="--disable-dependency-tracking"

	use sdl || myconf="${myconf} --disable-sdl"
	use alsa || myconf="${myconf} --disable-alsa9 --disable-alsa"
	if ! use alsa && ! use oss ; then
		myconf="${myconf} --disable-sound"
	fi
	egamesconf ${myconf}
}

src_compile() {
	# bug 139785
	if use alsa || use oss ; then
		emake -j1 -C sound-src || die
	fi
	emake || die
}

src_install() {
	local s

	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog README TODO
	domenu gtk-v2/crossfire-client.desktop
	for s in 16 32 48
	do
		newicon -s ${s} pixmaps/${s}x${s}.png ${PN}.png
	done
	prepgamesdirs
}

pkg_preinst() {
	games_pkg_preinst
	gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}