[gentoo-commits] gentoo-x86 commit in net-analyzer/nagios-core: ChangeLog nagios-core-2.10.ebuild nagios-core-2.9-r1.ebuild

[Tobias Scherbaum (dertobi123)]

dertobi123    07/10/22 18:29:09

  Modified:             ChangeLog
  Added:                nagios-core-2.10.ebuild
  Removed:              nagios-core-2.9-r1.ebuild
  Log:
  Version bump
  (Portage version: 2.1.3.15)

Revision  Changes    Path
1.104                net-analyzer/nagios-core/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/nagios-core/ChangeLog?rev=1.104&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/nagios-core/ChangeLog?rev=1.104&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/nagios-core/ChangeLog?r1=1.103&r2=1.104

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/nagios-core/ChangeLog,v
retrieving revision 1.103
retrieving revision 1.104
diff -u -r1.103 -r1.104
--- ChangeLog	1 Aug 2007 21:00:26 -0000	1.103
+++ ChangeLog	22 Oct 2007 18:29:08 -0000	1.104
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/nagios-core
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nagios-core/ChangeLog,v 1.103 2007/08/01 21:00:26 marineam Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nagios-core/ChangeLog,v 1.104 2007/10/22 18:29:08 dertobi123 Exp $
+
+*nagios-core-2.10 (22 Oct 2007)
+
+  22 Oct 2007; Tobias Scherbaum <dertobi123@g.o>
+  -nagios-core-2.9-r1.ebuild, +nagios-core-2.10.ebuild:
+  Version bump
 
   01 Aug 2007; Michael Marineau <marineam@g.o>
   nagios-core-2.9-r1.ebuild:



1.1                  net-analyzer/nagios-core/nagios-core-2.10.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/nagios-core/nagios-core-2.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/nagios-core/nagios-core-2.10.ebuild?rev=1.1&content-type=text/plain

Index: nagios-core-2.10.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/nagios-core/nagios-core-2.10.ebuild,v 1.1 2007/10/22 18:29:08 dertobi123 Exp $

inherit eutils apache-module toolchain-funcs

MY_P=${PN/-core}-${PV/_}
DESCRIPTION="Nagios Core - Check daemon, CGIs, docs"
HOMEPAGE="http://www.nagios.org/"
SRC_URI="mirror://sourceforge/nagios/${MY_P}.tar.gz
	mirror://gentoo/nagios-2.0b.cfg-sample.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="noweb perl debug"
# mysql postgres
DEPEND="virtual/mailx
	!noweb? (
		>=media-libs/jpeg-6b-r3
		>=media-libs/libpng-1.2.5-r4
		>=media-libs/gd-1.8.3-r5
		${NEED_APACHE_DEPEND}
		perl? ( net-analyzer/traceroute )
	)
	perl? ( >=dev-lang/perl-5.6.1-r7 )"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	# Check if gd has been compiled with jpeg and png support
	if ! use noweb; then
		if ! built_with_use media-libs/gd jpeg png; then
			eerror "Your gd has been compiled without jpeg and/or png support."
			eerror "Please re-emerge gd:"
			eerror "# USE="jpeg png" emerge gd"
			die "pkg_setup failed"
		fi
	fi

	enewgroup nagios
	enewuser nagios -1 /bin/bash /var/nagios/home nagios
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/2.x-series-nsca.patch

	local strip="$(echo '$(MAKE) strip-post-install')"
	sed -i -e "s:${strip}::" {cgi,base}/Makefile.in || die "sed failed in Makefile.in"
}

src_compile() {
	local myconf

	if use perl
	then
		myconf="${myconf} --enable-embedded-perl --with-perlcache"
	fi

	if use debug; then
		myconf="${myconf} --enable-DEBUG0"
		myconf="${myconf} --enable-DEBUG1"
		myconf="${myconf} --enable-DEBUG2"
		myconf="${myconf} --enable-DEBUG3"
		myconf="${myconf} --enable-DEBUG4"
		myconf="${myconf} --enable-DEBUG5"
	fi

	if use noweb; then
		myconf="${myconf} --with-command-grp=nagios"
	else
		myconf="${myconf} --with-command-grp=apache"
	fi

	econf ${myconf} \
		--prefix=/usr/nagios \
		--localstatedir=/var/nagios \
		--sysconfdir=/etc/nagios \
		--datadir=/usr/nagios/share \
		|| die "./configure failed"

	emake CC=$(tc-getCC) nagios || die "make failed"

	if use !noweb ; then
		# Only compile the CGI's if "noweb" useflag is not set.
		make CC=$(tc-getCC) DESTDIR="${D}" cgis || die
	fi

	emake -C contrib all || "contrib make filed"

}

