[gentoo-commits] gentoo-x86 commit in www-client/chromium: metadata.xml ChangeLog chromium-7.0.544.0-r1.ebuild chromium-9999.ebuild

[PaweA Hajdan (phajdan.jr)]

phajdan.jr    10/10/09 14:01:25

  Modified:             metadata.xml ChangeLog chromium-9999.ebuild
  Added:                chromium-7.0.544.0-r1.ebuild
  Log:
  Add optional support for www-plugins/gecko-mediaplayer, as suggested by sandrain in Gentoo Forums.
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.10                 www-client/chromium/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/metadata.xml?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/metadata.xml?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/metadata.xml?r1=1.9&r2=1.10

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/metadata.xml,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- metadata.xml	1 Oct 2010 08:34:59 -0000	1.9
+++ metadata.xml	9 Oct 2010 14:00:14 -0000	1.10
@@ -4,6 +4,8 @@
 	<herd>chromium</herd>
 	<longdescription>Chromium is the open-source web browser project behind Google Chrome</longdescription>
 	<use>
+		<flag name="gecko-mediaplayer">Allow the browser to load
+			<pkg>www-plugins/gecko-mediaplayer</pkg></flag>
 		<flag name="system-sqlite">Use the system-wide <pkg>dev-db/sqlite</pkg>
 			installation with secure-delete enabled</flag>
 	</use>



1.199                www-client/chromium/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.199&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?rev=1.199&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/ChangeLog?r1=1.198&r2=1.199

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v
retrieving revision 1.198
retrieving revision 1.199
diff -u -r1.198 -r1.199
--- ChangeLog	8 Oct 2010 12:11:06 -0000	1.198
+++ ChangeLog	9 Oct 2010 14:00:16 -0000	1.199
@@ -1,6 +1,14 @@
 # ChangeLog for www-client/chromium
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.198 2010/10/08 12:11:06 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/ChangeLog,v 1.199 2010/10/09 14:00:16 phajdan.jr Exp $
+
+*chromium-7.0.544.0-r1 (09 Oct 2010)
+
+  09 Oct 2010; Pawel Hajdan jr <phajdan.jr@g.o>
+  +files/chromium-gecko-mediaplayer-r0.patch, +chromium-7.0.544.0-r1.ebuild,
+  chromium-9999.ebuild, metadata.xml:
+  Add optional support for www-plugins/gecko-mediaplayer, as suggested by
+  sandrain in Gentoo Forums.
 
 *chromium-7.0.517.36 (08 Oct 2010)
 



1.93                 www-client/chromium/chromium-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.93&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?rev=1.93&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-9999.ebuild?r1=1.92&r2=1.93

Index: chromium-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v
retrieving revision 1.92
retrieving revision 1.93
diff -u -r1.92 -r1.93
--- chromium-9999.ebuild	7 Oct 2010 15:20:09 -0000	1.92
+++ chromium-9999.ebuild	9 Oct 2010 14:00:31 -0000	1.93
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.92 2010/10/07 15:20:09 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-9999.ebuild,v 1.93 2010/10/09 14:00:31 phajdan.jr Exp $
 
 EAPI="2"
 
@@ -15,7 +15,7 @@
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS=""
-IUSE="cups gnome gnome-keyring system-sqlite"
+IUSE="cups +gecko-mediaplayer gnome gnome-keyring system-sqlite"
 
 RDEPEND="app-arch/bzip2
 	system-sqlite? (
@@ -49,7 +49,8 @@
 	)
 	x11-apps/xmessage
 	x11-misc/xdg-utils
