[gentoo-commits] repo/gentoo:master commit in: dev-libs/libinput/

[Lars Wendler]

commit:     63e79c925af4d7c9b3c33c02bd9af78a06996ee1
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 16 08:22:15 2018 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Oct 16 08:26:02 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=63e79c92

dev-libs/libinput: Revbump to fix build with USE="doc".

Revbump because a new dependency is required that has only
amd64 and x86 keywords.

Closes: https://bugs.gentoo.org/668620
Closes: https://bugs.gentoo.org/665722
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 dev-libs/libinput/libinput-1.12.1-r1.ebuild | 62 +++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/dev-libs/libinput/libinput-1.12.1-r1.ebuild b/dev-libs/libinput/libinput-1.12.1-r1.ebuild
new file mode 100644
index 00000000000..35d61bb2738
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.12.1-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit meson udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/10"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc input_devices_wacom"
+# Tests require write access to udev rules directory which is a no-no for live system.
+# Other tests are just about logs, exported symbols and autotest of the test library.
+RESTRICT="test"
+
+RDEPEND="
+	input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
+	>=dev-libs/libevdev-1.3
+	>=sys-libs/mtdev-1.1
+	virtual/libudev:=
+	virtual/udev
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? (
+		dev-python/recommonmark
+		dev-python/sphinx
+		>=app-doc/doxygen-1.8.3
+		>=media-gfx/graphviz-2.38.0
+	)
+"
+#	test? (
+#		>=dev-libs/check-0.9.10
+#		dev-util/valgrind
+#		sys-libs/libunwind )
+
+src_configure() {
+	# gui can be built but will not be installed
+	local emesonargs=(
+		-Ddebug-gui=false
+		$(meson_use doc documentation)
+		$(meson_use input_devices_wacom libwacom)
+		-Dtests=false # tests are restricted
+		-Dudev-dir="$(get_udevdir)"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc ; then
+		docinto html
+		dodoc -r "${BUILD_DIR}"/Documentation/.
+	fi
+}
+
+pkg_postinst() {
+	udevadm hwdb --update --root="${ROOT%/}"
+}