[gentoo-commits] gentoo-x86 commit in media-sound/pulseaudio: pulseaudio-0.9.16_rc3-r51.ebuild pulseaudio-0.9.16_rc3.ebuild pulseaudio-0.9.15-r51.ebuild ChangeLog metadata.xml pulseaudio-0.9.16_rc2-r50.ebuild pulseaudio-0.9.16_rc2-r1.ebuild pulseaudio-0.9.16_rc2-r51.ebuild pulseaudio-0.9.15-r50.ebuild pulseaudio-0.9.15-r1.ebuild pulseaudio-0.9.16_rc2-r2.ebuild pulseaudio-0.9.9.ebuild

[Diego Petteno (flameeyes)]

flameeyes    09/07/30 13:27:22

  Modified:             pulseaudio-0.9.15-r51.ebuild ChangeLog metadata.xml
  Added:                pulseaudio-0.9.16_rc3-r51.ebuild
                        pulseaudio-0.9.16_rc3.ebuild
  Removed:              pulseaudio-0.9.16_rc2-r50.ebuild
                        pulseaudio-0.9.16_rc2-r1.ebuild
                        pulseaudio-0.9.16_rc2-r51.ebuild
                        pulseaudio-0.9.15-r50.ebuild
                        pulseaudio-0.9.15-r1.ebuild
                        pulseaudio-0.9.16_rc2-r2.ebuild
                        pulseaudio-0.9.9.ebuild
  Log:
  Bump to the latest test version, add udev support (that was missing before), remove old versions while I'm at it.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  media-sound/pulseaudio/pulseaudio-0.9.15-r51.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.15-r51.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.15-r51.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.15-r51.ebuild?r1=1.2&r2=1.3

Index: pulseaudio-0.9.15-r51.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.15-r51.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- pulseaudio-0.9.15-r51.ebuild	22 Jul 2009 18:30:53 -0000	1.2
+++ pulseaudio-0.9.15-r51.ebuild	30 Jul 2009 13:27:22 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.15-r51.ebuild,v 1.2 2009/07/22 18:30:53 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.15-r51.ebuild,v 1.3 2009/07/30 13:27:22 flameeyes Exp $
 
 EAPI=2
 
@@ -132,6 +132,7 @@
 		$(use_define avahi) \
 		$(use_define alsa) \
 		$(use_define bluetooth) \
+		-UUDEV \
 		"${FILESDIR}/pulseaudio.init.d-4" \
 		> "${T}/pulseaudio"
 



1.138                media-sound/pulseaudio/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.138&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/ChangeLog?rev=1.138&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/ChangeLog?r1=1.137&r2=1.138

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v
retrieving revision 1.137
retrieving revision 1.138
diff -u -r1.137 -r1.138
--- ChangeLog	22 Jul 2009 18:30:53 -0000	1.137
+++ ChangeLog	30 Jul 2009 13:27:22 -0000	1.138
@@ -1,6 +1,19 @@
 # ChangeLog for media-sound/pulseaudio
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.137 2009/07/22 18:30:53 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/ChangeLog,v 1.138 2009/07/30 13:27:22 flameeyes Exp $
+
+*pulseaudio-0.9.16_rc3-r51 (30 Jul 2009)
+*pulseaudio-0.9.16_rc3 (30 Jul 2009)
+
+  30 Jul 2009; Diego E. Pettenò <flameeyes@g.o>
+  -pulseaudio-0.9.9.ebuild, -pulseaudio-0.9.15-r1.ebuild,
+  -pulseaudio-0.9.15-r50.ebuild, pulseaudio-0.9.15-r51.ebuild,
+  -pulseaudio-0.9.16_rc2-r1.ebuild, -pulseaudio-0.9.16_rc2-r2.ebuild,
+  -pulseaudio-0.9.16_rc2-r50.ebuild, -pulseaudio-0.9.16_rc2-r51.ebuild,
+  +pulseaudio-0.9.16_rc3.ebuild, +pulseaudio-0.9.16_rc3-r51.ebuild,
+  files/pulseaudio.init.d-4, metadata.xml:
+  Bump to the latest test version, add udev support (that was missing
+  before), remove old versions while I'm at it.
 
   22 Jul 2009; Diego E. Pettenò <flameeyes@g.o>
   pulseaudio-0.9.15-r2.ebuild, pulseaudio-0.9.15-r51.ebuild,



