[gentoo-commits] gentoo-x86 commit in app-mobilephone/obexftp: obexftp-0.23-r2.ebuild ChangeLog

[Manuel Rueger (mrueg)]

mrueg       13/11/05 00:15:55

  Modified:             ChangeLog
  Added:                obexftp-0.23-r2.ebuild
  Log:
  NMU: Update ebuild to work with ruby 1.9 only. Fixes bug #483096.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key )

Revision  Changes    Path
1.65                 app-mobilephone/obexftp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/obexftp/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/obexftp/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/obexftp/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	21 Aug 2013 19:34:38 -0000	1.64
+++ ChangeLog	5 Nov 2013 00:15:54 -0000	1.65
@@ -1,6 +1,12 @@
 # ChangeLog for app-mobilephone/obexftp
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v 1.64 2013/08/21 19:34:38 creffett Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/ChangeLog,v 1.65 2013/11/05 00:15:54 mrueg Exp $
+
+*obexftp-0.23-r2 (05 Nov 2013)
+
+  05 Nov 2013; Manuel Rüger <mrueg@g.o>
+  +files/obexftp-0.23-fix-ruby19.patch, +obexftp-0.23-r2.ebuild:
+  NMU: Update ebuild to work with ruby 1.9 only. Fixes bug #483096.
 
   21 Aug 2013; Chris Reffett <creffett@g.o> obexftp-0.23-r1.ebuild:
   Update to distutils-r1. Fix bugs 312725 and 398113.



1.1                  app-mobilephone/obexftp/obexftp-0.23-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/obexftp/obexftp-0.23-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-mobilephone/obexftp/obexftp-0.23-r2.ebuild?rev=1.1&content-type=text/plain

Index: obexftp-0.23-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-mobilephone/obexftp/obexftp-0.23-r2.ebuild,v 1.1 2013/11/05 00:15:54 mrueg Exp $

EAPI="5"

PYTHON_COMPAT=( python{2_6,2_7} )
GENTOO_DEPEND_ON_PERL=no

inherit distutils-r1 eutils perl-module flag-o-matic autotools

DESCRIPTION="File transfer over OBEX for mobile phones"
HOMEPAGE="http://dev.zuckschwerdt.org/openobex/wiki/ObexFtp"
SRC_URI="mirror://sourceforge/openobex/${P}.tar.bz2"
SLOT="0"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="bluetooth debug perl python ruby tcl"

RDEPEND="dev-libs/openobex
	bluetooth? ( net-wireless/bluez )
	perl? ( dev-lang/perl )
	ruby? ( dev-lang/ruby:1.9 )
	tcl? ( dev-lang/tcl )
"
DEPEND="${RDEPEND}
	virtual/pkgconfig
"

src_prepare() {
	epatch "${FILESDIR}"/${P}-fixruby.patch \
		"${FILESDIR}"/${P}-gentoo.patch \
		"${FILESDIR}"/${P}-fix-ruby19.patch
	# Python bindings are built/installed manually.
	sed -e "/MAYBE_PYTHON_ = python/d" -i swig/Makefile.am || die "sed failed"

	eautoreconf
}

src_configure() {
	if use debug ; then
		strip-flags
		append-flags "-g -DOBEXFTP_DEBUG=5"
	fi

	local MYRUBY
	use ruby && MYRUBY="RUBY=/usr/bin/ruby19"

	econf \
		$(use_enable bluetooth) \
		$(use_enable perl) \
		$(use_enable python) \
		$(use_enable tcl) \
		$(use_enable ruby) \
		${MYRUBY}
}

src_compile() {
	default

	if use python; then
		pushd swig/python/
		distutils-r1_src_compile
		popd
	fi
}

src_install() {
	# -j1 because "make -fMakefile.ruby install" fails
	# upstream added -j1 to that command so it should be removed
	# from here in the next version bump
	emake -j1 DESTDIR="${D}" INSTALLDIRS=vendor install

	if use python; then
		pushd swig/python/
		distutils-r1_src_install
		popd
	fi

	dodoc AUTHORS ChangeLog NEWS README* THANKS TODO
	dohtml doc/*.html

	# Install examples
	insinto /usr/share/doc/${PF}/examples
	doins examples/*.c
	use perl && doins examples/*.pl
	use python && doins examples/*.py
	use ruby && doins examples/*.rb
	use tcl && doins examples/*.tcl

	if use perl ; then
		perl_delete_localpod
		perl_delete_packlist
	fi
}

pkg_postinst() {
	use perl && perl-module_pkg_postinst
	use python && distutils-r1_pkg_postinst
}

pkg_postrm() {
	use perl && perl-module_pkg_postrm
	use python && distutils-r1_pkg_postrm
}