[gentoo-commits] gentoo-x86 commit in dev-java/icedtea-web: ChangeLog icedtea-web-1.4.2.ebuild

[Vlastimil Babka (caster)]

caster      14/06/01 20:53:52

  Modified:             ChangeLog
  Added:                icedtea-web-1.4.2.ebuild
  Log:
  Version bump, security bug #501472.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 4E61DE84)

Revision  Changes    Path
1.39                 dev-java/icedtea-web/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea-web/ChangeLog?rev=1.39&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea-web/ChangeLog?rev=1.39&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea-web/ChangeLog?r1=1.38&r2=1.39

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/icedtea-web/ChangeLog,v
retrieving revision 1.38
retrieving revision 1.39
diff -u -r1.38 -r1.39
--- ChangeLog	30 Dec 2013 17:23:46 -0000	1.38
+++ ChangeLog	1 Jun 2014 20:53:52 -0000	1.39
@@ -1,6 +1,11 @@
 # ChangeLog for dev-java/icedtea-web
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/icedtea-web/ChangeLog,v 1.38 2013/12/30 17:23:46 tomwij Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/icedtea-web/ChangeLog,v 1.39 2014/06/01 20:53:52 caster Exp $
+
+*icedtea-web-1.4.2 (01 Jun 2014)
+
+  01 Jun 2014; Vlastimil Babka <caster@g.o> +icedtea-web-1.4.2.ebuild:
+  Version bump, security bug #501472.
 
   30 Dec 2013; Tom Wijsman <TomWij@g.o> -icedtea-web-1.3.1-r7.ebuild,
   -icedtea-web-1.3.1.ebuild, metadata.xml:



1.1                  dev-java/icedtea-web/icedtea-web-1.4.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea-web/icedtea-web-1.4.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/icedtea-web/icedtea-web-1.4.2.ebuild?rev=1.1&content-type=text/plain

Index: icedtea-web-1.4.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/icedtea-web/icedtea-web-1.4.2.ebuild,v 1.1 2014/06/01 20:53:52 caster Exp $
# Build written by Andrew John Hughes (ahughes@××××××.com)

EAPI="5"

inherit autotools eutils readme.gentoo java-pkg-2 java-vm-2

DESCRIPTION="FOSS Java browser plugin and Web Start implementation"
HOMEPAGE="http://icedtea.classpath.org"
SRC_URI="http://icedtea.classpath.org/download/source/${P}.tar.gz"

LICENSE="GPL-2 GPL-2-with-linking-exception LGPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="doc +icedtea7 javascript +nsplugin test"

COMMON_DEP="
	icedtea7? ( || (
		dev-java/icedtea:7 dev-java/icedtea-bin:7
	) )
	!icedtea7? ( || (
		dev-java/icedtea:7 dev-java/icedtea-bin:7
		dev-java/icedtea:6 dev-java/icedtea-bin:6
	) )
	app-admin/eselect-java
	nsplugin? (
		>=dev-libs/glib-2.16
	)"
RDEPEND="${COMMON_DEP}"
# Need system junit 4.8+. Bug #389795
DEPEND="${COMMON_DEP}
	virtual/pkgconfig
	javascript? ( dev-java/rhino:1.6 )
	nsplugin? ( net-misc/npapi-sdk )
	test? (	>=dev-java/junit-4.8:4 )"

# http://mail.openjdk.java.net/pipermail/distro-pkg-dev/2010-December/011221.html
pkg_setup() {
	JAVA_PKG_WANT_BUILD_VM="icedtea-7 icedtea-bin-7"
	if ! use icedtea7; then
		JAVA_PKG_WANT_BUILD_VM="${JAVA_PKG_WANT_BUILD_VM} icedtea-6 icedtea-bin-6"
	fi
	JAVA_PKG_WANT_SOURCE="1.6"
	JAVA_PKG_WANT_TARGET="1.6"

	java-pkg-2_pkg_setup
	java-vm-2_pkg_setup
}

src_prepare() {
	epatch "${FILESDIR}"/0001-Fix-parallel-install.-BGO-440906.patch
	epatch "${FILESDIR}"/0002-Respect-LDFLAGS.patch # bug #356645
	eautoreconf
}

src_configure() {
	local config=(
		# javaws is managed by eselect java-vm and symlinked to by icedtea so
		# move it out of the way and symlink itweb-settings back to bin
		--bindir="${EPREFIX}"/usr/libexec/${PN}
		--with-jdk-home="${JAVA_HOME}"
		$(use_enable doc docs)
		$(use_enable nsplugin plugin)
		$(use_with javascript rhino)
	)

	unset JAVA_HOME JDK_HOME CLASSPATH JAVAC JAVACFLAGS
	econf "${config[@]}"
}

src_compile() {
	default
}

src_install() {
	default

	if use nsplugin; then
		install_mozilla_plugin "/usr/$(get_libdir)/IcedTeaPlugin.so"
	fi

	mkdir -p "${ED}"/usr/bin || die
	dosym /usr/libexec/${PN}/itweb-settings /usr/bin/itweb-settings || die

	# Should we patch system default lookup instead?
	mkdir -p "${ED}"/etc/.java/deployment/ || die
	echo "deployment.jre.dir=/etc/java-config-2/current-icedtea-web-vm" \
		> "${ED}"/etc/.java/deployment/deployment.properties || die

	readme.gentoo_create_doc
}

pkg_postinst() {
	VMHANDLE="icedtea-web@${GENTOO_VM}" java-vm_check-nsplugin
	java_mozilla_clean_
	readme.gentoo_print_elog
}

pkg_prerm() {
	# override the java-vm-2 eclass check for removing a system VM, as it
	# doesn't make sense here.
	:;
}