-	virtual/ttf-fonts"
+	virtual/ttf-fonts
+	gecko-mediaplayer? ( !www-plugins/gecko-mediaplayer[gnome] )"
 
 src_unpack() {
 	subversion_src_unpack
@@ -113,6 +114,9 @@
 	# to be upstreamed.
 	epatch "${FILESDIR}"/${PN}-system-icu-r0.patch
 
+	# Enable optional support for gecko-mediaplayer.
+	epatch "${FILESDIR}"/${PN}-gecko-mediaplayer-r0.patch
+
 	remove_bundled_lib "third_party/bzip2"
 	remove_bundled_lib "third_party/codesighs"
 	remove_bundled_lib "third_party/cros"
@@ -189,6 +193,14 @@
 		myconf+=" -Dv8_use_snapshot=0"
 	fi
 
+	if use gecko-mediaplayer; then
+		# Disable hardcoded blacklist for gecko-mediaplayer.
+		# When www-plugins/gecko-mediaplayer is compiled with USE=gnome, it causes
+		# the browser to hang. We can handle the situation via dependencies,
+		# thus making it possible to use gecko-mediaplayer.
+		append-flags -DGENTOO_CHROMIUM_ENABLE_GECKO_MEDIAPLAYER
+	fi
+
 	# Use target arch detection logic from bug #296917.
 	local myarch="$ABI"
 	[[ $myarch = "" ]] && myarch="$ARCH"



1.1                  www-client/chromium/chromium-7.0.544.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-7.0.544.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/chromium/chromium-7.0.544.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: chromium-7.0.544.0-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/chromium/chromium-7.0.544.0-r1.ebuild,v 1.1 2010/10/09 14:00:27 phajdan.jr Exp $

EAPI="2"

inherit eutils flag-o-matic multilib pax-utils toolchain-funcs

DESCRIPTION="Open-source version of Google Chrome web browser"
HOMEPAGE="http://chromium.org/"
SRC_URI="http://build.chromium.org/buildbot/official/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="cups +gecko-mediaplayer gnome gnome-keyring system-sqlite"

RDEPEND="app-arch/bzip2
	system-sqlite? (
		>=dev-db/sqlite-3.6.23.1[fts3,icu,secure-delete,threadsafe]
	)
	>=dev-libs/icu-4.4.1
	>=dev-libs/libevent-1.4.13
	dev-libs/libxml2
	dev-libs/libxslt
	>=dev-libs/nss-3.12.3
	>=gnome-base/gconf-2.24.0
	gnome-keyring? ( >=gnome-base/gnome-keyring-2.28.2 )
	>=media-libs/alsa-lib-1.0.19
	media-libs/jpeg:0
	media-libs/libpng
	cups? ( >=net-print/cups-1.4.4 )
	sys-libs/zlib
	>=x11-libs/gtk+-2.14.7
	x11-libs/libXScrnSaver"
DEPEND="${RDEPEND}
	dev-lang/perl
	>=dev-util/gperf-3.0.3
	>=dev-util/pkgconfig-0.23
	sys-devel/flex"
RDEPEND+="
	|| (
		x11-themes/gnome-icon-theme
		x11-themes/oxygen-molecule
		x11-themes/tango-icon-theme
		x11-themes/xfce4-icon-theme
	)
	x11-apps/xmessage
	x11-misc/xdg-utils
	virtual/ttf-fonts
	gecko-mediaplayer? ( !www-plugins/gecko-mediaplayer[gnome] )"

remove_bundled_lib() {
	einfo "Removing bundled library $1 ..."
	local out
	out="$(find $1 -mindepth 1 \! -iname '*.gyp' -print -delete)" \
		|| die "failed to remove bundled library $1"
	if [[ -z $out ]]; then
		die "no files matched when removing bundled library $1"
	fi
}

pkg_setup() {
	CHROMIUM_HOME="/usr/$(get_libdir)/chromium-browser"
}

src_prepare() {
	# Small fixes to the system-provided sqlite support,
	# to be upstreamed.
	epatch "${FILESDIR}"/${PN}-system-sqlite-r0.patch

	# Small fix to the system-provided icu support,
	# to be upstreamed.
	epatch "${FILESDIR}"/${PN}-system-icu-r0.patch

	# Enable optional support for gecko-mediaplayer.
	epatch "${FILESDIR}"/${PN}-gecko-mediaplayer-r0.patch

	remove_bundled_lib "third_party/bzip2"
	remove_bundled_lib "third_party/codesighs"
	remove_bundled_lib "third_party/cros"
	remove_bundled_lib "third_party/icu"
	remove_bundled_lib "third_party/jemalloc"
	remove_bundled_lib "third_party/lcov"
	remove_bundled_lib "third_party/libevent"
	remove_bundled_lib "third_party/libjpeg"
	remove_bundled_lib "third_party/libpng"
	remove_bundled_lib "third_party/libxml"
	remove_bundled_lib "third_party/libxslt"
	remove_bundled_lib "third_party/lzma_sdk"
	remove_bundled_lib "third_party/molokocacao"
	remove_bundled_lib "third_party/ocmock"
	remove_bundled_lib "third_party/pyftpdlib"
	remove_bundled_lib "third_party/simplejson"
	remove_bundled_lib "third_party/tlslite"
	# TODO: also remove third_party/zlib. For now the compilation fails if we
	# remove it (minizip-related).

	if use system-sqlite; then
		remove_bundled_lib "third_party/sqlite/src"
		remove_bundled_lib "third_party/sqlite/preprocessed"
	fi
}

src_configure() {
	local myconf=""

	# Never tell the build system to "enable" SSE2, it has a few unexpected
	# additions, bug #336871.
	myconf+=" -Ddisable_sse2=1"

	# Use system-provided libraries.
	# TODO: use_system_ffmpeg (http://crbug.com/50678).
	# TODO: use_system_hunspell (upstream changes needed).
	# TODO: use_system_ssl (need to consult upstream).
	myconf+="
		-Duse_system_bzip2=1
		-Duse_system_icu=1
		-Duse_system_libevent=1
		-Duse_system_libjpeg=1
		-Duse_system_libpng=1
		-Duse_system_libxml=1
		-Duse_system_zlib=1"

	if use system-sqlite; then
		myconf+=" -Duse_system_sqlite=1"
	fi

	# The dependency on cups is optional, see bug #324105.
	if use cups; then
		myconf+=" -Duse_cups=1"
	else
		myconf+=" -Duse_cups=0"
	fi

	if use "gnome-keyring"; then
		myconf+=" -Duse_gnome_keyring=1 -Dlinux_link_gnome_keyring=1"
	else
		# TODO: we should also disable code trying to dlopen
		# gnome-keyring in that case.
		myconf+=" -Duse_gnome_keyring=0 -Dlinux_link_gnome_keyring=0"
	fi

	# Enable sandbox.
	myconf+="
		-Dlinux_sandbox_path=${CHROMIUM_HOME}/chrome_sandbox
		-Dlinux_sandbox_chrome_path=${CHROMIUM_HOME}/chrome"

	if host-is-pax; then
		# Prevent the build from failing (bug #301880). The performance
		# difference is very small.
		myconf+=" -Dv8_use_snapshot=0"
	fi

	if use gecko-mediaplayer; then
		# Disable hardcoded blacklist for gecko-mediaplayer.
		# When www-plugins/gecko-mediaplayer is compiled with USE=gnome, it causes
		# the browser to hang. We can handle the situation via dependencies,
		# thus making it possible to use gecko-mediaplayer.
		append-flags -DGENTOO_CHROMIUM_ENABLE_GECKO_MEDIAPLAYER
	fi

	# Use target arch detection logic from bug #296917.
	local myarch="$ABI"
	[[ $myarch = "" ]] && myarch="$ARCH"

	if [[ $myarch = amd64 ]] ; then
		myconf+=" -Dtarget_arch=x64"
	elif [[ $myarch = x86 ]] ; then
		myconf+=" -Dtarget_arch=ia32"
	elif [[ $myarch = arm ]] ; then
		# TODO: check this again after
		# http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39509 is fixed.
		append-flags -fno-tree-sink

		myconf+=" -Dtarget_arch=arm -Ddisable_nacl=1 -Dlinux_use_tcmalloc=0"
	else
		die "Failed to determine target arch, got '$myarch'."
	fi

	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "44" ]]; then
		myconf+=" -Dno_strict_aliasing=1 -Dgcc_version=44"
	fi

	# Work around a likely GCC bug, see bug #331945.
	if [[ "$(gcc-major-version)$(gcc-minor-version)" == "45" ]]; then
		append-flags -fno-ipa-cp
	fi

	# Make sure that -Werror doesn't get added to CFLAGS by the build system.
	# Depending on GCC version the warnings are different and we don't want
	# the build to fail because of that.
	myconf+=" -Dwerror="

	build/gyp_chromium --depth=. ${myconf} || die
}

