[gentoo-commits] repo/gentoo:master commit in: net-misc/mosh/

[Amy Liffey]

commit:     ac9879ce8808ad99a75edc3fa67c2740cd2b197d
Author:     Amy Liffey <amynka <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 27 17:38:05 2021 +0000
Commit:     Amy Liffey <amynka <AT> gentoo <DOT> org>
CommitDate: Wed Oct 27 18:59:46 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ac9879ce

net-misc/mosh: eapi bump

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Amy Liffey <amynka <AT> gentoo.org>

 net-misc/mosh/mosh-1.3.2-r1.ebuild | 70 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)

diff --git a/net-misc/mosh/mosh-1.3.2-r1.ebuild b/net-misc/mosh/mosh-1.3.2-r1.ebuild
new file mode 100644
index 00000000000..469c7b1f214
--- /dev/null
+++ b/net-misc/mosh/mosh-1.3.2-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools bash-completion-r1
+
+DESCRIPTION="Mobile shell that supports roaming and intelligent local echo"
+HOMEPAGE="https://mosh.org"
+SRC_URI="https://mosh.org/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="+client examples +mosh-hardening +server ufw +utempter"
+
+REQUIRED_USE="
+	|| ( client server )
+	examples? ( client )"
+
+RDEPEND="
+	dev-libs/protobuf:0=
+	sys-libs/ncurses:0=
+	virtual/ssh
+	client? (
+		dev-lang/perl
+		dev-perl/IO-Tty
+	)
+	dev-libs/openssl:0=
+	utempter? (
+		sys-libs/libutempter
+	)"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+# [0] - avoid sandbox-violation calling git describe in Makefile.
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.2.5-git-version.patch
+)
+
+src_prepare() {
+	MAKEOPTS+=" V=1"
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-completion \
+		$(use_enable client) \
+		$(use_enable server) \
+		$(use_enable examples) \
+		$(use_enable ufw) \
+		$(use_enable mosh-hardening hardening) \
+		$(use_with utempter)
+}
+
+src_install() {
+	default
+
+	for myprog in $(find src/examples -type f -perm /0111) ; do
+		newbin ${myprog} ${PN}-$(basename ${myprog})
+		elog "${myprog} installed as ${PN}-$(basename ${myprog})"
+	done
+
+	# bug 477384
+	dobashcomp conf/bash-completion/completions/mosh
+}