[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     ba971cfbe54c535e06839bf6d70ccbec127f574f
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Jul  9 11:52:08 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jul  9 11:52:08 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ba971cfb

sys-kernel/gentoo-kernel-bin: bump to 5.12.15-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.12.15-r1.ebuild            | 115 +++++++++++++++++++++
 2 files changed, 116 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 9812742063c..3c57285fb59 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -83,6 +83,7 @@ DIST gentoo-kernel-5.12.14-1.amd64.xpak 66384986 BLAKE2B 42979ab70fc69caf68d60bc
 DIST gentoo-kernel-5.12.14-1.arm64.xpak 59994823 BLAKE2B c36896fc4771218013fff34d504507a0312ccae2c76e486396e6c6fec39d79a3e38bf056f355188ea78f45a249e3798be1943295ebb07e2af77ef8b73ad7f9fe SHA512 f2bad60254ee49d7439a789756ccf064cbdcd9e8e8e298edc4c75cdf2a03ff3c5827880167139e4334457af7062c55fde37e8ea92a728e16c224f424f0a9fba3
 DIST gentoo-kernel-5.12.14-1.x86.xpak 58064174 BLAKE2B b614ad928d99685a4b93482155e1bfdaec106c868fc7e619dee0fe9c68d101ceabb16cb203555fac00332f19dda028a30b5aece8d046ed24ae3948efbb081046 SHA512 664f8db652b124b4db2ebcf331d295529f2832d033b81e21a0517da5c002bb6c96dfba77c389af87641174468f4693332c1d0ca2d295e69b7229d068613ce332
 DIST gentoo-kernel-5.12.15-1.amd64.xpak 66395917 BLAKE2B b77c5e26863dc1c10da3c82904ef035f93c7bbbf60925f7c91836b7cfbb3d32335a8cad78a9b1a90a6d462f34fb798c393f7f992c54ffe6e1a5391b1e63652a4 SHA512 3efe58c6e9d948981fe51fc93ceb73de2f9a049cd396c62e743b3c5033eaf60b05d3100b2377060d1ba6245118281a49447bb5404dd4cc12b616a682fc4c252a
+DIST gentoo-kernel-5.12.15-1.arm64.xpak 59971350 BLAKE2B 4231ed09d6efd9acae82078d259bef241223770fc95c24145a940ff3e4d712cfe52677a358d4fe26a6bf74129feaa3abad67e2d17eedd1e04f34758fd7ac5e1e SHA512 9eb582dab725c1716b777986e0adf90b353ca481763b27c65240d6b4d8e52d54ca394848b3ff7977651606341e39fbc19b0002caaa8174916f298bfe480087d9
 DIST gentoo-kernel-5.12.15-1.x86.xpak 58062337 BLAKE2B 2ea33f13f41f6153e117dc99fdb805ff6a24071b6231730ff159ea2597e203655e5d6daa632f4fc8ace6444d8ffec7e624d222500b32e7b33035ac5a56b3efcb SHA512 62cae2c8e1fb42b3cf2ab48ade6fcbffcc03fe3b48c0d00fa7f2d3229e43a615887907e70b3219c3b040061134134f95c11c9b2d33a1f0ae568df7ec47507395
 DIST gentoo-kernel-5.4.120-1.amd64.xpak 61385726 BLAKE2B 4eda28bcfaaeb8caaa0d74c6fb37b203528ccd9853c775bcd40dc9f4698edc282a5c70602b42945b98840b1ea3d6b0d620b7726c65c83c16363e1c7542822cc1 SHA512 c36c7c5f309dea87df6af0567929f7fe09656ac49e33fd7edca62522aa45656e53d717dca5a9702b246446f25d7c3249ef0fdae8554f71cedf90339bc8b620eb
 DIST gentoo-kernel-5.4.120-1.arm64.xpak 56380077 BLAKE2B d9d0a98d00b17925c852b75875ba4eb373624cd1fc35df60aa50796e81facb5067146f3008313b5776aae7b251ae6559118cb36f1480813073341dfa37de01ac SHA512 c207f79b59ae38ab58a2f7341c8d21e3fc388eb949417a033d4dfd9fb0a7acdcac4a1d5ce8528708e7a2dfba1b241f0cf03235b5c2fb9dd1c930a36a8bebd2f5

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.15-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.15-r1.ebuild
new file mode 100644
index 00000000000..9cc54d1c175
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.15-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}