[gentoo-commits] gentoo-x86 commit in net-ftp/lftp: ChangeLog lftp-4.4.4.ebuild

[Jeroen Roovers (jer)]

jer         13/02/27 15:26:20

  Modified:             ChangeLog
  Added:                lftp-4.4.4.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.393                net-ftp/lftp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?rev=1.393&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?rev=1.393&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?r1=1.392&r2=1.393

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v
retrieving revision 1.392
retrieving revision 1.393
diff -u -r1.392 -r1.393
--- ChangeLog	11 Feb 2013 00:13:53 -0000	1.392
+++ ChangeLog	27 Feb 2013 15:26:20 -0000	1.393
@@ -1,6 +1,11 @@
 # ChangeLog for net-ftp/lftp
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.392 2013/02/11 00:13:53 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.393 2013/02/27 15:26:20 jer Exp $
+
+*lftp-4.4.4 (27 Feb 2013)
+
+  27 Feb 2013; Jeroen Roovers <jer@g.o> +lftp-4.4.4.ebuild:
+  Version bump.
 
 *lftp-4.4.3 (11 Feb 2013)
 



1.1                  net-ftp/lftp/lftp-4.4.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/lftp-4.4.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/lftp-4.4.4.ebuild?rev=1.1&content-type=text/plain

Index: lftp-4.4.4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/lftp-4.4.4.ebuild,v 1.1 2013/02/27 15:26:20 jer Exp $

EAPI=5
inherit autotools eutils libtool

DESCRIPTION="A sophisticated ftp/sftp/http/https/torrent client and file transfer program"
HOMEPAGE="http://lftp.yar.ru/"
SRC_URI="http://ftp.yars.free.net/pub/source/${PN}/${P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"

IUSE="gnutls nls socks5 +ssl"
LFTP_LINGUAS=( cs de es fr it ja ko pl pt_BR ru zh_CN zh_HK zh_TW )
IUSE+=" ${LFTP_LINGUAS[@]/#/linguas_}"

RDEPEND="
	dev-libs/expat
	>=sys-libs/ncurses-5.1
	socks5? (
		>=net-proxy/dante-1.1.12
		virtual/pam )
	ssl? (
		gnutls? ( >=net-libs/gnutls-1.2.3 )
		!gnutls? ( >=dev-libs/openssl-0.9.6 )
	)
	>=sys-libs/readline-5.1
"

DEPEND="
	${RDEPEND}
	=sys-devel/libtool-2*
	app-arch/xz-utils
	dev-lang/perl
	nls? ( sys-devel/gettext )
	virtual/pkgconfig
"

DOCS=(
	BUGS ChangeLog FAQ FEATURES MIRRORS NEWS README  README.debug-levels
	README.dnssec  README.modules THANKS TODO
)

src_prepare() {
	epatch \
		"${FILESDIR}/${PN}-4.0.2.91-lafile.patch" \
		"${FILESDIR}/${PN}-4.3.5-autopoint.patch" \
		"${FILESDIR}/${PN}-4.3.8-gets.patch"
	eautoreconf
	elibtoolize # for Darwin bundles
}

src_configure() {
	local myconf=""

	if use ssl && use gnutls ; then
		myconf="${myconf} --without-openssl"
	elif use ssl && ! use gnutls ; then
		myconf="${myconf} --without-gnutls --with-openssl=${EPREFIX}/usr"
	else
		myconf="${myconf} --without-gnutls --without-openssl"
	fi

	use socks5 && myconf="${myconf} --with-socksdante=${EPREFIX}/usr" \
		|| myconf="${myconf} --without-socksdante"

	econf \
		$(use_enable nls) \
		${myconf} \
		--enable-packager-mode \
		--sysconfdir="${EPREFIX}"/etc/${PN} \
		--with-modules \
		--without-included-regex
}