[gentoo-commits] repo/gentoo:master commit in: net-libs/libtrace/files/, net-libs/libtrace/

[Jeroen Roovers]

commit:     7f7c94aee5a43251ac2812993d0c7ab51f0d17a2
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 20 09:01:15 2019 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Tue Aug 20 09:02:26 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7f7c94ae

net-libs/libtrace: Add include for SIOCGSTAMP definition

Package-Manager: Portage-2.3.72, Repoman-2.3.17
Fixes: https://bugs.gentoo.org/692430
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 .../files/libtrace-4.0.9_p1-SIOCGSTAMP.patch       | 12 +++++
 net-libs/libtrace/libtrace-4.0.9_p1-r1.ebuild      | 61 ++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/net-libs/libtrace/files/libtrace-4.0.9_p1-SIOCGSTAMP.patch b/net-libs/libtrace/files/libtrace-4.0.9_p1-SIOCGSTAMP.patch
new file mode 100644
index 00000000000..0693601356b
--- /dev/null
+++ b/net-libs/libtrace/files/libtrace-4.0.9_p1-SIOCGSTAMP.patch
@@ -0,0 +1,12 @@
+diff --git a/lib/format_linux_common.h b/lib/format_linux_common.h
+index 244144b1..b6a66d30 100644
+--- a/lib/format_linux_common.h
++++ b/lib/format_linux_common.h
+@@ -44,6 +44,7 @@
+ #include <netpacket/packet.h>
+ #include <net/ethernet.h>
+ #include <net/if_arp.h>
++#include <linux/sockios.h>
+ 
+ #include <net/if.h>
+ #include <sys/ioctl.h>

diff --git a/net-libs/libtrace/libtrace-4.0.9_p1-r1.ebuild b/net-libs/libtrace/libtrace-4.0.9_p1-r1.ebuild
new file mode 100644
index 00000000000..84bdf221362
--- /dev/null
+++ b/net-libs/libtrace/libtrace-4.0.9_p1-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools
+
+DESCRIPTION="A library and tools for trace processing"
+HOMEPAGE="https://research.wand.net.nz/software/libtrace.php"
+SRC_URI="https://github.com/${PN^}Team/${PN}/archive//${PV/_p/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc ncurses numa static-libs"
+
+RDEPEND="
+	>=net-libs/libpcap-0.8
+	dev-libs/libyaml
+	dev-libs/openssl:0=
+	net-libs/wandio
+	ncurses? ( sys-libs/ncurses:0= )
+	numa? ( sys-process/numactl )
+"
+DEPEND="
+	${RDEPEND}
+	app-doc/doxygen
+	sys-devel/flex
+	virtual/os-headers
+	virtual/pkgconfig
+	virtual/yacc
+"
+PATCHES=(
+		"${FILESDIR}"/${PN}-3.0.20-autoconf-1.13.patch
+		"${FILESDIR}"/${PN}-4.0.0-no-examples.patch
+		"${FILESDIR}"/${PN}-4.0.0-with-numa.patch
+		"${FILESDIR}"/${PN}-4.0.9_p1-tinfo.patch
+		"${FILESDIR}"/${PN}-4.0.9_p1-SIOCGSTAMP.patch
+)
+S=${WORKDIR}/${P/_p/-}
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with ncurses) \
+		$(use_with numa) \
+		--with-man
+}
+
+src_install() {
+	default
+
+	use doc && dodoc -r docs/doxygen/html
+
+	find "${D}" -name "*.la" -delete || die
+}