[gentoo-commits] repo/gentoo:master commit in: net-misc/owncloud-client/

[Bernard Cafarelli]

commit:     ffe2f2995705df17954c295402e9c3e5bc76516b
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 30 08:24:05 2016 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Fri Sep 30 08:24:05 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ffe2f299

net-misc/owncloud-client: version bump to 2.2.4

Package-Manager: portage-2.3.1

 net-misc/owncloud-client/Manifest                  |   1 +
 .../owncloud-client/owncloud-client-2.2.4.ebuild   | 101 +++++++++++++++++++++
 2 files changed, 102 insertions(+)

diff --git a/net-misc/owncloud-client/Manifest b/net-misc/owncloud-client/Manifest
index 639fa9a..bfef112 100644
--- a/net-misc/owncloud-client/Manifest
+++ b/net-misc/owncloud-client/Manifest
@@ -1 +1,2 @@
 DIST owncloudclient-2.2.3.tar.xz 12215320 SHA256 f8c921e3eda543c6c860ea8e3024ed164df0db7c0e83d1778ab0adfd324f7d01 SHA512 71be325e5d6177a767dc61b043bd6126b5b7a492a2a777c0179c2dbb77bf6104e26fce92734a6d4bfcc7b9c451026e86a2f44d39869e9451f21b0e534c26e189 WHIRLPOOL 7099c62214f1170c6ec3dfe2adc1c692d8847a0643bd7f5d5a5028f65e395774a29eec3ee6ece72e9e85dd343b05c3c1184665db34e635b2b99c6e15a33ce54e
+DIST owncloudclient-2.2.4.tar.xz 12216896 SHA256 f313534f7cdae686beeaa6670d9e3586a627ce78b67cab6e42a448a675d9e7d3 SHA512 5bc5273c90ab63c411e58d1fe13636f6b5977c28470efe53296a71541aaa63af99001cb630adaee99b9b81a8b56fe0f66c337319464ab950dd6eac4cdd53f951 WHIRLPOOL 18aa5076049f9cdfbafa58454937b7fc4c38a5405b6e1375d762d88bbfae92b813cd2ec88a4e4108012137c94908894821575d3f6d2bf694e35d734f2b8fbd37

diff --git a/net-misc/owncloud-client/owncloud-client-2.2.4.ebuild b/net-misc/owncloud-client/owncloud-client-2.2.4.ebuild
new file mode 100644
index 00000000..244f59b
--- /dev/null
+++ b/net-misc/owncloud-client/owncloud-client-2.2.4.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="Synchronize files from ownCloud Server with your computer"
+HOMEPAGE="http://owncloud.org/"
+SRC_URI="http://download.owncloud.com/desktop/stable/${P/-}.tar.xz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc dolphin nautilus samba +sftp test qt4 +qt5"
+
+REQUIRED_USE="^^ ( qt4 qt5 )
+	dolphin? ( qt5 )"
+
+RDEPEND=">=dev-db/sqlite-3.4:3
+	sys-fs/inotify-tools
+	virtual/libiconv
+	dolphin? (
+		>=kde-frameworks/kcoreaddons-5.16:5
+		>=kde-frameworks/kio-5.16:5 )
+	nautilus? ( dev-python/nautilus-python )
+	qt4? (
+		dev-libs/qtkeychain[qt4]
+		dev-qt/qtcore:4
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4
+		dev-qt/qtsql:4
+		dev-qt/qtwebkit:4
+		net-libs/neon[ssl]
+	)
+	qt5? (
+		dev-libs/qtkeychain[qt5]
+		dev-qt/qtconcurrent:5
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		>=dev-qt/qtnetwork-5.4:5
+		dev-qt/qtgui:5
+		dev-qt/qtquickcontrols:5
+		dev-qt/qtsql:5
+		dev-qt/qtwebkit:5[printsupport]
+	)
+	samba? ( >=net-fs/samba-3.5 )
+	sftp? ( >=net-libs/libssh-0.5 )
+	!net-misc/ocsync
+	!net-misc/nextcloud-client"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/sphinx
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( >=kde-frameworks/extra-cmake-modules-5.22.0 )
+	qt5? ( dev-qt/linguist-tools:5 )
+	test? (
+		dev-util/cmocka
+		qt4? ( dev-qt/qttest:4 )
+		qt5? ( dev-qt/qttest:5 )
+	)"
+
+S=${WORKDIR}/${P/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die "sed failed"
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	default
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DWITH_ICONV=ON
+		-DWITH_DOC=$(usex doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DBUILD_WITH_QT4=$(usex qt4)
+		-DCMAKE_DISABLE_FIND_PACKAGE_Libsmbclient=$(usex !samba)
+		-DCMAKE_DISABLE_FIND_PACKAGE_LibSSH=$(usex !sftp)
+		-DUNIT_TESTING=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}