[gentoo-commits] repo/proj/guru:dev commit in: app-misc/fastfetch/

[Viorel Munteanu]

commit:     01e1c6d6026a20c700ee4937c20f9fd8e6d470d5
Author:     Viorel Munteanu <ceamac.paragon <AT> gmail <DOT> com>
AuthorDate: Thu Mar 31 17:19:31 2022 +0000
Commit:     Viorel Munteanu <ceamac.paragon <AT> gmail <DOT> com>
CommitDate: Thu Mar 31 17:19:31 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=01e1c6d6

app-misc/fastfetch: add 1.2.3

Signed-off-by: Viorel Munteanu <ceamac.paragon <AT> gmail.com>

 app-misc/fastfetch/Manifest               |  1 +
 app-misc/fastfetch/fastfetch-1.2.3.ebuild | 56 +++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index df6cd5ea0..c91a17992 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1 +1,2 @@
 DIST fastfetch-1.1.0.tar.gz 327601 BLAKE2B d3fca85fba1ac51540dde8a2ca9fed5ebe1e1c288d6e8aae2db5ad09cc149cfb218699a4825673c8c0160849493ee035243ad520143dd6106b0090a0418f538f SHA512 6273592c422a8a7740c8719bb9b6cad3b583b14ebdc14c7d4abc2ea51c24164cdf84976109df41d99df5385d2627d67a8be1ede04a7c1ac852da1e131c1fc362
+DIST fastfetch-1.2.3.tar.gz 328561 BLAKE2B d52ba5a41eda9cd12cca01ae0387854586f7e3d5594155a20c22fa311b919ade7f71b089c39eb8044ebfb38b486c5d259a1b9f6a671ac7c60e2b36ca5f9d21c5 SHA512 239f695239a181ffb3b1b8d836d67e2876d2e7bfa9d75f3dc74c615e5497e510d1610347b72e3a8a1c31295fd48f6cad4f108592e2cdc9261f209318ca74b154

diff --git a/app-misc/fastfetch/fastfetch-1.2.3.ebuild b/app-misc/fastfetch/fastfetch-1.2.3.ebuild
new file mode 100644
index 000000000..414ee9c3d
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-1.2.3.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Like neofetch but faster"
+HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/LinusDierheimer/fastfetch.git"
+else
+	SRC_URI="https://github.com/LinusDierheimer/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="X gnome pci vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	X? ( x11-libs/libX11 )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	pci? ( sys-apps/pciutils )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="xrandr? ( X )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_XFCONF=$(usex xfce)
+	)
+
+	cmake_src_configure
+}