[gentoo-commits] gentoo-x86 commit in mate-base/mate-session-manager: mate-session-manager-1.8.1-r1.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       14/05/29 18:48:21

  Modified:             ChangeLog
  Added:                mate-session-manager-1.8.1-r1.ebuild
  Log:
  upower support relies on old upower, systemd setups are supposed to rely on systemd to do all the stuff now (#508920#c15)
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.8                  mate-base/mate-session-manager/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-base/mate-session-manager/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-base/mate-session-manager/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-base/mate-session-manager/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mate-base/mate-session-manager/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	4 May 2014 14:54:07 -0000	1.7
+++ ChangeLog	29 May 2014 18:48:21 -0000	1.8
@@ -1,6 +1,13 @@
 # ChangeLog for mate-base/mate-session-manager
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mate-base/mate-session-manager/ChangeLog,v 1.7 2014/05/04 14:54:07 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/mate-base/mate-session-manager/ChangeLog,v 1.8 2014/05/29 18:48:21 pacho Exp $
+
+*mate-session-manager-1.8.1-r1 (29 May 2014)
+
+  29 May 2014; Pacho Ramos <pacho@g.o>
+  +mate-session-manager-1.8.1-r1.ebuild:
+  upower support relies on old upower, systemd setups are supposed to rely on
+  systemd to do all the stuff now (#508920#c15)
 
   04 May 2014; Agostino Sarubbo <ago@g.o>
   mate-session-manager-1.6.1-r1.ebuild:



1.1                  mate-base/mate-session-manager/mate-session-manager-1.8.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-base/mate-session-manager/mate-session-manager-1.8.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mate-base/mate-session-manager/mate-session-manager-1.8.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: mate-session-manager-1.8.1-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mate-base/mate-session-manager/mate-session-manager-1.8.1-r1.ebuild,v 1.1 2014/05/29 18:48:21 pacho Exp $

EAPI="5"

GCONF_DEBUG="yes"

inherit autotools gnome2 versionator

MATE_BRANCH="$(get_version_component_range 1-2)"

SRC_URI="http://pub.mate-desktop.org/releases/${MATE_BRANCH}/${P}.tar.xz"
DESCRIPTION="MATE session manager"
HOMEPAGE="http://mate-desktop.org/"

LICENSE="GPL-2 LGPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~amd64"

IUSE="ipv6 elibc_FreeBSD gnome-keyring systemd upower"

# x11-misc/xdg-user-dirs{,-gtk} are needed to create the various XDG_*_DIRs, and
# create .config/user-dirs.dirs which is read by glib to get G_USER_DIRECTORY_*
# xdg-user-dirs-update is run during login (see 10-user-dirs-update-gnome below).

RDEPEND=">=dev-libs/dbus-glib-0.76:0
	>=dev-libs/glib-2.25:2
	dev-libs/libxslt:0
	sys-apps/dbus:0
	x11-apps/xdpyinfo:0
	x11-libs/gdk-pixbuf:2
	>=x11-libs/gtk+-2.14:2
	x11-libs/libICE:0
	x11-libs/libSM:0
	x11-libs/libX11:0
	x11-libs/libXau:0
	x11-libs/libXext:0
	x11-libs/libXrender:0
	x11-libs/libXtst:0
	x11-libs/pango:0
	x11-libs/xtrans:0
	x11-misc/xdg-user-dirs:0
	x11-misc/xdg-user-dirs-gtk:0
	virtual/libintl:0
	elibc_FreeBSD? ( dev-libs/libexecinfo:0 )
	gnome-keyring? ( gnome-base/gnome-keyring:0 )
	systemd? ( sys-apps/systemd:0 )
	upower? ( || ( <sys-power/upower-0.99 sys-power/upower-pm-utils ) )"

DEPEND="${RDEPEND}
	>=dev-util/intltool-0.40:*
	>=dev-lang/perl-5:0
	>=mate-base/mate-common-1.6:0
	>=sys-devel/gettext-0.10.40:*
	virtual/pkgconfig:*
	!<gnome-base/gdm-2.20.4:0"

src_prepare() {
	# Add "session saving" button back,
	# see https://bugzilla.gnome.org/show_bug.cgi?id=575544
	epatch "${FILESDIR}"/${PN}-1.5.2-save-session-ui.patch

	# Fix race condition in idle monitor, GNOME bug applies to MATE too,
	# see https://bugzilla.gnome.org/show_bug.cgi?id=627903
	epatch "${FILESDIR}"/${PN}-1.2.0-idle-transition.patch

	eautoreconf
	gnome2_src_prepare
}

src_configure() {
	gnome2_src_configure \
		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
		--with-default-wm=mate-wm \
		--with-gtk=2.0 \
		$(use_enable ipv6) \
		$(use_with systemd) \
		$(use_enable upower)
}

DOCS="AUTHORS ChangeLog NEWS README"

src_install() {
	gnome2_src_install

	dodir /etc/X11/Sessions/
	exeinto /etc/X11/Sessions/
	doexe "${FILESDIR}"/MATE

	dodir /usr/share/mate/applications/
	insinto /usr/share/mate/applications/
	doins "${FILESDIR}"/defaults.list

	dodir /etc/X11/xinit/xinitrc.d/
	exeinto /etc/X11/xinit/xinitrc.d/
	doexe "${FILESDIR}"/15-xdg-data-mate

	# This should be done in MATE too, see Gentoo bug #270852
	doexe "${FILESDIR}"/10-user-dirs-update-mate
}