[gentoo-commits] gentoo-x86 commit in sys-apps/pmount: pmount-0.9.99_alpha.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    11/12/03 01:22:52

  Modified:             ChangeLog
  Added:                pmount-0.9.99_alpha.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha79/cvs/Linux x86_64)

Revision  Changes    Path
1.87                 sys-apps/pmount/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pmount/ChangeLog?rev=1.87&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pmount/ChangeLog?rev=1.87&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pmount/ChangeLog?r1=1.86&r2=1.87

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pmount/ChangeLog,v
retrieving revision 1.86
retrieving revision 1.87
diff -u -r1.86 -r1.87
--- ChangeLog	18 Jul 2010 14:20:06 -0000	1.86
+++ ChangeLog	3 Dec 2011 01:22:52 -0000	1.87
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/pmount
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pmount/ChangeLog,v 1.86 2010/07/18 14:20:06 nixnut Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pmount/ChangeLog,v 1.87 2011/12/03 01:22:52 ssuominen Exp $
+
+*pmount-0.9.99_alpha (03 Dec 2011)
+
+  03 Dec 2011; Samuli Suominen <ssuominen@g.o>
+  +pmount-0.9.99_alpha.ebuild:
+  Version bump.
 
   18 Jul 2010; <nixnut@g.o> pmount-0.9.23.ebuild:
   ppc stable #325507



1.1                  sys-apps/pmount/pmount-0.9.99_alpha.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pmount/pmount-0.9.99_alpha.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pmount/pmount-0.9.99_alpha.ebuild?rev=1.1&content-type=text/plain

Index: pmount-0.9.99_alpha.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pmount/pmount-0.9.99_alpha.ebuild,v 1.1 2011/12/03 01:22:52 ssuominen Exp $

EAPI=4
inherit eutils

DESCRIPTION="Policy based mounter that gives the ability to mount removable devices as a user"
HOMEPAGE="http://pmount.alioth.debian.org/"
SRC_URI="mirror://debian/pool/main/p/${PN}/${PN}_${PV/_/-}.orig.tar.bz2"
#SRC_URI="http://alioth.debian.org/frs/download.php/3530/${P/_/-}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="crypt"

RDEPEND=">=sys-apps/util-linux-2.17.2
	crypt? ( >=sys-fs/cryptsetup-1.0.6-r2 )"
DEPEND="${RDEPEND}
	dev-util/intltool
	sys-devel/gettext"

S=${WORKDIR}/${P/_/-}

pkg_setup() {
	enewgroup plugdev
}

src_prepare() {
	cat <<-EOF > po/POTFILES.skip
	src/conffile.c
	src/configuration.c
	src/loop.c
	EOF

	epatch "${FILESDIR}"/${PN}-0.9.19-testsuite-missing-dir.patch
}

src_configure() {
	econf --disable-hal
}

src_test() {
	local testdir=${S}/tests/check_fstab

	ln -s $testdir/a $testdir/b && ln -s $testdir/d $testdir/c && \
		ln -s $testdir/c $testdir/e \
		|| die "Unable to create fake symlinks required for testsuite"

	emake check
}

src_install () {
	# Must be run SETUID+SETGID, bug #250106
	exeinto /usr/bin
	exeopts -m 6710 -g plugdev
	doexe src/{p,pu}mount

	dodoc AUTHORS ChangeLog TODO
	doman man/{{p,pu}mount.1,pmount.conf.5}

	insinto /etc
	doins etc/pmount.{allow,conf}
}

pkg_postinst() {
	elog
	elog "This package has been installed setuid and setgid."

	elog "The permissions are as such that only users that belong to the plugdev"
	elog "group are allowed to run this. But if a script run by root mounts a"
	elog "device, members of the plugdev group will have access to it."
	elog
	elog "Please add your user to the plugdev group to be able to mount USB drives"
}