1.6                  media-sound/pulseaudio/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	3 Jul 2009 00:14:32 -0000	1.5
+++ metadata.xml	30 Jul 2009 13:27:22 -0000	1.6
@@ -27,6 +27,11 @@
       libpulse client library, to allow using libpulse on glib-based
       programs.
     </flag>
+    <flag name="udev">
+      Use <pkg>sys-fs/udev</pkg> for autodiscovery of sound devices;
+      this replaces the deprecated <pkg>sys-apps/hal</pkg>
+      autodiscovery code.
+    </flag>
     <flag name="asyncns">Use libasyncns for asynchronous name resolution.</flag>
     <flag name="glib">Enable glib eventloop support</flag>
     <flag name="policykit">Enable support for PolicyKit framework.</flag>



1.1                  media-sound/pulseaudio/pulseaudio-0.9.16_rc3-r51.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.16_rc3-r51.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.16_rc3-r51.ebuild?rev=1.1&content-type=text/plain

Index: pulseaudio-0.9.16_rc3-r51.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.16_rc3-r51.ebuild,v 1.1 2009/07/30 13:27:22 flameeyes Exp $

EAPI=2

inherit eutils libtool flag-o-matic

MY_P=${P/_rc/-test}

DESCRIPTION="A networked sound server with an advanced plugin system"
HOMEPAGE="http://www.pulseaudio.org/"
SRC_URI="http://0pointer.de/public/${MY_P}.tar.gz"

S="${WORKDIR}/${MY_P}"

LICENSE="LGPL-2 GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="alsa avahi caps jack lirc oss tcpd X hal dbus libsamplerate gnome bluetooth policykit asyncns +glib test doc udev"

RDEPEND="X? ( x11-libs/libX11 x11-libs/libSM x11-libs/libICE x11-libs/libXtst )
	caps? ( sys-libs/libcap )
	libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
	alsa? ( >=media-libs/alsa-lib-1.0.19 )
	glib? ( >=dev-libs/glib-2.4.0 )
	avahi? ( >=net-dns/avahi-0.6.12[dbus] )
	>=dev-libs/liboil-0.3.0
	jack? ( >=media-sound/jack-audio-connection-kit-0.100 )
	tcpd? ( sys-apps/tcp-wrappers )
	lirc? ( app-misc/lirc )
	dbus? ( >=sys-apps/dbus-1.0.0 )
	gnome? ( >=gnome-base/gconf-2.4.0 )
	hal? (
		>=sys-apps/hal-0.5.7
		>=sys-apps/dbus-1.0.0
	)
	app-admin/eselect-esd
	bluetooth? (
		|| ( >=net-wireless/bluez-4
			 >=net-wireless/bluez-libs-3 )
		>=sys-apps/dbus-1.0.0
	)
	policykit? ( sys-auth/policykit )
	asyncns? ( net-libs/libasyncns )
	udev? ( >=sys-fs/udev-143 )
	>=media-libs/audiofile-0.2.6-r1
	>=media-libs/speex-1.2_beta
	>=media-libs/libsndfile-1.0.10
	>=dev-libs/liboil-0.3.6
	sys-libs/gdbm
	>=sys-devel/libtool-2.2.4" # it's a valid RDEPEND, libltdl.so is used

DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	X? ( x11-proto/xproto )
	dev-libs/libatomic_ops
	dev-util/pkgconfig
	|| ( dev-util/unifdef sys-freebsd/freebsd-ubin )
	dev-util/intltool"

