[gentoo-commits] gentoo-x86 commit in dev-util/buildbot: ChangeLog buildbot-0.8.4_p2.ebuild

[Dirkjan Ochtman (djc)]

djc         11/09/03 19:34:00

  Modified:             ChangeLog
  Added:                buildbot-0.8.4_p2.ebuild
  Log:
  Version bump buildbot to 0.8.4_p2.
  
  (Portage version: 2.1.10.12/cvs/Linux x86_64)

Revision  Changes    Path
1.92                 dev-util/buildbot/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/buildbot/ChangeLog?rev=1.92&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/buildbot/ChangeLog?rev=1.92&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/buildbot/ChangeLog?r1=1.91&r2=1.92

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v
retrieving revision 1.91
retrieving revision 1.92
diff -u -r1.91 -r1.92
--- ChangeLog	23 Mar 2011 21:30:05 -0000	1.91
+++ ChangeLog	3 Sep 2011 19:34:00 -0000	1.92
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/buildbot
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v 1.91 2011/03/23 21:30:05 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v 1.92 2011/09/03 19:34:00 djc Exp $
+
+*buildbot-0.8.4_p2 (03 Sep 2011)
+
+  03 Sep 2011; Dirkjan Ochtman <djc@g.o> +buildbot-0.8.4_p2.ebuild:
+  Version bump to 0.8.4_p2 (fixes bug 373927).
 
   23 Mar 2011; Kacper Kowalik <xarthisius@g.o> buildbot-0.8.3_p1.ebuild:
   ppc/ppc64 stable wrt #352741



1.1                  dev-util/buildbot/buildbot-0.8.4_p2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/buildbot/buildbot-0.8.4_p2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/buildbot/buildbot-0.8.4_p2.ebuild?rev=1.1&content-type=text/plain

Index: buildbot-0.8.4_p2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/buildbot-0.8.4_p2.ebuild,v 1.1 2011/09/03 19:34:00 djc Exp $

EAPI="3"
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.* *-jython"
DISTUTILS_SRC_TEST="trial"
DISTUTILS_DISABLE_TEST_DEPENDENCY="1"

inherit distutils eutils

MY_PV="${PV/_p/p}"
MY_P="${PN}-${MY_PV}"

DESCRIPTION="BuildBot build automation system"
HOMEPAGE="http://trac.buildbot.net/ http://code.google.com/p/buildbot/ http://pypi.python.org/pypi/buildbot"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples irc mail manhole test"

# sqlite3 module of Python 2.5 is not supported.
RDEPEND=">=dev-python/jinja-2.1
	|| ( dev-lang/python:2.7 dev-lang/python:2.6 dev-python/simplejson )
	|| ( dev-lang/python:2.7[sqlite] dev-lang/python:2.6[sqlite] dev-python/pysqlite:2 )
	>=dev-python/twisted-8.0.0
	dev-python/twisted-web
	dev-python/sqlalchemy
	dev-python/sqlalchemy-migrate
	irc? ( dev-python/twisted-words )
	mail? ( dev-python/twisted-mail )
	manhole? ( dev-python/twisted-conch )"
DEPEND="${DEPEND}
	dev-python/setuptools
	doc? ( sys-apps/texinfo )
	test? (
		dev-python/mock
		dev-python/twisted-mail
		dev-python/twisted-web
		dev-python/twisted-words
	)"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	python_pkg_setup
	enewuser buildbot
}

src_compile() {
	distutils_src_compile

	if use doc; then
		einfo "Generation of documentation"
		pushd docs > /dev/null
		emake buildbot.html buildbot.info || die "Generation of documentation failed"
		popd > /dev/null
	fi
}

src_install() {
	distutils_src_install

	doman docs/buildbot.1 || die "doman failed"

	if use doc; then
		dohtml -r docs/buildbot.html docs/images || die "dohtml failed"
		doinfo docs/buildbot.info || die "doinfo failed"
	fi

	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r contrib docs/examples || die "doins failed"
	fi

	newconfd "${FILESDIR}/buildmaster.confd" buildmaster || die "newconfd failed"
	newinitd "${FILESDIR}/buildmaster.initd" buildmaster || die "newinitd failed"
}

pkg_postinst() {
	distutils_pkg_postinst

	elog "The \"buildbot\" user and the \"buildmaster\" init script has been added"
	elog "to support starting buildbot through Gentoo's init system. To use this,"
	elog "set up your build master following the documentation, make sure the"
	elog "resulting directories are owned by the \"buildbot\" user and point"
	elog "\"${ROOT}etc/conf.d/buildmaster\" at the right location. The scripts can"
	elog "run as a different user if desired. If you need to run more than one"
	elog "build master, just copy the scripts."
	elog
	elog "Upstream recommends the following when upgrading:"
	elog "Each time you install a new version of Buildbot, you should run the"
	elog "\"buildbot upgrade-master\" command on each of your pre-existing build masters."
	elog "This will add files and fix (or at least detect) incompatibilities between"
	elog "your old config and the new code."
}