[gentoo-commits] gentoo-x86 commit in sys-auth/polkit: metadata.xml ChangeLog polkit-0.96-r2.ebuild

[Nirbheek Chauhan (nirbheek)]

nirbheek    10/07/02 10:02:24

  Modified:             metadata.xml ChangeLog
  Added:                polkit-0.96-r2.ebuild
  Log:
  USE=expat was quite useless, expat is mandatory in polkit. Don't create user 'polkituser', it was used by policykit, but isn't by polkit. Also, add introspection support
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.2                  sys-auth/polkit/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/polkit/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	29 Oct 2009 23:28:01 -0000	1.1
+++ metadata.xml	2 Jul 2010 10:02:23 -0000	1.2
@@ -6,5 +6,9 @@
 		<name>Nirbheek Chauhan</name>
 	</maintainer>
 	<herd>freedesktop</herd>
+	<use>
+		<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg> for
+			introspection</flag>
+	</use>
 </pkgmetadata>
 



1.18                 sys-auth/polkit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/polkit/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	4 Jun 2010 19:50:44 -0000	1.17
+++ ChangeLog	2 Jul 2010 10:02:24 -0000	1.18
@@ -1,6 +1,14 @@
 # ChangeLog for sys-auth/polkit
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit/ChangeLog,v 1.17 2010/06/04 19:50:44 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit/ChangeLog,v 1.18 2010/07/02 10:02:24 nirbheek Exp $
+
+*polkit-0.96-r2 (02 Jul 2010)
+
+  02 Jul 2010; Nirbheek Chauhan <nirbheek@g.o>
+  +polkit-0.96-r2.ebuild, metadata.xml:
+  USE=expat was quite useless, expat is mandatory in polkit. Don't create
+  user 'polkituser', it was used by policykit, but isn't by polkit. Also,
+  add introspection support
 
   04 Jun 2010; Markus Meier <maekke@g.o> polkit-0.96-r1.ebuild:
   x86 stable, bug #314899



1.1                  sys-auth/polkit/polkit-0.96-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/polkit-0.96-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/polkit/polkit-0.96-r2.ebuild?rev=1.1&content-type=text/plain

Index: polkit-0.96-r2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-auth/polkit/polkit-0.96-r2.ebuild,v 1.1 2010/07/02 10:02:24 nirbheek Exp $

EAPI="2"

inherit autotools eutils multilib pam

DESCRIPTION="Policy framework for controlling privileges for system-wide services"
HOMEPAGE="http://hal.freedesktop.org/docs/PolicyKit"
SRC_URI="http://hal.freedesktop.org/releases/${P}.tar.gz
!pam? ( mirror://gentoo/${P}-r1-shadow-support.patch.lzma )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc examples +introspection nls pam"

# not mature enough
RDEPEND=">=dev-libs/glib-2.21.4
	>=dev-libs/eggdbus-0.6
	dev-libs/expat
	introspection? ( dev-libs/gobject-introspection )
	pam? ( virtual/pam )"
DEPEND="${RDEPEND}
	!!>=sys-auth/policykit-0.92
	dev-libs/libxslt
	app-text/docbook-xsl-stylesheets
	>=dev-util/pkgconfig-0.18
	>=dev-util/intltool-0.36
	>=dev-util/gtk-doc-am-1.13
	doc? ( >=dev-util/gtk-doc-1.13 )"
PDEPEND=">=sys-auth/consolekit-0.4[policykit]"
# gtk-doc-am-1.13 needed for eautoreconf

src_prepare() {
	epatch "${FILESDIR}/${P}-getcwd.patch"
	if ! use pam; then
		# Experimental shadow support, bug 291116
		epatch "${WORKDIR}/${P}-r1-shadow-support.patch"
		eautoreconf
	fi
}

src_configure() {
	local conf

	if use pam; then
		conf="${conf} --with-authfw=pam
			--with-pam-module-dir=$(getpam_mod_dir)"
	else
		conf="${conf} --with-authfw=shadow"
	fi

	# We define libexecdir due to fdo bug #22951
	# easier to maintain than patching everything
	econf ${conf} \
		--disable-ansi \
		--disable-examples \
		--enable-fast-install \
		--enable-libtool-lock \
		--enable-man-pages \
		--disable-dependency-tracking \
		--with-os-type=gentoo \
		--localstatedir=/var \
		--libexecdir='${exec_prefix}/libexec/polkit-1' \
		$(use_enable debug verbose-mode) \
		$(use_enable doc gtk-doc) \
		$(use_enable introspection) \
		$(use_enable nls)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc NEWS README AUTHORS ChangeLog || die "dodoc failed"

	# We disable example compilation above, and handle it here
	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins src/examples/{*.c,*.policy*}
	fi

	# Need to keep a few directories around...
	diropts -m0700 -o root -g root
	keepdir /var/run/polkit-1
	keepdir /var/lib/polkit-1
}