[gentoo-commits] repo/gentoo:master commit in: dev-util/bite/

[Tim Harder]

commit:     b769b2b602157c5cb406391e4dc4fdbd760ec1ab
Author:     Tim Harder <radhermit <AT> gentoo <DOT> org>
AuthorDate: Mon Jun  4 23:50:07 2018 +0000
Commit:     Tim Harder <radhermit <AT> gentoo <DOT> org>
CommitDate: Mon Jun  4 23:56:36 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b769b2b6

dev-util/bite: initial import for live ebuild

 dev-util/bite/bite-9999.ebuild | 57 ++++++++++++++++++++++++++++++++++++++++++
 dev-util/bite/metadata.xml     | 11 ++++++++
 2 files changed, 68 insertions(+)

diff --git a/dev-util/bite/bite-9999.ebuild b/dev-util/bite/bite-9999.ebuild
new file mode 100644
index 00000000000..9460f20c7e4
--- /dev/null
+++ b/dev-util/bite/bite-9999.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_6 )
+DISTUTILS_IN_SOURCE_BUILD=1
+PYTHON_REQ_USE="xml"
+
+inherit distutils-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/bite/bite.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/bite/${PN}/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="bug, issue, and ticket extraction library and command line tool"
+HOMEPAGE="https://github.com/bite/bite"
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/requests-2[${PYTHON_USEDEP}]
+	dev-python/multidict[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+"
+if [[ ${PV} == *9999 ]] ; then
+	RDEPEND+=" =dev-python/snakeoil-9999[${PYTHON_USEDEP}]"
+	SPHINX="dev-python/sphinx[${PYTHON_USEDEP}]"
+else
+	RDEPEND+=" >=dev-python/snakeoil-0.8[${PYTHON_USEDEP}]"
+	SPHINX="doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+fi
+DEPEND="
+	${SPHINX}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+python_compile_all() {
+	esetup.py build_man $(usex doc "build_docs" "")
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install install_man \
+		$(usex doc "install_docs --path="${ED%/}"/usr/share/doc/${PF}/html" "")
+	distutils-r1_python_install_all
+}

diff --git a/dev-util/bite/metadata.xml b/dev-util/bite/metadata.xml
new file mode 100644
index 00000000000..f5edf41502c
--- /dev/null
+++ b/dev-util/bite/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>radhermit@g.o</email>
+    <name>Tim Harder</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">bite/bite</remote-id>
+  </upstream>
+</pkgmetadata>