[gentoo-commits] gentoo-x86 commit in x11-wm/afterstep: ChangeLog afterstep-2.2.9.ebuild

[Bernard Cafarelli (voyageur)]

voyageur    09/11/03 14:49:27

  Modified:             ChangeLog
  Added:                afterstep-2.2.9.ebuild
  Log:
  Version bump with cleanups, fixes bugs #180765 (bump request), #252119 (stripped files), and #265841 (ldconfig run on install)
  (Portage version: 2.2_rc48/cvs/Linux x86_64)

Revision  Changes    Path
1.83                 x11-wm/afterstep/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/afterstep/ChangeLog?rev=1.83&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/afterstep/ChangeLog?rev=1.83&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/afterstep/ChangeLog?r1=1.82&r2=1.83

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/afterstep/ChangeLog,v
retrieving revision 1.82
retrieving revision 1.83
diff -u -r1.82 -r1.83
--- ChangeLog	10 Jul 2009 13:58:19 -0000	1.82
+++ ChangeLog	3 Nov 2009 14:49:26 -0000	1.83
@@ -1,6 +1,13 @@
 # ChangeLog for x11-wm/afterstep
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/afterstep/ChangeLog,v 1.82 2009/07/10 13:58:19 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/afterstep/ChangeLog,v 1.83 2009/11/03 14:49:26 voyageur Exp $
+
+*afterstep-2.2.9 (03 Nov 2009)
+
+  03 Nov 2009; Bernard Cafarelli <voyageur@g.o>
+  +afterstep-2.2.9.ebuild, +files/no-alternatives-2.2.9.patch:
+  Version bump with cleanups, fixes bugs #180765 (bump request), #252119
+  (stripped files), and #265841 (ldconfig run on install)
 
   10 Jul 2009; Samuli Suominen <ssuominen@g.o>
   -files/afterstep-1.8.11-gentoo.diff, -afterstep-2.00.05.ebuild,



1.1                  x11-wm/afterstep/afterstep-2.2.9.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/afterstep/afterstep-2.2.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/afterstep/afterstep-2.2.9.ebuild?rev=1.1&content-type=text/plain

Index: afterstep-2.2.9.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/afterstep/afterstep-2.2.9.ebuild,v 1.1 2009/11/03 14:49:26 voyageur Exp $

EAPI=2
inherit autotools flag-o-matic eutils

DESCRIPTION="AfterStep is a feature rich NeXTish window manager"
HOMEPAGE="http://www.afterstep.org"
SRC_URI="ftp://ftp.afterstep.org/stable/AfterStep-${PV}.tar.bz2"

LICENSE="AFTERSTEP"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="alsa debug dbus gif gtk jpeg mmx nls png svg tiff xinerama"

RDEPEND="media-libs/freetype
	alsa? ( media-libs/alsa-lib )
	dbus? ( sys-apps/dbus )
	jpeg? ( >=media-libs/jpeg-6b )
	gif?  ( >=media-libs/giflib-4.1.0 )
	gtk? ( x11-libs/gtk+:2 )
	png? ( >=media-libs/libpng-1.2.5 )
	svg? ( gnome-base/librsvg:2 )
	tiff? ( >=media-libs/tiff-3.5.7 )
	x11-libs/libICE
	x11-libs/libXext
	x11-libs/libSM
	x11-libs/libXmu
	x11-libs/libXt
	x11-libs/libX11
	x11-libs/libXpm
	x11-libs/libXrender
	xinerama? ( x11-libs/libXinerama )"

DEPEND="${RDEPEND}
	x11-proto/xextproto
	x11-proto/xproto
	xinerama? ( x11-proto/xineramaproto )"

S=${WORKDIR}/AfterStep-${PV}

src_prepare() {
	epatch "${FILESDIR}"/no-alternatives-${PV}.patch

	# Do not strip binaries, bug #252119
	sed -e "/STRIP_BINARIES/s/-s//" -i autoconf/configure.in || die "strip sed failed"
	cd "${S}"/autoconf || die "cd autoconf failed"
	eautoreconf
	cp "${S}"/autoconf/autoconf/config.h.in "${S}"/autoconf || die "cp failed"
	cp "${S}"/autoconf/configure "${S}" || die "cp failed"
}

src_configure() {
	local myconf

	use debug && myconf="--enable-gdb --enable-warn --enable-gprof
		--enable-audit --enable-trace --enable-trace-x"

	#implied intent of debug means you need the frame pointers.
	use debug && filter-flags -fomit-frame-pointer

	# Explanation of configure options
	# ================================
	# --with-helpcommand="xterm -e man" -  Avoid installing xiterm
	# --with-xpm - Contained in xfree
	# --disable-availability - So we can use complete paths for menuitems
	# --enable-ascp - The AfterStep ControlPanel is abandoned
	# LDCONFIG - bug #265841

	LDCONFIG=/bin/true econf \
		$(use_enable alsa) \
		$(use_enable mmx mmx-optimization) \
		$(use_enable nls i18n) \
		$(use_enable xinerama) \
		$(use_with dbus dbus1) \
		$(use_with gif) \
		$(use_with gtk) \
		$(use_with jpeg) \
		$(use_with png) \
		$(use_with tiff) \
		$(use_with svg) \
		--with-helpcommand="xterm -e man" \
		--disable-availability \
		--disable-staticlibs \
		--enable-ascp=no \
		${myconf} || die "configure failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"

	# Create a symlink from MonitorWharf to Wharf
	rm "${D}"/usr/bin/MonitorWharf
	dosym /usr/bin/Wharf /usr/bin/MonitorWharf

	# Handle the documentation
	dodoc ChangeLog INSTALL NEW* README* TEAM UPGRADE
	cp -pPR "${S}"/TODO "${D}"/usr/share/doc/${PF}/
	dodir /usr/share/doc/${PF}/html
	cp -pPR "${S}"/doc/* "${D}"/usr/share/doc/${PF}/html
	rm "${D}"/usr/share/doc/${PF}/html/{Makefile*,afterstepdoc.in}

	insinto /usr/share/xsessions
	newins "${S}"/AfterStep.desktop.final AfterStep.desktop

	# For desktop managers like GDM or KDE
	exeinto /etc/X11/Sessions
	doexe "${FILESDIR}"/afterstep
}