[gentoo-commits] gentoo-x86 commit in games-emulation/openmsx: ChangeLog openmsx-0.8.0.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    10/10/03 04:13:45

  Modified:             ChangeLog
  Added:                openmsx-0.8.0.ebuild
  Log:
  version bump
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.33                 games-emulation/openmsx/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/openmsx/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/openmsx/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/openmsx/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-emulation/openmsx/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	28 May 2010 18:11:05 -0000	1.32
+++ ChangeLog	3 Oct 2010 04:13:45 -0000	1.33
@@ -1,6 +1,12 @@
 # ChangeLog for games-emulation/openmsx
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-emulation/openmsx/ChangeLog,v 1.32 2010/05/28 18:11:05 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/openmsx/ChangeLog,v 1.33 2010/10/03 04:13:45 mr_bones_ Exp $
+
+*openmsx-0.8.0 (03 Oct 2010)
+
+  03 Oct 2010; Michael Sterrett <mr_bones_@g.o>
+  +openmsx-0.8.0.ebuild:
+  version bump
 
   28 May 2010; Joseph Jezak <josejx@g.o> openmsx-0.7.2.ebuild:
   Marked ppc stable, ~ppc64 for bug #320503.



1.1                  games-emulation/openmsx/openmsx-0.8.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/openmsx/openmsx-0.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/openmsx/openmsx-0.8.0.ebuild?rev=1.1&content-type=text/plain

Index: openmsx-0.8.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-emulation/openmsx/openmsx-0.8.0.ebuild,v 1.1 2010/10/03 04:13:45 mr_bones_ Exp $

EAPI=2
inherit games

DESCRIPTION="MSX emulator that aims for perfection"
HOMEPAGE="http://openmsx.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE=""

DEPEND="dev-lang/tcl
	dev-libs/libxml2
	media-libs/libpng
	media-libs/libsdl[audio,video]
	media-libs/glew
	media-libs/sdl-image[png]
	media-libs/sdl-ttf
	virtual/opengl"

src_prepare() {
	sed -i \
		-e '/^LDFLAGS:=/d' \
		-e '/LINK_FLAGS_PREFIX/d' \
		-e '/LINK_FLAGS+=/s/-s//' \
		-e '/LINK_FLAGS+=\$(TARGET_FLAGS)/s/$/ $(LDFLAGS)/' \
		build/main.mk \
		|| die
	sed -i \
		-e '/SYMLINK/s:true:false:' \
		build/custom.mk \
		|| die
	find share/extensions -type f -exec chmod -x '{}' +
}

src_compile() {
	emake \
		CXXFLAGS="${CXXFLAGS}" \
		INSTALL_SHARE_DIR="${GAMES_DATADIR}"/${PN} \
		|| die
}

src_install() {
	emake \
		INSTALL_BINARY_DIR="${D}${GAMES_BINDIR}" \
		INSTALL_SHARE_DIR="${D}${GAMES_DATADIR}"/${PN} \
		INSTALL_DOC_DIR="${D}"/usr/share/doc/${PF} \
		install || die "emake install failed"
	dodoc ChangeLog README
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	elog "If you want to if you want to emulate real MSX systems and not"
	elog "only the free C-BIOS machines, put the system ROMs in one of"
	elog "the following directories: ${GAMES_DATADIR}/${PN}/systemroms"
	elog "or ~/.openMSX/share/systemroms"
}