[gentoo-commits] repo/gentoo:master commit in: xfce-base/xfce4-panel/

[Michał Górny]

commit:     cd453c2bf9c3b9261f789bb9baa3291e8426a8b4
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Jan 27 09:03:06 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jan 27 09:03:06 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cd453c2b

xfce-base/xfce4-panel: Bump to 4.16.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 xfce-base/xfce4-panel/Manifest                  |  1 +
 xfce-base/xfce4-panel/xfce4-panel-4.16.1.ebuild | 71 +++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/xfce-base/xfce4-panel/Manifest b/xfce-base/xfce4-panel/Manifest
index 966eef0aba8..8d9a2b053f2 100644
--- a/xfce-base/xfce4-panel/Manifest
+++ b/xfce-base/xfce4-panel/Manifest
@@ -1,2 +1,3 @@
 DIST xfce4-panel-4.14.4.tar.bz2 1307938 BLAKE2B 79e0abcc5dfe41faaab1de981b8a61a99e9c11ab5b3ddba5fb7385517d24b50210f12d0a6a49720d6d8458fa7143ed65d7960025c5e8c01af1a59dd6b339a2d9 SHA512 5ae7c7acf0254fdc3f5eaccf75d7c12699ab8147322f231af7bd17b1238b8c25a96d628dada9caa086fc8fde2b7dc4030a38eb7b863b290f9e069193b3728d85
 DIST xfce4-panel-4.16.0.tar.bz2 1382354 BLAKE2B 37737826e9d08974a2cad7513d93f6d998c6a49df0ae35b496db231448cb75d7b27631936fbae7ad25ed7bd80649737d678d6a761311c369e49e347876035c3b SHA512 ab3c4f23d67ff382c6f8bdc6c4f35c968f7789ab35132836c0aba824d074eda09c8cc7518b1f9f251a8e9cd6fa52844f194e70af52e3e11b0576d0ab8917a2f5
+DIST xfce4-panel-4.16.1.tar.bz2 1381003 BLAKE2B 103d1b60c13758ad5e3f139d3bc66923e648540195c7a71fb6c39bcdb06b109f620ced42b7eb6c36ccf5a833e97957c373e760feab3f062c5a7ecd3038803366 SHA512 ec55a9812d61db755ea56a87ea1b709af2870703fc0e5a45797406f2f4c78e8afecd6e1bc081f3618a81030c9c0595ae8edbb29731d4bef3750e202bbf35e99c

diff --git a/xfce-base/xfce4-panel/xfce4-panel-4.16.1.ebuild b/xfce-base/xfce4-panel/xfce4-panel-4.16.1.ebuild
new file mode 100644
index 00000000000..b3238b007d8
--- /dev/null
+++ b/xfce-base/xfce4-panel/xfce4-panel-4.16.1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit vala xdg-utils
+
+DESCRIPTION="Panel for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+dbusmenu introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND=">=dev-libs/glib-2.50
+	>=x11-libs/cairo-1
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	x11-libs/libX11
+	x11-libs/libwnck:3
+	>=xfce-base/exo-0.11.2:=
+	>=xfce-base/garcon-0.5:=
+	>=xfce-base/libxfce4ui-4.15.8:=
+	>=xfce-base/libxfce4util-4.15.6:=[introspection?]
+	>=xfce-base/xfconf-4.13:=
+	dbusmenu? ( >=dev-libs/libdbusmenu-16.04.0[gtk3] )
+	introspection? ( dev-libs/gobject-introspection:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	vala? ( $(vala_depend) )
+	dev-lang/perl
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# stupid vala.eclass...
+	default
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable dbusmenu dbusmenu-gtk3)
+		$(use_enable vala)
+	)
+
+	use vala && vala_src_prepare
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}