Gentoo Archives: gentoo-commits

From: "Tony Vroon (chainsaw)" <chainsaw@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in net-misc/asterisk: ChangeLog asterisk-12.3.0.ebuild
Date: Mon, 02 Jun 2014 16:19:23
Message-Id: 20140602161918.8CEBD2004E@flycatcher.gentoo.org
1 chainsaw 14/06/02 16:19:18
2
3 Modified: ChangeLog
4 Added: asterisk-12.3.0.ebuild
5 Log:
6 Significant string handling fixes as encouraged by GCC 4.10; leak fixes for PJSIP. Still not recommended for production deployment, remains masked.
7
8 (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB5058F9A)
9
10 Revision Changes Path
11 1.483 net-misc/asterisk/ChangeLog
12
13 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/asterisk/ChangeLog?rev=1.483&view=markup
14 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/asterisk/ChangeLog?rev=1.483&content-type=text/plain
15 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/asterisk/ChangeLog?r1=1.482&r2=1.483
16
17 Index: ChangeLog
18 ===================================================================
19 RCS file: /var/cvsroot/gentoo-x86/net-misc/asterisk/ChangeLog,v
20 retrieving revision 1.482
21 retrieving revision 1.483
22 diff -u -r1.482 -r1.483
23 --- ChangeLog 30 May 2014 12:39:52 -0000 1.482
24 +++ ChangeLog 2 Jun 2014 16:19:18 -0000 1.483
25 @@ -1,6 +1,12 @@
26 # ChangeLog for net-misc/asterisk
27 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
28 -# $Header: /var/cvsroot/gentoo-x86/net-misc/asterisk/ChangeLog,v 1.482 2014/05/30 12:39:52 chainsaw Exp $
29 +# $Header: /var/cvsroot/gentoo-x86/net-misc/asterisk/ChangeLog,v 1.483 2014/06/02 16:19:18 chainsaw Exp $
30 +
31 +*asterisk-12.3.0 (02 Jun 2014)
32 +
33 + 02 Jun 2014; Tony Vroon <chainsaw@g.o> +asterisk-12.3.0.ebuild:
34 + Significant string handling fixes as encouraged by GCC 4.10; leak fixes for
35 + PJSIP. Still not recommended for production deployment, remains masked.
36
37 *asterisk-11.10.0 (30 May 2014)
38 *asterisk-1.8.28.0 (30 May 2014)
39
40
41
42 1.1 net-misc/asterisk/asterisk-12.3.0.ebuild
43
44 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/asterisk/asterisk-12.3.0.ebuild?rev=1.1&view=markup
45 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/asterisk/asterisk-12.3.0.ebuild?rev=1.1&content-type=text/plain
46
47 Index: asterisk-12.3.0.ebuild
48 ===================================================================
49 # Copyright 1999-2014 Gentoo Foundation
50 # Distributed under the terms of the GNU General Public License v2
51 # $Header: /var/cvsroot/gentoo-x86/net-misc/asterisk/asterisk-12.3.0.ebuild,v 1.1 2014/06/02 16:19:18 chainsaw Exp $
52
53 EAPI=5
54 inherit autotools base eutils linux-info multilib user
55
56 MY_P="${PN}-${PV/_/-}"
57
58 DESCRIPTION="Asterisk: A Modular Open Source PBX System"
59 HOMEPAGE="http://www.asterisk.org/"
60 SRC_URI="http://downloads.asterisk.org/pub/telephony/asterisk/releases/${MY_P}.tar.gz
61 mirror://gentoo/gentoo-asterisk-patchset-3.10.tar.bz2"
62 LICENSE="GPL-2"
63 SLOT="0"
64 KEYWORDS="~amd64 ~x86"
65
66 IUSE_VOICEMAIL_STORAGE="
67 +voicemail_storage_file
68 voicemail_storage_odbc
69 voicemail_storage_imap
70 "
71 IUSE="${IUSE_VOICEMAIL_STORAGE} alsa bluetooth calendar +caps cluster curl dahdi debug doc freetds gtalk http iconv ilbc jabber ldap libedit lua mysql newt +samples odbc osplookup oss portaudio postgres radius selinux snmp span speex srtp static syslog vorbis"
72 IUSE_EXPAND="VOICEMAIL_STORAGE"
73 REQUIRED_USE="gtalk? ( jabber )
74 ^^ ( ${IUSE_VOICEMAIL_STORAGE/+/} )
75 voicemail_storage_odbc? ( odbc )
76 "
77
78 EPATCH_SUFFIX="patch"
79 EPATCH_EXCLUDE="08-tls-certificate-chaining-support.patch"
80 PATCHES=( "${WORKDIR}/asterisk-patchset" )
81
82 RDEPEND="dev-db/sqlite:3
83 dev-libs/popt
84 dev-libs/jansson
85 dev-libs/libxml2
86 dev-libs/openssl
87 sys-libs/ncurses
88 sys-libs/zlib
89 alsa? ( media-libs/alsa-lib )
90 bluetooth? ( net-wireless/bluez )
91 calendar? ( net-libs/neon
92 dev-libs/libical
93 dev-libs/iksemel )
94 caps? ( sys-libs/libcap )
95 cluster? ( sys-cluster/corosync )
96 curl? ( net-misc/curl )
97 dahdi? ( >=net-libs/libpri-1.4.12_beta2
98 net-misc/dahdi-tools )
99 freetds? ( dev-db/freetds )
100 gtalk? ( dev-libs/iksemel )
101 http? ( dev-libs/gmime:2.6 )
102 iconv? ( virtual/libiconv )
103 ilbc? ( dev-libs/ilbc-rfc3951 )
104 jabber? ( dev-libs/iksemel )
105 ldap? ( net-nds/openldap )
106 libedit? ( dev-libs/libedit )
107 lua? ( dev-lang/lua )
108 mysql? ( virtual/mysql )
109 newt? ( dev-libs/newt )
110 odbc? ( dev-db/unixODBC )
111 osplookup? ( net-libs/osptoolkit )
112 portaudio? ( media-libs/portaudio )
113 postgres? ( dev-db/postgresql-base )
114 radius? ( net-dialup/radiusclient-ng )
115 selinux? ( sec-policy/selinux-asterisk )
116 snmp? ( net-analyzer/net-snmp )
117 span? ( media-libs/spandsp )
118 speex? ( media-libs/speex )
119 srtp? ( net-libs/libsrtp )
120 vorbis? ( media-libs/libvorbis )"
121
122 DEPEND="${RDEPEND}
123 !net-libs/openh323
124 !net-libs/pjsip
125 voicemail_storage_imap? ( virtual/imap-c-client )
126 "
127
128 RDEPEND="${RDEPEND}
129 syslog? ( virtual/logger )"
130
131 PDEPEND="net-misc/asterisk-core-sounds
132 net-misc/asterisk-extra-sounds
133 net-misc/asterisk-moh-opsound"
134
135 S="${WORKDIR}/${MY_P}"
136
137 pkg_setup() {
138 CONFIG_CHECK="~!NF_CONNTRACK_SIP"
139 local WARNING_NF_CONNTRACK_SIP="SIP (NAT) connection tracking is enabled. Some users
140 have reported that this module dropped critical SIP packets in their deployments. You
141 may want to disable it if you see such problems."
142 check_extra_config
143
144 enewgroup asterisk
145 enewgroup dialout 20
146 enewuser asterisk -1 -1 /var/lib/asterisk "asterisk,dialout"
147 }
148
149 src_prepare() {
150 base_src_prepare
151 AT_M4DIR=autoconf eautoreconf
152 }
153
154 src_configure() {
155 local vmst
156
157 econf \
158 --libdir="/usr/$(get_libdir)" \
159 --localstatedir="/var" \
160 --with-crypto \
161 --with-gsm=internal \
162 --with-popt \
163 --with-ssl \
164 --with-z \
165 --without-pwlib \
166 $(use_with caps cap) \
167 $(use_with http gmime) \
168 $(use_with newt) \
169 $(use_with portaudio)
170
171 # Blank out sounds/sounds.xml file to prevent
172 # asterisk from installing sounds files (we pull them in via
173 # asterisk-{core,extra}-sounds and asterisk-moh-opsound.
174 >"${S}"/sounds/sounds.xml
175
176 # That NATIVE_ARCH chatter really is quite bothersome
177 sed -i 's/NATIVE_ARCH=/NATIVE_ARCH=0/' build_tools/menuselect-deps || die "Unable to squelch noisy build system"
178
179 # Compile menuselect binary for optional components
180 emake menuselect.makeopts
181
182 # Broken functionality is forcibly disabled (bug #360143)
183 menuselect/menuselect --disable chan_misdn menuselect.makeopts
184 menuselect/menuselect --disable chan_ooh323 menuselect.makeopts
185
186 # Utility set is forcibly enabled (bug #358001)
187 menuselect/menuselect --enable smsq menuselect.makeopts
188 menuselect/menuselect --enable streamplayer menuselect.makeopts
189 menuselect/menuselect --enable aelparse menuselect.makeopts
190 menuselect/menuselect --enable astman menuselect.makeopts
191
192 # this is connected, otherwise it would not find
193 # ast_pktccops_gate_alloc symbol
194 menuselect/menuselect --enable chan_mgcp menuselect.makeopts
195 menuselect/menuselect --enable res_pktccops menuselect.makeopts
196
197 # SSL is forcibly enabled, IAX2 & DUNDI are expected to be available
198 menuselect/menuselect --enable pbx_dundi menuselect.makeopts
199 menuselect/menuselect --enable func_aes menuselect.makeopts
200 menuselect/menuselect --enable chan_iax2 menuselect.makeopts
201
202 # SQlite3 is now the main database backend, enable related features
203 menuselect/menuselect --enable cdr_sqlite3_custom menuselect.makeopts
204 menuselect/menuselect --enable cel_sqlite3_custom menuselect.makeopts
205
206 # The others are based on USE-flag settings
207 use_select() {
208 local state=$(use "$1" && echo enable || echo disable)
209 shift # remove use from parameters
210
211 while [[ -n $1 ]]; do
212 menuselect/menuselect --${state} "$1" menuselect.makeopts
213 shift
214 done
215 }
216
217 use_select alsa chan_alsa
218 use_select bluetooth chan_mobile
219 use_select calendar res_calendar res_calendar_{caldav,ews,exchange,icalendar}
220 use_select cluster res_corosync
221 use_select curl func_curl res_config_curl res_curl
222 use_select dahdi app_dahdibarge app_dahdiras chan_dahdi codec_dahdi res_timing_dahdi
223 use_select freetds {cdr,cel}_tds
224 use_select gtalk chan_motif
225 use_select http res_http_post
226 use_select iconv func_iconv
227 use_select jabber res_xmpp
228 use_select ilbc codec_ilbc format_ilbc
229 use_select ldap res_config_ldap
230 use_select lua pbx_lua
231 use_select mysql app_mysql cdr_mysql res_config_mysql
232 use_select odbc cdr_adaptive_odbc res_config_odbc {cdr,cel,res,func}_odbc
233 use_select osplookup app_osplookup
234 use_select oss chan_oss
235 use_select postgres {cdr,cel}_pgsql res_config_pgsql
236 use_select radius {cdr,cel}_radius
237 use_select snmp res_snmp
238 use_select span res_fax_spandsp
239 use_select speex {codec,func}_speex
240 use_select srtp res_srtp
241 use_select syslog cdr_syslog
242 use_select vorbis format_ogg_vorbis
243
244 # Voicemail storage ...
245 for vmst in ${IUSE_VOICEMAIL_STORAGE/+/}; do
246 if use ${vmst}; then
247 menuselect/menuselect --enable $(echo ${vmst##*_} | tr '[:lower:]' '[:upper:]')_STORAGE menuselect.makeopts
248 fi
249 done
250
251 if use debug; then
252 for o in DONT_OPTIMIZE DEBUG_THREADS BETTER_BACKTRACES; do
253 menuselect/menuselect --enable $o menuselect.makeopts
254 done
255 fi
256 }
257
258 src_compile() {
259 ASTLDFLAGS="${LDFLAGS}" emake
260 }
261
262 src_install() {
263 mkdir -p "${D}"usr/$(get_libdir)/pkgconfig || die
264 emake DESTDIR="${D}" installdirs
265 emake DESTDIR="${D}" install
266
267 if use radius; then
268 insinto /etc/radiusclient-ng/
269 doins contrib/dictionary.digium
270 fi
271 if use samples; then
272 emake DESTDIR="${D}" samples
273 for conffile in "${D}"etc/asterisk/*.*
274 do
275 chown asterisk:asterisk $conffile
276 chmod 0660 $conffile
277 done
278 einfo "Sample files have been installed"
279 else
280 einfo "Skipping installation of sample files..."
281 rm -f "${D}"var/lib/asterisk/mohmp3/* || die
282 rm -f "${D}"var/lib/asterisk/sounds/demo-* || die
283 rm -f "${D}"var/lib/asterisk/agi-bin/* || die
284 rm -f "${D}"etc/asterisk/* || die
285 fi
286 rm -rf "${D}"var/spool/asterisk/voicemail/default || die
287
288 # keep directories
289 diropts -m 0770 -o asterisk -g asterisk
290 keepdir /etc/asterisk
291 keepdir /var/lib/asterisk
292 keepdir /var/spool/asterisk
293 keepdir /var/spool/asterisk/{system,tmp,meetme,monitor,dictate,voicemail}
294 diropts -m 0750 -o asterisk -g asterisk
295 keepdir /var/log/asterisk/{cdr-csv,cdr-custom}
296
297 newinitd "${FILESDIR}"/1.8.0/asterisk.initd7 asterisk
298 newconfd "${FILESDIR}"/1.8.0/asterisk.confd asterisk
299
300 # install the upgrade documentation
301 #
302 dodoc README UPGRADE* BUGS CREDITS
303
304 # install extra documentation
305 #
306 if use doc
307 then
308 dodoc doc/*.txt
309 dodoc doc/*.pdf
310 fi
311
312 # install SIP scripts; bug #300832
313 #
314 dodoc "${FILESDIR}/1.6.2/sip_calc_auth"
315 dodoc "${FILESDIR}/1.8.0/find_call_sip_trace.sh"
316 dodoc "${FILESDIR}/1.8.0/find_call_ids.sh"
317 dodoc "${FILESDIR}/1.6.2/call_data.txt"
318
319 # install logrotate snippet; bug #329281
320 #
321 insinto /etc/logrotate.d
322 newins "${FILESDIR}/1.6.2/asterisk.logrotate3" asterisk
323 }
324
325 pkg_postinst() {
326 #
327 # Announcements, warnings, reminders...
328 #
329 einfo "Asterisk has been installed"
330 echo
331 elog "If you want to know more about asterisk, visit these sites:"
332 elog "http://www.asteriskdocs.org/"
333 elog "http://www.voip-info.org/wiki-Asterisk"
334 echo
335 elog "http://www.automated.it/guidetoasterisk.htm"
336 echo
337 elog "Gentoo VoIP IRC Channel:"
338 elog "#gentoo-voip @ irc.freenode.net"
339 echo
340 echo
341 elog "Please read the Asterisk 12 upgrade document:"
342 elog "https://wiki.asterisk.org/wiki/display/AST/Upgrading+to+Asterisk+12"
343 }
344
345 pkg_config() {
346 einfo "Do you want to reset file permissions and ownerships (y/N)?"
347
348 read tmp
349 tmp="$(echo $tmp | tr '[:upper:]' '[:lower:]')"
350
351 if [[ "$tmp" = "y" ]] ||\
352 [[ "$tmp" = "yes" ]]
353 then
354 einfo "Resetting permissions to defaults..."
355
356 for x in spool run lib log; do
357 chown -R asterisk:asterisk "${ROOT}"var/${x}/asterisk
358 chmod -R u=rwX,g=rwX,o= "${ROOT}"var/${x}/asterisk
359 done
360
361 chown -R root:asterisk "${ROOT}"etc/asterisk
362 chmod -R u=rwX,g=rwX,o= "${ROOT}"etc/asterisk
363
364 einfo "done"
365 else
366 einfo "skipping"
367 fi
368 }