[gentoo-commits] repo/gentoo:master commit in: app-misc/ola/

[Marek Szuba]

commit:     72ba2fe5d4f79e637fdace7e0b3ff9559b682373
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 26 22:02:25 2023 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Sun Feb 26 22:03:09 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=72ba2fe5

app-misc/ola: add 0.10.9

Closes: https://bugs.gentoo.org/896592
Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 app-misc/ola/Manifest          |   1 +
 app-misc/ola/ola-0.10.9.ebuild | 110 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 111 insertions(+)

diff --git a/app-misc/ola/Manifest b/app-misc/ola/Manifest
index 8994df22e307..c98814f9b31a 100644
--- a/app-misc/ola/Manifest
+++ b/app-misc/ola/Manifest
@@ -1 +1,2 @@
 DIST ola-0.10.8.tar.gz 2552023 BLAKE2B b4fa7e36e2b907e8f0ea16ef089607fc223afc543752a03740fd1d525062ea676d2f392bb623804543827d6f5ac6078c469a3edcb4321bca9a454b1c219f9c89 SHA512 78ef8cc7f8e8d0b1d15bbb305d99a589fce82e07e89ca3bf2466bef8cdc1b18f590fc8dcbf29fc5af2349e0721c832f525fd665d62498907554ee742d79cd3d2
+DIST ola-0.10.9.tar.gz 2578760 BLAKE2B 8cace370b21788d0fe65e56d33fdc9436a5103837d370e3e7e07b43318d4ec3b29536b55c4b117f515a4698ebab88f58718759a0cf9a00f79d0b839e7a79d581 SHA512 e8e2f4249d6e1f63f6c36ae548d9e3a82080f0da82829f923ba6b4d63685fb89f9baccf4588fd6fcbf756708d91e27d022c0d623e7c03c84ec058e7dc7c46bdf

diff --git a/app-misc/ola/ola-0.10.9.ebuild b/app-misc/ola/ola-0.10.9.ebuild
new file mode 100644
index 000000000000..5cdbca6899a9
--- /dev/null
+++ b/app-misc/ola/ola-0.10.9.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit autotools python-single-r1
+
+DESCRIPTION="Open Lighting Architecture, a framework for lighting control information"
+HOMEPAGE="https://www.openlighting.org/ola/"
+SRC_URI="https://github.com/OpenLightingProject/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc examples ftdi http osc python rdm-tests tcmalloc test usb zeroconf"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+	rdm-tests? ( python )"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-libs/protobuf:=
+	sys-apps/util-linux
+	sys-libs/ncurses
+	ftdi? ( dev-embedded/libftdi:1 )
+	http? ( net-libs/libmicrohttpd:= )
+	osc? ( media-libs/liblo )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/protobuf-python[${PYTHON_USEDEP}]
+		')
+	)
+	rdm-tests? (
+		$(python_gen_cond_dep '
+			dev-python/numpy[${PYTHON_USEDEP}]
+		')
+	)
+	tcmalloc? ( dev-util/google-perftools:= )
+	usb? ( virtual/libusb:1 )
+	zeroconf? ( net-dns/avahi )"
+DEPEND="${RDEPEND}
+	sys-kernel/linux-headers"
+BDEPEND="sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen
+		media-gfx/graphviz
+	)
+	test? (
+		dev-util/cppunit
+		python? (
+			${PYTHON_DEPS}
+			$(python_gen_cond_dep '
+				dev-python/numpy[${PYTHON_USEDEP}]
+				dev-python/protobuf-python[${PYTHON_USEDEP}]
+			')
+		)
+	)"
+
+src_prepare() {
+	default
+	# Upstream recommends doing this even for tarball builds
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-fatal-warnings
+		--with-uucp-lock="/run"
+		$(use_enable doc doxygen-doc)
+		$(use_enable doc doxygen-dot)
+		$(use_enable examples)
+		$(use_enable ftdi libftdi)
+		$(use_enable http)
+		$(use_enable osc)
+		$(use_enable python python-libs)
+		$(use_enable rdm-tests)
+		$(use_enable tcmalloc)
+		$(use_enable test unittests)
+		$(use_enable usb libusb)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+	use doc && emake doxygen-doc
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+
+	if use doc; then
+		dodoc -r html
+		docompress -x /usr/share/doc/${PF}/html
+	fi
+
+	if use examples && use python; then
+		docinto examples
+		python_fix_shebang python/examples/*.py
+		dodoc python/examples/*.py
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}