[gentoo-commits] repo/gentoo:master commit in: dev-python/pytest-rerunfailures/

[Michał Górny]

commit:     4821784c526a1dab7a383bc983e97b5afe521e14
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu May 12 10:20:04 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu May 12 10:40:42 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4821784c

dev-python/pytest-rerunfailures: Use PEP517 build

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../pytest-rerunfailures-10.2-r1.ebuild            | 35 ++++++++++++++++++++++
 1 file changed, 35 insertions(+)

diff --git a/dev-python/pytest-rerunfailures/pytest-rerunfailures-10.2-r1.ebuild b/dev-python/pytest-rerunfailures/pytest-rerunfailures-10.2-r1.ebuild
new file mode 100644
index 000000000000..1fc685a9c8cc
--- /dev/null
+++ b/dev-python/pytest-rerunfailures/pytest-rerunfailures-10.2-r1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="pytest plugin to re-run tests to eliminate flaky failures"
+HOMEPAGE="
+	https://github.com/pytest-dev/pytest-rerunfailures/
+	https://pypi.org/project/pytest-rerunfailures/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MPL-2.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_rerunfailures
+	if has_version "dev-python/pytest-xdist[${PYTHON_USEDEP}]"; then
+		PYTEST_PLUGINS+=,xdist.plugin
+	fi
+	epytest
+}