[gentoo-commits] repo/gentoo:master commit in: media-libs/vulkan-layers/

[Nick Sarnie]

commit:     45b3d9a3504572d45d174a15c49acb500db3f916
Author:     Nick Sarnie <sarnex <AT> gentoo <DOT> org>
AuthorDate: Wed Jun 22 23:06:16 2022 +0000
Commit:     Nick Sarnie <sarnex <AT> gentoo <DOT> org>
CommitDate: Wed Jun 22 23:12:34 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=45b3d9a3

media-libs/vulkan-layers: Version bump

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Nick Sarnie <sarnex <AT> gentoo.org>

 media-libs/vulkan-layers/Manifest                  |  1 +
 .../vulkan-layers/vulkan-layers-1.3.216.ebuild     | 55 ++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/media-libs/vulkan-layers/Manifest b/media-libs/vulkan-layers/Manifest
index 3a239f340465..7602c032cfac 100644
--- a/media-libs/vulkan-layers/Manifest
+++ b/media-libs/vulkan-layers/Manifest
@@ -1 +1,2 @@
 DIST vulkan-layers-1.3.211.tar.gz 3967709 BLAKE2B f86ff0fa053e0138a0bbdbec30e2fe0a59cfc24f43fe787b007ae352db81a700442d777637e1fc577332a47f36bc09383dd29416b5170fcf5d735562b6a58230 SHA512 e494ba793064f0d32fbdeaddaa01dcd730a36a5c793625bb4671a4e8067364171416ec8fb7361f946cc5d5e8dc16d58e2194c3eb5d3a57d58f4ace2e7ed34f5f
+DIST vulkan-layers-1.3.216.tar.gz 4036109 BLAKE2B 03772c0c34fb531366ad3f0e5610c21af013ed05b50f37eee20220385f3525f5a3ae0fcca5ab28b1cc0650057faf7a22db3f17b22187e09ddad7bd8425903ce4 SHA512 c3e3f44ddec4a440c759a5773cf8cabdb79e35152fd912b75ba7ef80126184fab7d0cd93e55e6f0a1b3fa5379295bf60dd21cbba97b3c24e753cd7b6ccb78f72

diff --git a/media-libs/vulkan-layers/vulkan-layers-1.3.216.ebuild b/media-libs/vulkan-layers/vulkan-layers-1.3.216.ebuild
new file mode 100644
index 000000000000..f1b3923e1bd1
--- /dev/null
+++ b/media-libs/vulkan-layers/vulkan-layers-1.3.216.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=Vulkan-ValidationLayers
+CMAKE_ECLASS="cmake"
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake-multilib python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	EGIT_SUBMODULES=()
+	inherit git-r3
+else
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/sdk-${PV}.0.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}"/${MY_PN}-sdk-${PV}.0
+fi
+
+DESCRIPTION="Vulkan Validation Layers"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-ValidationLayers"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="wayland X"
+
+BDEPEND=">=dev-util/cmake-3.10.2"
+RDEPEND="~dev-util/spirv-tools-${PV}:=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	>=dev-cpp/robin-hood-hashing-3.11.5
+	~dev-util/glslang-${PV}:=[${MULTILIB_USEDEP}]
+	~dev-util/vulkan-headers-${PV}
+	wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11:=[${MULTILIB_USEDEP}]
+		x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+	)
+"
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_C_FLAGS="${CFLAGS} -DNDEBUG"
+		-DCMAKE_CXX_FLAGS="${CXXFLAGS} -DNDEBUG"
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_LAYER_SUPPORT_FILES=ON
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DBUILD_TESTS=OFF
+		-DCMAKE_INSTALL_INCLUDEDIR="${EPREFIX}/usr/include/"
+	)
+	cmake_src_configure
+}