[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     db9b471496b5e0e6eedaddd91efe6efc01dd8a21
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 13 03:43:43 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Oct 13 03:43:56 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=db9b4714

sys-kernel/gentoo-kernel-bin: add 5.10.72-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.10.72-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 074f18793f2..5e1e883a61f 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -43,6 +43,7 @@ DIST gentoo-kernel-5.10.71-1.amd64.xpak 65531448 BLAKE2B a452aa65c53ddc469f7b62e
 DIST gentoo-kernel-5.10.71-1.arm64.xpak 61260000 BLAKE2B 43c44a2f34445f28cd4748e94a416d680c51ad98dc19d521ca8b6a55847c8ca59dadacc02c1f3f74159c070bbf8a25c3418f0bdd9713c05abc23d8587db84703 SHA512 ae21250d1db987af750af20b079359cab76c5a149ca55324a007e070a5c6fd1a50189d109efafc10fe8434be6b8587da9e8dbe445b74d936fdeba41ad87d9ece
 DIST gentoo-kernel-5.10.71-1.x86.xpak 57265156 BLAKE2B a9eaca5de9ef3883863cab33773d63569accaa2095e9725f37181fb2d05435717ff9562faf6d4bdf76625c554a13378c6ca84e7b60bb81df236633d2d0e9ec44 SHA512 19f6de9ca4190255be47f0cd0bb53367df9114d961e2fbda081962647b3c71e5f7cb0df22bad5e92d2d7647fe163d4dcfb7a517b0be783c80e61259589c63703
 DIST gentoo-kernel-5.10.72-1.amd64.xpak 65501066 BLAKE2B c4f9d43fd17a73addb6db65f62f68ab18d49937581e833abc1653cf41a70980bff0b1fa9332e8f13a5acb7c4918e226a24ea0f96b2a874c63a2cbfa37dc0116e SHA512 6bba12624a100b892d939bcc39e4324866dc9393dac34e1fa296fa92393b392517f7aeeac2503e8066b937d0f8002be14f499c0633d8c62d45324a4ab63c1d44
+DIST gentoo-kernel-5.10.72-1.arm64.xpak 61226946 BLAKE2B 09501bbb9146450bb25d3dc89422f14286351e86b3482bdf351a86a21883ba07117a1dedcf6d218eacfb0468e1e92af724ae898a4fac0b088e8690d86c783841 SHA512 7a9e5c2c8f26900abec2337295a225911478191f1a3088226821779177326735b7987bf3646647594dd3e17a83be857f4addc05445906b851c3583f0fe2da84d
 DIST gentoo-kernel-5.10.72-1.x86.xpak 57243325 BLAKE2B 019dd95e8fab63f6010ded8f726119a46780ddde160509730974773afde6eb9fe2c339d33c8b8b3c0212671e0355048018365681bbd8ef6664771288d6b48c0f SHA512 16fbdc50a198b275e1931ee183ce51e05ebc989bed7102020cc03090ee2d757f6f1879f06899ba683ebd030465022aed76873b03c0541c2231d59370f3675136
 DIST gentoo-kernel-5.13.19-1.amd64.xpak 67338326 BLAKE2B d9e718a94bf9a341f5b57063cbde2f3f1f0ea6d03f1805051c084b792388789494a49786d643f1570871ca2b6366a206497aed83f9ed00837c542ac970a71fc6 SHA512 aea74f6f39861752f7a5dae16d955d541f65d3e7b8a0e5fba593011d9ca8583f3dd0964e76aa21daa6583d5d26e3616885aeca8a04dbba222e0aae2a85062b40
 DIST gentoo-kernel-5.13.19-1.arm64.xpak 62747957 BLAKE2B 1981ddb4e35d2210e1c678856ac58e088cd100ecbd70d2b5c88ffe8eb25b56f3f0c90e45d12adb74c7a0fb881dfd36b1d46d6fdfb837dbdff1881ded066b906d SHA512 d8c1e524a3e58def5352b3faae07c42074a2d67015cc62b9601e20bb9b7f29d44d2843e7771e0399e9150be1de2be2b28776f96f7fe75ba7ec4e8f2c31e1f715

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.72-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.72-r1.ebuild
new file mode 100644
index 00000000000..9f8ae493e21
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.72-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 6 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}