src_compile() {
	emake chrome chrome_sandbox BUILDTYPE=Release V=1 || die
}

src_install() {
	exeinto "${CHROMIUM_HOME}"
	pax-mark m out/Release/chrome
	doexe out/Release/chrome
	doexe out/Release/chrome_sandbox || die
	fperms 4755 "${CHROMIUM_HOME}/chrome_sandbox"
	doexe out/Release/xdg-settings || die
	doexe "${FILESDIR}"/chromium-launcher.sh || die

	insinto "${CHROMIUM_HOME}"
	doins out/Release/chrome.pak || die
	doins out/Release/resources.pak || die

	doins -r out/Release/locales || die
	doins -r out/Release/resources || die

	# chrome.1 is for chromium --help
	newman out/Release/chrome.1 chrome.1 || die
	newman out/Release/chrome.1 chromium.1 || die

	doexe out/Release/ffmpegsumo_nolink || die
	doexe out/Release/libffmpegsumo.so || die

	# Install icon and desktop entry.
	newicon out/Release/product_logo_48.png ${PN}-browser.png || die
	dosym "${CHROMIUM_HOME}/chromium-launcher.sh" /usr/bin/chromium || die
	make_desktop_entry chromium "Chromium" ${PN}-browser "Network;WebBrowser" \
		"MimeType=text/html;text/xml;application/xhtml+xml;"
	sed -e "/^Exec/s/$/ %U/" -i "${D}"/usr/share/applications/*.desktop || die

	# Install GNOME default application entry (bug #303100).
	if use gnome; then
		dodir /usr/share/gnome-control-center/default-apps || die
		insinto /usr/share/gnome-control-center/default-apps
		doins "${FILESDIR}"/chromium.xml || die
	fi
}