[gentoo-commits] repo/gentoo:master commit in: sys-devel/llvm-toolchain-symlinks/

[Michał Górny]

commit:     eadd62daeb499184f038e77e5091999560554a06
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 20 15:04:11 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Sep 20 16:55:24 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eadd62da

sys-devel/llvm-toolchain-symlinks: Add for LLVM 14.x

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../llvm-toolchain-symlinks-14.ebuild              | 42 ++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/sys-devel/llvm-toolchain-symlinks/llvm-toolchain-symlinks-14.ebuild b/sys-devel/llvm-toolchain-symlinks/llvm-toolchain-symlinks-14.ebuild
new file mode 100644
index 000000000000..9cc42ef77e31
--- /dev/null
+++ b/sys-devel/llvm-toolchain-symlinks/llvm-toolchain-symlinks-14.ebuild
@@ -0,0 +1,42 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib
+
+DESCRIPTION="Symlinks to use LLVM on binutils-free system"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:LLVM"
+SRC_URI=""
+S=${WORKDIR}
+
+LICENSE="public-domain"
+SLOT="${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~ppc-macos ~x64-macos"
+IUSE="+native-symlinks"
+
+RDEPEND="
+	sys-devel/llvm:${SLOT}
+"
+
+src_install() {
+	use native-symlinks || return
+
+	local tools=(
+		addr2line ar dlltool nm objcopy objdump ranlib readelf size
+		strings strip windres
+	)
+
+	local abi t
+	local dest=/usr/lib/llvm/${SLOT}/bin
+	dodir "${dest}"
+	for t in "${tools[@]}"; do
+		dosym "llvm-${t}" "${dest}/${t}"
+	done
+	for abi in $(get_all_abis); do
+		local abi_chost=$(get_abi_CHOST "${abi}")
+		for t in "${tools[@]}"; do
+			dosym "llvm-${t}" "${dest}/${abi_chost}-${t}"
+		done
+	done
+}