[gentoo-commits] gentoo-x86 commit in dev-python/pandas: pandas-0.10.0.ebuild ChangeLog

[Kacper Kowalik (xarthisius)]

xarthisius    12/12/29 13:26:25

  Modified:             ChangeLog
  Added:                pandas-0.10.0.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 0x5D21B852895192F9)

Revision  Changes    Path
1.9                  dev-python/pandas/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pandas/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pandas/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pandas/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/pandas/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	23 Nov 2012 05:14:47 -0000	1.8
+++ ChangeLog	29 Dec 2012 13:26:25 -0000	1.9
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pandas
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/ChangeLog,v 1.8 2012/11/23 05:14:47 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/ChangeLog,v 1.9 2012/12/29 13:26:25 xarthisius Exp $
+
+*pandas-0.10.0 (29 Dec 2012)
+
+  29 Dec 2012; Kacper Kowalik <xarthisius@g.o> +pandas-0.10.0.ebuild:
+  Version bump
 
 *pandas-0.9.1 (23 Nov 2012)
 



1.1                  dev-python/pandas/pandas-0.10.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pandas/pandas-0.10.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/pandas/pandas-0.10.0.ebuild?rev=1.1&content-type=text/plain

Index: pandas-0.10.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/pandas-0.10.0.ebuild,v 1.1 2012/12/29 13:26:25 xarthisius Exp $

EAPI=4

# python cruft
SUPPORT_PYTHON_ABIS="1"
DISTUTILS_SRC_TEST="nosetests"
RESTRICT_PYTHON_ABIS="2.4 2.7-pypy-* *-jython 3.3"

inherit distutils

DESCRIPTION="Powerful data structures for data analysis and statistics"
HOMEPAGE="http://pandas.sourceforge.net/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="BSD"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
SLOT="0"
IUSE="doc examples excel R"

CDEPEND="dev-python/numpy
	>=dev-python/python-dateutil-2.1"
DEPEND="${CDEPEND}
	doc? (
		dev-python/ipython
		dev-python/rpy
		dev-python/sphinx
		sci-libs/scikits_statsmodels
	)"
RDEPEND="${CDEPEND}
	dev-python/matplotlib
	dev-python/pytables
	dev-python/pytz
	sci-libs/scipy
	excel? (
		dev-python/openpyxl
		dev-python/xlrd
		dev-python/xlwt
	)
	R? ( dev-python/rpy )"

src_compile() {
	distutils_src_compile
	if use doc; then
		cd doc
		"$(PYTHON -f)" make.py html || die
	fi
}

src_test() {
	testing() {
		cd "${S}/build-${PYTHON_ABI}"/lib*
		PYTHONPATH=. MPLCONFIGDIR=. HOME=. nosetests-"${PYTHON_ABI}" pandas
	}
	python_execute_function testing
}

src_install() {
	distutils_src_install
	use doc && dohtml -r doc/build/html
	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi
}