[gentoo-commits] gentoo-x86 commit in net-print/lprng: ChangeLog lprng-3.8.35.ebuild

[Andreas HAttel (dilfridge)]

dilfridge    12/01/31 23:24:13

  Modified:             ChangeLog
  Added:                lprng-3.8.35.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.44/cvs/Linux x86_64)

Revision  Changes    Path
1.59                 net-print/lprng/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/lprng/ChangeLog?rev=1.59&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/lprng/ChangeLog?rev=1.59&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/lprng/ChangeLog?r1=1.58&r2=1.59

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-print/lprng/ChangeLog,v
retrieving revision 1.58
retrieving revision 1.59
diff -u -r1.58 -r1.59
--- ChangeLog	27 Jan 2012 14:33:47 -0000	1.58
+++ ChangeLog	31 Jan 2012 23:24:13 -0000	1.59
@@ -1,6 +1,11 @@
 # ChangeLog for net-print/lprng
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/lprng/ChangeLog,v 1.58 2012/01/27 14:33:47 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/lprng/ChangeLog,v 1.59 2012/01/31 23:24:13 dilfridge Exp $
+
+*lprng-3.8.35 (31 Jan 2012)
+
+  31 Jan 2012; Andreas K. Huettel <dilfridge@g.o> +lprng-3.8.35.ebuild:
+  Version bump
 
   27 Jan 2012; Pawel Hajdan jr <phajdan.jr@g.o> lprng-3.8.28.ebuild:
   Add blocker on net-print/cups, bug #388515 by Martin von Gagern. Also note



1.1                  net-print/lprng/lprng-3.8.35.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/lprng/lprng-3.8.35.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-print/lprng/lprng-3.8.35.ebuild?rev=1.1&content-type=text/plain

Index: lprng-3.8.35.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-print/lprng/lprng-3.8.35.ebuild,v 1.1 2012/01/31 23:24:13 dilfridge Exp $

EAPI=4

inherit eutils flag-o-matic

MY_PN=LPRng
DESCRIPTION="Extended implementation of the Berkeley LPR print spooler"
HOMEPAGE="http://www.lprng.com/"
SRC_URI="ftp://ftp.lprng.com/pub/${MY_PN}/${MY_PN}/${MY_PN}-${PV}.tgz"

LICENSE="|| ( GPL-2 Artistic )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="foomaticdb kerberos nls ssl"

RDEPEND="sys-process/procps
	ssl? ( dev-libs/openssl )
	foomaticdb? ( net-print/foomatic-filters net-print/foomatic-db )
	!net-print/cups"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	kerberos? ( app-crypt/mit-krb5 )"

S=${WORKDIR}/${MY_PN}-${PV}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-3.8.27-certs.diff
	epatch "${FILESDIR}"/${PN}-3.8.28-make.diff
	epatch "${FILESDIR}"/${PN}-3.8.28-krb.diff
}

src_configure() {
	# wont compile with -O3, needs -O2
	replace-flags -O[3-9] -O2

	econf \
		$(use_enable nls) \
		$(use_enable kerberos) \
		$(use_enable ssl) \
		--disable-setuid \
		--disable-werror \
		--with-userid=lp \
		--with-groupid=lp \
		--with-lpd_conf_path=/etc/lprng/lpd.conf \
		--with-lpd_perms_path=/etc/lprng/lpd.perms \
		--libexecdir=/usr/libexec/lprng \
		--sysconfdir=/etc/lprng \
		--disable-strip
}

src_compile() {
	emake -j1
}

src_install() {
	dodir /var/spool/lpd
	diropts -m 700 -o lp -g lp
	dodir /var/spool/lpd/lp

	emake install \
		DESTDIR="${D}" \
		POSTINSTALL="NO" \
		gnulocaledir="${D}"/usr/share/locale

	dodoc CHANGES README VERSION "${FILESDIR}"/printcap lpd.conf lpd.perms
	dohtml HOWTO/*

	insinto /etc/lprng
	doins "${FILESDIR}"/printcap lpd.conf lpd.perms
	dosym /etc/lprng/printcap /etc/printcap
	newinitd "${FILESDIR}"/lprng-init lprng
}

pkg_postinst() {
	einfo "If printing does not work, try 'checkpc'/'checkpc -f'"
}