[gentoo-commits] repo/gentoo:master commit in: net-misc/youtube-dl/

[Jeroen Roovers]

commit:     40f7b73142b624f8ca1b6c371716c0234c653189
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  1 12:42:12 2020 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Wed Jan  1 12:42:46 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=40f7b731

net-misc/youtube-dl: Version 2020.01.01

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 net-misc/youtube-dl/Manifest                     |  1 +
 net-misc/youtube-dl/youtube-dl-2020.01.01.ebuild | 77 ++++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index 09b53c0f02f..b38adedbd01 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1 +1,2 @@
 DIST youtube-dl-2019.12.25.tar.gz 3153090 BLAKE2B c86aa3f905c2cea84b6083cba215e6404d8dc25689290aaac6a642d5da61df162609d52bcf578b6463cd1898b282a15245efc8a3cc36f26f163170427c3174cb SHA512 951219648597d5e19fd3bcb3c64d8641bffd63cf3c6b4b30332d9148ad8b12c1be252e4cacbcd8169ce502b0fe20b2ff7163620382769b5e83e82d155e4f38c8
+DIST youtube-dl-2020.01.01.tar.gz 3156193 BLAKE2B 0052e8da07d83127a8c2cf3a25ab9733e7f4417473e89cdaf849e11e79285e4c8bdce5003b59f6ff8cbf3980043ce2e992346264f08caecebfa4ee33370203b0 SHA512 035d44aa4989067587d3c5a8d1bb4214bb7bfa16b91562c730fcf93de1578de75ddf12c8a0900643578546a4230da776b8b83f69378525c1480e9e0061f492cf

diff --git a/net-misc/youtube-dl/youtube-dl-2020.01.01.ebuild b/net-misc/youtube-dl/youtube-dl-2020.01.01.ebuild
new file mode 100644
index 00000000000..0199f8e970a
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2020.01.01.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=(python{2_7,3_{5,6,7,8}})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://github.com/ytdl-org/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+LICENSE="public-domain"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+SLOT="0"
+IUSE="test"
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	|| (
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/flake8[${PYTHON_USEDEP}]
+	)
+"
+S=${WORKDIR}/${PN}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_test() {
+	emake offlinetest
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}