[gentoo-commits] repo/gentoo:master commit in: net-misc/gerbera/

[Sam James]

commit:     df28e4189e81c56181ac13cf9d2a26c078fb3ef7
Author:     Christian Tietz <christian.tietz <AT> mailbox <DOT> org>
AuthorDate: Wed May  4 20:12:31 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat May  7 05:28:31 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=df28e418

net-misc/gerbera: Bump to 1.11.0

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Christian Tietz <christian.tietz <AT> mailbox.org>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-misc/gerbera/Manifest              |  1 +
 net-misc/gerbera/gerbera-1.11.0.ebuild | 91 ++++++++++++++++++++++++++++++++++
 2 files changed, 92 insertions(+)

diff --git a/net-misc/gerbera/Manifest b/net-misc/gerbera/Manifest
index 809bc619aee4..5e729d3e4915 100644
--- a/net-misc/gerbera/Manifest
+++ b/net-misc/gerbera/Manifest
@@ -1 +1,2 @@
 DIST gerbera-1.10.0.tar.gz 3960516 BLAKE2B 9240ff4334f6f018ed27489f3984bd8439eb1ae9784712d23e778f9c3054c37241036a32167fc1c19303f4d68db3862ae09e35b7a3f4c15ee1e960a1aa78086c SHA512 9bb605b6475bddc5b683433bc9c50818e4986fc134bb0a6daaa444d1733624164c6ff7440789af95da2ec3c04b6c2f4fd46a29744b4ef793b10d9fab0c65a881
+DIST gerbera-1.11.0.tar.gz 4115178 BLAKE2B 1b5f28c4602f949459816f57555bfebbedbabc9681b3d0d9eb3d7742a9b273644cf9c10b411baeb3b0c4b5ea3c340d1c0d8d6035cb0e7f38ba0c40fae1c5cd1b SHA512 ae2b3342b3b57ce6d656d0ebadfd73b5f2764f2164314f6b0deac170a82e6861349c37732e6914454918112124038b221dbd4882001b5de51a49326432ccd70f

diff --git a/net-misc/gerbera/gerbera-1.11.0.ebuild b/net-misc/gerbera/gerbera-1.11.0.ebuild
new file mode 100644
index 000000000000..f069b91f13cf
--- /dev/null
+++ b/net-misc/gerbera/gerbera-1.11.0.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake linux-info
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/gerbera/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/gerbera/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+	S="${WORKDIR}/${P}"
+fi
+
+DESCRIPTION="UPnP Media Server"
+HOMEPAGE="https://gerbera.io"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="curl debug +exif exiv2 +ffmpeg ffmpegthumbnailer +javascript lastfm +magic +matroska mysql systemd +taglib"
+
+RDEPEND="
+	acct-user/gerbera
+	dev-db/sqlite
+	dev-libs/libebml:=
+	dev-libs/libfmt:=
+	dev-libs/pugixml
+	dev-libs/spdlog:=
+	>=net-libs/libupnp-1.14.12:=[ipv6,reuseaddr,-blocking-tcp]
+	sys-apps/util-linux
+	sys-libs/zlib
+	virtual/libiconv
+	curl? ( net-misc/curl )
+	exif? ( media-libs/libexif )
+	exiv2? ( media-gfx/exiv2 )
+	ffmpeg? ( media-video/ffmpeg:= )
+	ffmpegthumbnailer? ( media-video/ffmpegthumbnailer )
+	javascript? ( dev-lang/duktape:= )
+	lastfm? ( media-libs/lastfmlib )
+	magic? ( sys-apps/file )
+	matroska? ( media-libs/libmatroska:= )
+	mysql? ( dev-db/mysql-connector-c )
+	taglib? ( media-libs/taglib )
+"
+
+DEPEND="${RDEPEND}"
+
+CONFIG_CHECK="~INOTIFY_USER"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_AVCODEC=$(usex ffmpeg)
+		-DWITH_CURL=$(usex curl)
+		-DWITH_DEBUG=$(usex debug)
+		-DWITH_EXIF=$(usex exif)
+		-DWITH_EXIV2=$(usex exiv2)
+		-DWITH_FFMPEGTHUMBNAILER=$(usex ffmpegthumbnailer)
+		-DWITH_INOTIFY=1
+		-DWITH_JS=$(usex javascript)
+		-DWITH_LASTFM=$(usex lastfm)
+		-DWITH_MAGIC=$(usex magic)
+		-DWITH_MATROSKA=$(usex matroska)
+		-DWITH_MYSQL=$(usex mysql)
+		-DWITH_SYSTEMD=$(usex systemd)
+		-DWITH_TAGLIB=$(usex taglib)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	newinitd "${FILESDIR}"/${PN}-1.0.0.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}-1.0.0.confd ${PN}
+
+	insinto /etc/${PN}
+	newins "${FILESDIR}"/${PN}-1.3.0.config config.xml
+	fperms 0640 /etc/${PN}/config.xml
+	fowners root:gerbera /etc/${PN}/config.xml
+}
+
+pkg_postinst() {
+	if use mysql; then
+		elog "Gerbera has been built with MySQL support and needs"
+		elog "to be configured before being started. By default"
+		elog "SQLite will be used."
+	fi
+}