[gentoo-commits] gentoo-x86 commit in media-libs/libpng: ChangeLog libpng-1.5.10.ebuild libpng-1.2.49.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/03/30 17:33:57

  Modified:             ChangeLog
  Added:                libpng-1.5.10.ebuild libpng-1.2.49.ebuild
  Log:
  Version bump wrt #410153 by Thomas D.
  
  (Portage version: 2.2.0_alpha96/cvs/Linux x86_64)

Revision  Changes    Path
1.359                media-libs/libpng/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpng/ChangeLog?rev=1.359&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpng/ChangeLog?rev=1.359&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpng/ChangeLog?r1=1.358&r2=1.359

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libpng/ChangeLog,v
retrieving revision 1.358
retrieving revision 1.359
diff -u -r1.358 -r1.359
--- ChangeLog	3 Mar 2012 19:58:29 -0000	1.358
+++ ChangeLog	30 Mar 2012 17:33:57 -0000	1.359
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/libpng
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/ChangeLog,v 1.358 2012/03/03 19:58:29 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/ChangeLog,v 1.359 2012/03/30 17:33:57 ssuominen Exp $
+
+*libpng-1.5.10 (30 Mar 2012)
+*libpng-1.2.49 (30 Mar 2012)
+
+  30 Mar 2012; Samuli Suominen <ssuominen@g.o> +libpng-1.2.49.ebuild,
+  +libpng-1.5.10.ebuild:
+  Version bump wrt #410153 by Thomas D.
 
   03 Mar 2012; Raúl Porcel <armin76@g.o> libpng-1.5.9.ebuild:
   ia64/m68k/s390/sh/sparc stable wrt #404197



1.1                  media-libs/libpng/libpng-1.5.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpng/libpng-1.5.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpng/libpng-1.5.10.ebuild?rev=1.1&content-type=text/plain

Index: libpng-1.5.10.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/libpng-1.5.10.ebuild,v 1.1 2012/03/30 17:33:57 ssuominen Exp $

EAPI=4

inherit eutils libtool multilib

DESCRIPTION="Portable Network Graphics library"
HOMEPAGE="http://www.libpng.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
	apng? ( mirror://sourceforge/${PN}-apng/${P}-apng.patch.gz )"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
IUSE="apng neon static-libs"

RDEPEND="sys-libs/zlib"
DEPEND="${RDEPEND}
	app-arch/xz-utils"

DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )

src_prepare() {
	if use apng; then
		epatch "${WORKDIR}"/${P}-apng.patch
		# Don't execute symbols check with apng patch wrt #378111
		sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
	fi
	elibtoolize
}

src_configure() {
	econf \
		$(use_enable static-libs static) \
		$(use_enable neon arm-neon)
}

src_install() {
	default
	find "${ED}" -name '*.la' -exec rm -f {} +
}

pkg_preinst() {
	has_version ${CATEGORY}/${PN}:1.4 && return 0
	preserve_old_lib /usr/$(get_libdir)/libpng14$(get_libname 14)
}

pkg_postinst() {
	has_version ${CATEGORY}/${PN}:1.4 && return 0
	preserve_old_lib_notify /usr/$(get_libdir)/libpng14$(get_libname 14)
}



1.1                  media-libs/libpng/libpng-1.2.49.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpng/libpng-1.2.49.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libpng/libpng-1.2.49.ebuild?rev=1.1&content-type=text/plain

Index: libpng-1.2.49.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libpng/libpng-1.2.49.ebuild,v 1.1 2012/03/30 17:33:57 ssuominen Exp $

# this ebuild is only for the libpng12.so.0 SONAME for ABI compat

EAPI=4

inherit multilib libtool

DESCRIPTION="Portable Network Graphics library"
HOMEPAGE="http://www.libpng.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"

LICENSE="as-is"
SLOT="1.2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE=""

RDEPEND="sys-libs/zlib
	!=media-libs/libpng-1.2*:0"
DEPEND="${RDEPEND}
	app-arch/xz-utils"

src_prepare() {
	elibtoolize
}

src_configure() {
	econf --disable-static
}

src_compile() {
	emake libpng12.la
}

src_install() {
	newlib.so .libs/libpng12.so.0.* libpng12.so.0
}