[gentoo-commits] repo/gentoo:master commit in: net-analyzer/goaccess/

[Patrice Clement]

commit:     9d8358f52e1923d57e7809ea628f3fa373e1f921
Author:     Vladimir Pavljuchenkov (SpiderX) <spiderx <AT> spiderx <DOT> dp <DOT> ua>
AuthorDate: Sun Dec  2 11:07:00 2018 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Tue Dec  4 22:52:57 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9d8358f5

net-analyzer/goaccess: version bump to 1.3, moved to EAPI 7, live ebuild.

Signed-off-by: Vladimir Pavljuchenkov <spiderx <AT> spiderx.dp.ua>
Package-Manager: Portage-2.3.51, Repoman-2.3.11
Signed-off-by: Patrice Clement <monsieurp <AT> gentoo.org>

 net-analyzer/goaccess/Manifest             |  1 +
 net-analyzer/goaccess/goaccess-1.3.ebuild  | 55 ++++++++++++++++++++++++++++
 net-analyzer/goaccess/goaccess-9999.ebuild | 59 ++++++++++++++++++++++++++++++
 3 files changed, 115 insertions(+)

diff --git a/net-analyzer/goaccess/Manifest b/net-analyzer/goaccess/Manifest
index d0134881f40..39e75605233 100644
--- a/net-analyzer/goaccess/Manifest
+++ b/net-analyzer/goaccess/Manifest
@@ -1 +1,2 @@
 DIST goaccess-1.2.tar.gz 423103 BLAKE2B 87c527a52db9fa69d6e6a02ffbda64a6a32e6214ca6bc1f2654e1451fe5d73e7caa02cf1416c93c511bee329b7885e4914fb7dfd37562ef5347ea3912d030c14 SHA512 bc31ef1e4c92608635856fa73e69b58267c161a7e3c6f2e3ca8860b862ed1c47575b93943dd975a5f8503774ee90ee0649d380563639e30908d876416638f889
+DIST goaccess-1.3.tar.gz 541374 BLAKE2B 55942e35d06f1467df9b80a3fc42211e867b08963a7334783c0279ba7b9e0fd8d6e197277bee780547a9b8f6264ae15844374604f6d7c1b3b57f57768c2b2019 SHA512 7ab8a42670c2009459eee6979cb14e32e7e776e89912077882652631d0ce6ff801fba46d91ab5c23af1229f000e220863e9b70336fcd9fe11521d0ae1fd3bde1

diff --git a/net-analyzer/goaccess/goaccess-1.3.ebuild b/net-analyzer/goaccess/goaccess-1.3.ebuild
new file mode 100644
index 00000000000..a38a46ce6f7
--- /dev/null
+++ b/net-analyzer/goaccess/goaccess-1.3.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="A real-time web log analyzer and interactive viewer that runs in a terminal"
+HOMEPAGE="https://goaccess.io"
+SRC_URI="https://tar.goaccess.io/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux"
+IUSE="btree bzip2 debug geoip geoipv2 getline libressl tokyocabinet ssl unicode zlib"
+REQUIRED_USE="btree? ( tokyocabinet ) bzip2? ( btree ) geoipv2? ( geoip ) zlib? ( btree )"
+
+BDEPEND="virtual/pkgconfig"
+RDEPEND="sys-libs/ncurses:0=[unicode?]
+	geoip? (
+		!geoipv2? ( dev-libs/geoip )
+		geoipv2? ( dev-libs/libmaxminddb:0= )
+	)
+	!tokyocabinet? ( dev-libs/glib:2 )
+	tokyocabinet? (
+		dev-db/tokyocabinet[bzip2?,zlib?]
+		btree? (
+			bzip2? ( app-arch/bzip2 )
+			zlib? ( sys-libs/zlib )
+		)
+	)
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	econf \
+		"$(use_enable bzip2 bzip)" \
+		"$(use_enable zlib)" \
+		"$(use_enable debug)" \
+		"$(use_enable geoip geoip "$(usex geoipv2 mmdb legacy)")" \
+		"$(use_enable tokyocabinet tcb "$(usex btree btree memhash)")" \
+		"$(use_enable unicode utf8)" \
+		"$(use_with getline)" \
+		"$(use_with ssl openssl)"
+}
+
+pkg_preinst() {
+	# Change path to GeoIP bases in config
+	sed -e s':/usr/local:/usr:' -i "${ED%/}"/etc/goaccess/goaccess.conf || die "sed failed for goaccess.conf"
+}
+
+pkg_postinst() {
+	ewarn "Upstream moved config to /etc/goaccess/goaccess.conf"
+}

diff --git a/net-analyzer/goaccess/goaccess-9999.ebuild b/net-analyzer/goaccess/goaccess-9999.ebuild
new file mode 100644
index 00000000000..a5512dc51d4
--- /dev/null
+++ b/net-analyzer/goaccess/goaccess-9999.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGIT_REPO_URI="https://github.com/allinurl/${PN}.git"
+
+inherit autotools git-r3
+
+DESCRIPTION="A real-time web log analyzer and interactive viewer that runs in a terminal"
+HOMEPAGE="https://goaccess.io"
+SRC_URI=""
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS=""
+IUSE="btree bzip2 debug geoip geoipv2 getline libressl tokyocabinet ssl unicode zlib"
+REQUIRED_USE="btree? ( tokyocabinet ) bzip2? ( btree ) geoipv2? ( geoip ) zlib? ( btree )"
+
+BDEPEND="virtual/pkgconfig"
+RDEPEND="sys-libs/ncurses:0=[unicode?]
+	geoip? (
+		!geoipv2? ( dev-libs/geoip )
+		geoipv2? ( dev-libs/libmaxminddb:0= )
+	)
+	!tokyocabinet? ( dev-libs/glib:2 )
+	tokyocabinet? (
+		dev-db/tokyocabinet[bzip2?,zlib?]
+		btree? (
+			bzip2? ( app-arch/bzip2 )
+			zlib? ( sys-libs/zlib )
+		)
+	)
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# Change path to GeoIP bases in config
+	sed -i -e s':/usr/local:/usr:' config/goaccess.conf || die "sed failed for goaccess.conf"
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		"$(use_enable bzip2 bzip)" \
+		"$(use_enable zlib)" \
+		"$(use_enable debug)" \
+		"$(use_enable geoip geoip "$(usex geoipv2 mmdb legacy)")" \
+		"$(use_enable tokyocabinet tcb "$(usex btree btree memhash)")" \
+		"$(use_enable unicode utf8)" \
+		"$(use_with getline)" \
+		"$(use_with ssl openssl)"
+}