# alsa-utils dep is for the alsasound init.d script (see bug #155707)
# bluez-utils dep is for the bluetooth init.d script
RDEPEND="${RDEPEND}
	sys-apps/openrc
	gnome-extra/gnome-audio
	alsa? ( media-sound/alsa-utils )
	bluetooth? (
	|| ( >=net-wireless/bluez-4
		 >=net-wireless/bluez-utils-3 ) )"

pkg_setup() {
	enewgroup audio 18 # Just make sure it exists
	enewgroup pulse-access
	enewgroup pulse
	enewuser pulse -1 -1 /var/run/pulse pulse,audio

	if use udev && use hal; then
		elog "Please note that enabling both udev and hal will build both"
		elog "discover modules, but only udev will be ued automatically."
		elog "If you wish to use hal you have to enable it explicitly"
		elog "or you might just disable the hal USE flag entirely."
	fi
}

src_prepare() {
	elibtoolize
}

src_configure() {
	# To properly fix CVE-2008-0008
	append-flags -UNDEBUG

	# It's a binutils bug, once I can find time to fix that I'll add a
	# proper dependency and fix this up. — flameeyes
	append-ldflags -Wl,--no-as-needed

	# udev is disabled because we don't have the right version just
	# yet, and thus we need to avoid it for now. Once we have the
	# version I'll revbump PA. — flameeyes
	econf \
		--enable-largefile \
		$(use_enable glib glib2) \
		--disable-solaris \
		$(use_enable asyncns) \
		$(use_enable oss) \
		$(use_enable alsa) \
		$(use_enable lirc) \
		$(use_enable tcpd tcpwrap) \
		$(use_enable jack) \
		$(use_enable lirc) \
		$(use_enable avahi) \
		$(use_enable hal) \
		$(use_enable dbus) \
		$(use_enable gnome gconf) \
		$(use_enable libsamplerate samplerate) \
		$(use_enable bluetooth bluez) \
		$(use_enable X x11) \
		$(use_enable test default-build-tests) \
		$(use_with caps) \
		$(use_enable udev) \
		--localstatedir=/var \
		--disable-per-user-esound-socket \
		--with-database=gdbm \
		|| die "econf failed"

	if use doc; then
		pushd doxygen
		doxygen doxygen.conf || die
		popd
	fi
}

src_install() {
	emake -j1 DESTDIR="${D}" install || die "make install failed"

	newconfd "${FILESDIR}/pulseaudio.conf.d" pulseaudio

	use_define() {
		local define=${2:-$(echo $1 | tr '[:lower:]' '[:upper:]')}

		use "$1" && echo "-D$define" || echo "-U$define"
	}

	unifdef $(use_define hal) \
		$(use_define avahi) \
		$(use_define alsa) \
		$(use_define bluetooth) \
		$(use_define udev) \
		"${FILESDIR}/pulseaudio.init.d-4" \
		> "${T}/pulseaudio"

	doinitd "${T}/pulseaudio"

	use avahi && sed -i -e '/module-zeroconf-publish/s:^#::' "${D}/etc/pulse/default.pa"

	if use hal && !use udev; then
		sed -i -e 's:-udev:-hal:' "${D}/etc/pulse/default.pa" || die
	fi

	dodoc README ChangeLog todo || die

	if use doc; then
		pushd doxygen/html
		dohtml * || die
		popd
	fi

	# Create the state directory
	diropts -o pulse -g pulse -m0755
	keepdir /var/run/pulse

	find "${D}" -name '*.la' -delete
}

