[gentoo-commits] repo/gentoo:master commit in: dev-python/openstacksdk/

[Michał Górny]

commit:     2545d3153c34016232cba07de10eda70010f5b53
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat May 21 05:45:15 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat May 21 06:47:08 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2545d315

dev-python/openstacksdk: Bump to 0.99.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/openstacksdk/Manifest                   |  1 +
 dev-python/openstacksdk/openstacksdk-0.99.0.ebuild | 85 ++++++++++++++++++++++
 2 files changed, 86 insertions(+)

diff --git a/dev-python/openstacksdk/Manifest b/dev-python/openstacksdk/Manifest
index 4beb8aac7b4f..540c9cd1e105 100644
--- a/dev-python/openstacksdk/Manifest
+++ b/dev-python/openstacksdk/Manifest
@@ -1 +1,2 @@
 DIST openstacksdk-0.61.0.tar.gz 1029483 BLAKE2B 5add768f12bc42562bcdaddf0379e1f59af80b34c5a7f808aaa7469788a685b093b47a4c2a8a771f6cf426f6ac11e188fca0843aaa5173266f3c69a0ac69c4f9 SHA512 6f02486b9de8c540cf43f49f55b67dede34a24a96229d42b43aa215f6286566579f726b53732a9b3b952cee5df1fa8d3cf2f6ccc7c0ca7f9a1a96888640ff734
+DIST openstacksdk-0.99.0.tar.gz 1060314 BLAKE2B 0c8f641e301ba4fb8ca83e651f85f8ba98aa73904b2e94b15b17d99354aace5b73ba243c4e624e4c53dd7fb1deb147801aee93233f1fe019a0068873530bdb37 SHA512 5e15f29002231dbad15e7a2dadaa97e64ed191389d259222880a7e40984d6fbcd9d1602a041164e4f819141417d108a179171b4c1430947dc5c5e9cdc5409aea

diff --git a/dev-python/openstacksdk/openstacksdk-0.99.0.ebuild b/dev-python/openstacksdk/openstacksdk-0.99.0.ebuild
new file mode 100644
index 000000000000..6e6dbaa5bb04
--- /dev/null
+++ b/dev-python/openstacksdk/openstacksdk-0.99.0.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A collection of libraries for building applications to work with OpenStack"
+HOMEPAGE="https://github.com/openstack/openstacksdk/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+CDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+	>=dev-python/appdirs-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/requestsexceptions-1.2.0[${PYTHON_USEDEP}]
+	>dev-python/jsonpatch-1.20[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.7.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/munch-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/decorator-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.7.0[${PYTHON_USEDEP}]
+	dev-python/importlib_metadata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${CDEPEND}
+	test? (
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/prometheus_client-0.4.2[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/statsd-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Internet?
+	sed -e 's:test_create_dynamic_large_object:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# TODO
+	sed -e 's:test_generate_form:_&:' \
+		-e 's:test_create_static_large_object:_&:' \
+		-e 's:test_object_segment_retries:_&:' \
+		-e 's:test_object_segment_retry_failure:_&:' \
+		-e 's:test_slo_manifest_retry:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# unhappy about paths due to test runner
+	sed -e 's:test_method_not_supported:_&:' \
+		-i openstack/tests/unit/test_exceptions.py || die
+	sed -e 's:test_repr:_&:' \
+		-i openstack/tests/unit/test_resource.py || die
+
+	# requires hacking
+	rm openstack/tests/unit/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b openstack/tests/unit
+}