[gentoo-commits] gentoo-x86 commit in app-portage/layman: ChangeLog layman-1.2.4-r1.ebuild

[Sebastian Pipping (sping)]

sping       10/01/01 00:58:18

  Modified:             ChangeLog
  Added:                layman-1.2.4-r1.ebuild
  Log:
  app-portage/layman: Integrate patch for bug #295018
  (Portage version: 2.2_rc61/cvs/Linux i686)

Revision  Changes    Path
1.83                 app-portage/layman/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/ChangeLog?rev=1.83&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/ChangeLog?rev=1.83&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/ChangeLog?r1=1.82&r2=1.83

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v
retrieving revision 1.82
retrieving revision 1.83
diff -u -r1.82 -r1.83
--- ChangeLog	30 Dec 2009 22:23:44 -0000	1.82
+++ ChangeLog	1 Jan 2010 00:58:18 -0000	1.83
@@ -1,6 +1,12 @@
 # ChangeLog for app-portage/layman
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.82 2009/12/30 22:23:44 sping Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.83 2010/01/01 00:58:18 sping Exp $
+
+*layman-1.2.4-r1 (01 Jan 2010)
+
+  01 Jan 2010; Sebastian Pipping <sping@g.o> +layman-1.2.4-r1.ebuild,
+  +files/layman-1.2.4-peg-backport.patch:
+  Integrate 1.2.4 backport patch for bug #295018
 
   30 Dec 2009; Sebastian Pipping <sping@g.o> layman-1.1.1.ebuild,
   layman-1.2.3.ebuild, layman-1.2.4.ebuild, layman-9999.ebuild:



1.1                  app-portage/layman/layman-1.2.4-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/layman-1.2.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-portage/layman/layman-1.2.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: layman-1.2.4-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/layman-1.2.4-r1.ebuild,v 1.1 2010/01/01 00:58:18 sping Exp $

EAPI="2"
NEED_PYTHON=2.5
SUPPORT_PYTHON_ABIS="1"

inherit eutils distutils

DESCRIPTION="A python script for retrieving gentoo overlays."
HOMEPAGE="http://layman.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="git subversion test"

COMMON_DEPS="|| (
	dev-lang/python[xml]
	( dev-lang/python dev-python/pyxml ) )"
DEPEND="${COMMON_DEPS}
	test? ( dev-util/subversion )"
RDEPEND="${COMMON_DEPS}
	git? ( dev-util/git )
	subversion? (
		|| (
			>=dev-util/subversion-1.5.4[webdav-neon]
			>=dev-util/subversion-1.5.4[webdav-serf]
		)
	)"
RESTRICT_PYTHON_ABIS="2.4 3.*"

src_prepare() {
	epatch "${FILESDIR}"/${P}-peg-backport.patch
}

pkg_setup() {
	if ! has_version dev-util/subversion; then
		ewarn "You do not have dev-util/subversion installed!"
		ewarn "While layman does not exactly depend on this"
		ewarn "version control system you should note that"
		ewarn "most available overlays are offered via"
		ewarn "dev-util/subversion. If you do not install it"
		ewarn "you will be unable to use these overlays."
		ewarn
	fi
}

src_test() {
	testing() {
		PYTHONPATH="." "$(PYTHON)" layman/tests/dtest.py
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install

	dodir /etc/layman

	cp etc/* "${D}"/etc/layman/

	doman doc/layman.8
	dohtml doc/layman.8.html

	keepdir /usr/local/portage/layman
}

pkg_postinst() {
	distutils_pkg_postinst

	einfo "You are now ready to add overlays into your system."
	einfo
	einfo "layman -L"
	einfo
	einfo "will display a list of available overlays."
	einfo
	elog  "Select an overlay and add it using"
	einfo
	elog  "layman -a overlay-name"
	einfo
	elog  "If this is the very first overlay you add with layman,"
	elog  "you need to append the following statement to your"
	elog  "/etc/make.conf file:"
	elog
	elog  "source /usr/local/portage/layman/make.conf"
	elog
	elog  "If you modify the 'storage' parameter in the layman"
	elog  "configuration file (/etc/layman/layman.cfg) you will"
	elog  "need to adapt the path given above to the new storage"
	elog  "directory."
	einfo
	ewarn "Please add the 'source' statement to make.conf only AFTER "
	ewarn "you added your first overlay. Otherwise portage will fail."
	epause 5
}