pkg_postinst() {
	elog "PulseAudio in Gentoo can use a system-wide pulseaudio daemon."
	elog "This support is enabled by starting the pulseaudio init.d ."
	elog "To be able to access that you need to be in the group pulse-access."
	elog "If you choose to use this feature, please make sure that you"
	elog "really want to run PulseAudio this way:"
	elog "   http://pulseaudio.org/wiki/WhatIsWrongWithSystemMode"
	elog "For more information about system-wide support, please refer to:"
	elog "	 http://pulseaudio.org/wiki/SystemWideInstance"
	if use gnome; then
		elog
		elog "By enabling gnome USE flag, you enabled gconf support. Please note"
		elog "that you might need to remove the gnome USE flag or disable the"
		elog "gconf module on /etc/pulse/system.pa to be able to use PulseAudio"
		elog "with a system-wide instance."
	fi
	elog
	elog "To use the ESounD wrapper while using a system-wide daemon, you also"
	elog "need to enable auth-anonymous for the esound-unix module, or to copy"
	elog "/var/run/pulse/.esd_auth into each home directory."
	elog
	if use bluetooth; then
		elog
		elog "The BlueTooth proximity module is not enabled in the default"
		elog "configuration file. If you do enable it, you'll have to have"
		elog "your BlueTooth controller enabled and inserted at bootup or"
		elog "PulseAudio will refuse to start."
		elog
		elog "Please note that the BlueTooth proximity module seems itself"
		elog "still experimental, so please report to upstream if you have"
		elog "problems with it."
	fi
	if use alsa; then
		local pkg="media-plugins/alsa-plugins"
		if has_version ${pkg} && ! built_with_use --missing false ${pkg} pulseaudio; then
			elog
			elog "You have alsa support enabled so you probably want to install"
			elog "${pkg} with pulseaudio support to have"
			elog "alsa using applications route their sound through pulseaudio"
		fi
	fi

	eselect esd update --if-unset
}



1.1                  media-sound/pulseaudio/pulseaudio-0.9.16_rc3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.16_rc3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.16_rc3.ebuild?rev=1.1&content-type=text/plain

Index: pulseaudio-0.9.16_rc3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/pulseaudio/pulseaudio-0.9.16_rc3.ebuild,v 1.1 2009/07/30 13:27:22 flameeyes Exp $

EAPI=2

inherit eutils libtool flag-o-matic

DESCRIPTION="A networked sound server with an advanced plugin system"
HOMEPAGE="http://www.pulseaudio.org/"
if [[ ${PV/_rc/} == ${PV} ]]; then
	SRC_URI="http://0pointer.de/lennart/projects/${PN}/${P}.tar.gz"
else
	SRC_URI="http://0pointer.de/public/${P/_rc/-test}.tar.gz"
fi

S="${WORKDIR}/${P/_rc/-test}"

LICENSE="LGPL-2 GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="alsa avahi caps jack lirc oss tcpd X hal dbus libsamplerate gnome bluetooth policykit asyncns +glib test doc udev"

RDEPEND="X? ( x11-libs/libX11 x11-libs/libSM x11-libs/libICE x11-libs/libXtst )
	caps? ( sys-libs/libcap )
	libsamplerate? ( >=media-libs/libsamplerate-0.1.1-r1 )
	alsa? ( >=media-libs/alsa-lib-1.0.19 )
	glib? ( >=dev-libs/glib-2.4.0 )
	avahi? ( >=net-dns/avahi-0.6.12[dbus] )
	>=dev-libs/liboil-0.3.0
	jack? ( >=media-sound/jack-audio-connection-kit-0.100 )
	tcpd? ( sys-apps/tcp-wrappers )
	lirc? ( app-misc/lirc )
	dbus? ( >=sys-apps/dbus-1.0.0 )
	gnome? ( >=gnome-base/gconf-2.4.0 )
	hal? (
		>=sys-apps/hal-0.5.7
		>=sys-apps/dbus-1.0.0
	)
	app-admin/eselect-esd
	bluetooth? (
		|| ( >=net-wireless/bluez-4
			 >=net-wireless/bluez-libs-3 )
		>=sys-apps/dbus-1.0.0
	)
	policykit? ( sys-auth/policykit )
	asyncns? ( net-libs/libasyncns )
	udev? ( >=sys-fs/udev-143 )
	>=media-libs/audiofile-0.2.6-r1
	>=media-libs/speex-1.2_beta
	>=media-libs/libsndfile-1.0.10
	>=dev-libs/liboil-0.3.6
	sys-libs/gdbm
	>=sys-devel/libtool-2.2.4" # it's a valid RDEPEND, libltdl.so is used

DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	X? ( x11-proto/xproto )
	dev-libs/libatomic_ops
	dev-util/pkgconfig
	dev-util/intltool"

RDEPEND="${RDEPEND}
	gnome-extra/gnome-audio"

pkg_setup() {
	enewgroup audio 18 # Just make sure it exists
	enewgroup realtime
	enewgroup pulse-access
	enewgroup pulse
	enewuser pulse -1 -1 /var/run/pulse pulse,audio

	if use udev && use hal; then
		elog "Please note that enabling both udev and hal will build both"
		elog "discover modules, but only udev will be ued automatically."
		elog "If you wish to use hal you have to enable it explicitly"
		elog "or you might just disable the hal USE flag entirely."
	fi
}

src_prepare() {
	elibtoolize
}

src_configure() {
	# To properly fix CVE-2008-0008
	append-flags -UNDEBUG

	append-ldflags -Wl,--no-as-needed

	econf \
		--enable-largefile \
		$(use_enable glib glib2) \
		--disable-solaris \
		$(use_enable asyncns) \
		$(use_enable oss) \
		$(use_enable alsa) \
		$(use_enable lirc) \
		$(use_enable tcpd tcpwrap) \
		$(use_enable jack) \
		$(use_enable lirc) \
		$(use_enable avahi) \
		$(use_enable hal) \
		$(use_enable dbus) \
		$(use_enable gnome gconf) \
		$(use_enable libsamplerate samplerate) \
		$(use_enable bluetooth bluez) \
		$(use_enable policykit polkit) \
		$(use_enable X x11) \
		$(use_enable test default-build-tests) \
		$(use_enable udev) \
		$(use_with caps) \
		--localstatedir=/var \
		--with-realtime-group=realtime \
		--disable-per-user-esound-socket \
		|| die "econf failed"

	if use doc; then
		pushd doxygen
		doxygen doxygen.conf || die
		popd
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"

	use avahi && sed -i -e '/module-zeroconf-publish/s:^#::' "${D}/etc/pulse/default.pa"

	if use hal && !use udev; then
		sed -i -e 's:-udev:-hal:' "${D}/etc/pulse/default.pa" || die
	fi

	dodoc README ChangeLog todo || die

	if use doc; then
		pushd doxygen/html
		dohtml * || die
		popd
	fi

	# Create the state directory
	diropts -o pulse -g pulse -m0755
	keepdir /var/run/pulse

	find "${D}" -name '*.la' -delete
}

pkg_postinst() {
	elog "If you want to make use of realtime capabilities of PulseAudio"
	elog "you should follow the realtime guide to create and set up a realtime"
	elog "user group: http://www.gentoo.org/proj/en/desktop/sound/realtime.xml"
	elog "Make sure you also have baselayout installed with pam USE flag"
	elog "enabled, if you're using the rlimit method."
	if use bluetooth; then
		elog
		elog "The BlueTooth proximity module is not enabled in the default"
		elog "configuration file. If you do enable it, you'll have to have"
		elog "your BlueTooth controller enabled and inserted at bootup or"
		elog "PulseAudio will refuse to start."
		elog
		elog "Please note that the BlueTooth proximity module seems itself"
		elog "still experimental, so please report to upstream if you have"
		elog "problems with it."
	fi
	if use alsa; then
		local pkg="media-plugins/alsa-plugins"
		if has_version ${pkg} && ! built_with_use --missing false ${pkg} pulseaudio; then
			elog
			elog "You have alsa support enabled so you probably want to install"
			elog "${pkg} with pulseaudio support to have"
			elog "alsa using applications route their sound through pulseaudio"
		fi
	fi

	eselect esd update --if-unset
}