src_install() {
	dodoc Changelog INSTALLING LEGAL LICENSE README UPGRADING
	docinto contrib
	dodoc contrib/README

	if use noweb; then
		sed -i -e 's/cd $(SRC_CGI) && $(MAKE) $@/# line removed due to noweb use flag/' \
			-e 's/cd $(SRC_HTM) && $(MAKE) $@/# line removed due to noweb use flag/' \
			Makefile
	fi

	sed -i -e 's/^contactgroups$//g' Makefile

	make DESTDIR="${D}" install
	make DESTDIR="${D}" install-config
	make DESTDIR="${D}" install-commandmode

	docinto sample-configs
	dodoc "${D}"/etc/nagios/*
	rm "${D}"/etc/nagios/*

	newdoc "${WORKDIR}"/nagios-2.0b.cfg-sample nagios.cfg-sample

	#contribs are not configured by the configure script, we'll configure them overselves...
	find "${S}"/contrib/ -type f | xargs sed -e 's:/usr/local/nagios/var/rw:/var/nagios/rw:;
						s:/usr/local/nagios/libexec:/usr/nagios/libexec:;
						s:/usr/local/nagios/etc:/etc/nagios:;
						s:/usr/local/nagios/sbin:/usr/nagios/sbin:;' -i

	insinto /usr/share/doc/${PF}/contrib
	doins -r contrib/eventhandlers

	doinitd "${FILESDIR}"/nagios
	newconfd "${FILESDIR}"/conf.d nagios

	chmod 644 "${S}"/contrib/*.cgi
	into /usr/nagios
	for bin in `find contrib/ -type f -perm 0755 -maxdepth 1` ; do
		dobin "$bin"
	done

	# Apache Module
	if use !noweb; then
		insinto "${APACHE2_MODULES_CONFDIR}"
		doins "${FILESDIR}"/99_nagios.conf

		if use perl; then
			into /usr/nagios ; dosbin contrib/traceroute.cgi
		fi
	fi

	for dir in etc/nagios var/nagios ; do
		chown -R nagios:nagios "${D}/${dir}" || die "Failed chown of ${D}/${dir}"
	done

	chown -R root:root "${D}"/usr/nagios
	find "${D}"/usr/nagios -type d -print0 | xargs -0 chmod 755
	find "${D}"/usr/nagios/*bin -type f -print0 | xargs -0 chmod 755
	find "${D}"/usr/nagios/share -type f -print0 | xargs -0 chmod 644

	keepdir /etc/nagios
	keepdir /var/nagios
	keepdir /var/nagios/archives
	keepdir /usr/nagios/share/ssi
	keepdir /var/nagios/rw

	if use noweb; then
		chown -R nagios:nagios "${D}"/var/nagios/rw || die "Failed Chown of ${D}/var/nagios/rw"
	else
		chown -R nagios:apache "${D}"/var/nagios/rw || die "Failed Chown of ${D}/var/nagios/rw"
	fi

	chmod ug+s "${D}"/var/nagios/rw || die "Failed Chmod of ${D}/var/nagios/rw"
	chmod 0750 "${D}"/etc/nagios || die "Failed chmod of ${D}/etc/nagios"

	cat << EOF > "${T}"/55-nagios-core-revdep
SEARCH_DIRS="/usr/nagios/bin /usr/nagios/libexec"
EOF

	insinto /etc/revdep-rebuild
	doins "${T}"/55-nagios-core-revdep
}

pkg_postinst() {
	einfo
	einfo "The example config files are located at /usr/share/doc/${PF}/sample-configs/."
	einfo
	einfo "Also, if you want nagios to start at boot time"
	einfo "remember to execute:"
	einfo "  rc-update add nagios default"
	einfo

	if use !noweb; then
		einfo "This does not include cgis that are perl-dependent"
		einfo "Currently traceroute.cgi is perl-dependent"
		einfo "To have ministatus.cgi requires copying of ministatus.c"
		einfo "to cgi directory for compiling."

		einfo " Edit /etc/conf.d/apache2 and add \"-D NAGIOS\""

		einfo
		einfo "That will make nagios's web front end visable via"
		einfo "http://localhost/nagios/"
		einfo
		einfo "Note that the user your webserver is running at needs"
		einfo "read-access to /etc/nagios. There are several possible"
		einfo "solutions to accomplish this, choose the one you are"
		einfo "most comfortable with:"
		einfo "	usermod -G nagios apache"
		einfo "or"
		einfo "	chown nagios:apache /etc/nagios"

	else
		einfo "Please note that you have installed Nagios without web interface."
		einfo "Please don't file any bugs about having no web interface when you do this."
		einfo "Thank you!"
	fi

	einfo
	einfo "If your kernel has /proc protection, nagios"
	einfo "will not be happy as it relies on accessing the proc"
	einfo "filesystem. You can fix this by adding nagios into"
	einfo "the group wheel, but this is not recomended."
	einfo

	einfo
	ewarn "Use /usr/nagios/bin/convertcfg for configuration file conversion"
}

pkg_prerm() {
	/etc/init.d/nagios stop
}



-- 
gentoo-commits@g.o mailing list