[gentoo-commits] repo/gentoo:master commit in: dev-python/h5py/

[Nicolas Bock]

commit:     c1490190ecc8806ea50ec353782c4b57e4162d1c
Author:     Nicolas Bock <nicolasbock <AT> gentoo <DOT> org>
AuthorDate: Thu Mar  1 19:03:48 2018 +0000
Commit:     Nicolas Bock <nicolasbock <AT> gentoo <DOT> org>
CommitDate: Thu Mar  1 19:04:16 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c1490190

dev-python/h5py: Version bump to 2.7.1

Closes: https://bugs.gentoo.org/649036
Package-Manager: Portage-2.3.19, Repoman-2.3.6

 dev-python/h5py/Manifest          |  1 +
 dev-python/h5py/h5py-2.7.1.ebuild | 66 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/dev-python/h5py/Manifest b/dev-python/h5py/Manifest
index a52869c7e6b..4a6a12e9117 100644
--- a/dev-python/h5py/Manifest
+++ b/dev-python/h5py/Manifest
@@ -1 +1,2 @@
 DIST h5py-2.7.0.tar.gz 256471 BLAKE2B c232eb86d00b9d1bb76903ea04bfd384bae7c9eb7b301de6aa450a46918f69132ab8d8d5a3f9b54095feee436a8aa9e9045c27ca1a120d665d6031c14218f0f5 SHA512 7c1e5d8b47c176521f5f62cfc4f782c09a0e003c5cbc07a673ccc3dfbe97df930b33801ef7311360892e3fad1d7d72561a8578aed9cb630d44e1a73543bb5da4
+DIST h5py-2.7.1.tar.gz 264225 BLAKE2B ffb0b52127f6cb9634b5ac3266a36bc0003144d302bdc300fff5f6f33e52b5a12e954cc2ef9fdfe9dfa0eddc810b30ee3f556cab2a31338500db666b87e64ddc SHA512 b702e3875c2767d2fabe66601820c517671fb5fc3321334aba081950b625435a1262554f39187cd1b41c6069e2b3826db6f0b610bfed2abe5db8a4dd8a29ecfd

diff --git a/dev-python/h5py/h5py-2.7.1.ebuild b/dev-python/h5py/h5py-2.7.1.ebuild
new file mode 100644
index 00000000000..30bee0302c8
--- /dev/null
+++ b/dev-python/h5py/h5py-2.7.1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Simple Python interface to HDF5 files"
+HOMEPAGE="http://www.h5py.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test examples mpi"
+
+RDEPEND="
+	sci-libs/hdf5:=[mpi=,hl(+)]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+
+DEPEND="
+	${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/alabaster[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.3.1[${PYTHON_USEDEP}]
+		)
+	mpi? ( dev-python/mpi4py[${PYTHON_USEDEP}] )"
+
+pkg_setup() {
+	use mpi && export CC=mpicc
+}
+
+python_prepare_all() {
+	append-cflags -fno-strict-aliasing
+	distutils-r1_python_prepare_all
+}
+
+python_configure() {
+	esetup.py configure $(usex mpi --mpi '')
+}
+
+python_compile_all() {
+	if use doc; then
+		cd "${S}"/docs || die
+		sed '/html_theme/s:default:alabaster:g' -i conf.py || die
+		emake html
+	fi
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	DOCS=( README.rst ANN.rst )
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	use examples && DOCS+=( examples )
+
+	distutils-r1_python_install_all
+}