[gentoo-commits] gentoo-x86 commit in media-libs/hamlib: ChangeLog hamlib-1.2.14.ebuild

[Thomas Beierlein (tomjbe)]

tomjbe      11/09/01 18:42:34

  Modified:             ChangeLog
  Added:                hamlib-1.2.14.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.11/cvs/Linux x86_64)

Revision  Changes    Path
1.61                 media-libs/hamlib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/hamlib/ChangeLog?rev=1.61&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/hamlib/ChangeLog?rev=1.61&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/hamlib/ChangeLog?r1=1.60&r2=1.61

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/hamlib/ChangeLog,v
retrieving revision 1.60
retrieving revision 1.61
diff -u -r1.60 -r1.61
--- ChangeLog	12 Aug 2011 21:15:44 -0000	1.60
+++ ChangeLog	1 Sep 2011 18:42:33 -0000	1.61
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/hamlib
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/hamlib/ChangeLog,v 1.60 2011/08/12 21:15:44 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/hamlib/ChangeLog,v 1.61 2011/09/01 18:42:33 tomjbe Exp $
+
+*hamlib-1.2.14 (01 Sep 2011)
+
+  01 Sep 2011; Thomas Beierlein <tomjbe@g.o> +hamlib-1.2.14.ebuild:
+  Version bump
 
   12 Aug 2011; Kacper Kowalik <xarthisius@g.o> hamlib-1.2.10.ebuild,
   hamlib-1.2.11.ebuild, hamlib-1.2.12-r2.ebuild, hamlib-1.2.13.ebuild:



1.1                  media-libs/hamlib/hamlib-1.2.14.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/hamlib/hamlib-1.2.14.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/hamlib/hamlib-1.2.14.ebuild?rev=1.1&content-type=text/plain

Index: hamlib-1.2.14.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/hamlib/hamlib-1.2.14.ebuild,v 1.1 2011/09/01 18:42:33 tomjbe Exp $

EAPI="3"
PYTHON_DEPEND="python? 2"

inherit autotools-utils eutils multilib python

DESCRIPTION="Ham radio backend rig control libraries"
HOMEPAGE="http://sourceforge.net/apps/mediawiki/hamlib"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="LGPL-2 GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~x86 ~x86-fbsd"
IUSE="doc python tcl"

RESTRICT="test"

RDEPEND="
	=virtual/libusb-0*
	dev-libs/libxml2
	tcl? ( dev-lang/tcl )"

DEPEND=" ${RDEPEND}
	dev-util/pkgconfig
	dev-lang/swig
	>=sys-devel/libtool-2.2
	doc? ( app-doc/doxygen )"

pkg_setup() {
	if use python; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_prepare() {
	# fix hardcoded libdir paths
	sed -i -e "s#fix}/lib#fix}/$(get_libdir)/hamlib#" \
		-e "s#fix}/include#fix}/include/hamlib#" \
		hamlib.pc.in || die "sed failed"

	# fix tcl lib path
	epatch "${FILESDIR}"/${PN}-1.2.11-bindings.diff

	eautoreconf
}

src_configure() {
	econf \
		--libdir=/usr/$(get_libdir)/hamlib \
		--disable-static \
		--with-rpc-backends \
		--without-perl-binding \
		$(use_with python python-binding) \
		$(use_enable tcl tcl-binding)
}

src_compile() {
	emake || die "emake failed"

	if use doc ; then
		cd doc && make doc || die "make doc failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	remove_libtool_files all

	dodoc AUTHORS NEWS PLAN README README.betatester \
		README.developer TODO || die "dodoc failed"

	if use doc; then
		dohtml doc/html/* || die "dohtml failed"
	fi

	insinto /usr/$(get_libdir)/pkgconfig
	doins hamlib.pc || die "doins failed"

	echo "LDPATH=/usr/$(get_libdir)/hamlib" > "${T}"/73hamlib
	doenvd "${T}"/73hamlib || die "doenvd failed"
}

pkg_postinst()  {
	use python && python_mod_optimize Hamlib.py
}

pkg_postrm()  {
	use python && python_mod_cleanup Hamlib.py
}