[gentoo-commits] gentoo-x86 commit in net-analyzer/darkstat: ChangeLog darkstat-3.0.713.ebuild

[Peter Volkov (pva)]

pva         10/05/06 08:51:16

  Modified:             ChangeLog
  Added:                darkstat-3.0.713.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.40                 net-analyzer/darkstat/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/darkstat/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/darkstat/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/darkstat/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/darkstat/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	1 Jun 2009 09:49:26 -0000	1.39
+++ ChangeLog	6 May 2010 08:51:16 -0000	1.40
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/darkstat
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/darkstat/ChangeLog,v 1.39 2009/06/01 09:49:26 pva Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/darkstat/ChangeLog,v 1.40 2010/05/06 08:51:16 pva Exp $
+
+*darkstat-3.0.713 (06 May 2010)
+
+  06 May 2010; Peter Volkov <pva@g.o> +darkstat-3.0.713.ebuild:
+  Version bump.
 
   01 Jun 2009; Peter Volkov <pva@g.o> -darkstat-3.0.707-r1.ebuild:
   Remove old.



1.1                  net-analyzer/darkstat/darkstat-3.0.713.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/darkstat/darkstat-3.0.713.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/darkstat/darkstat-3.0.713.ebuild?rev=1.1&content-type=text/plain

Index: darkstat-3.0.713.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/darkstat/darkstat-3.0.713.ebuild,v 1.1 2010/05/06 08:51:16 pva Exp $

EAPI="2"
inherit eutils

DESCRIPTION="darkstat is a network traffic analyzer"
HOMEPAGE="http://dmr.ath.cx/net/darkstat/"
SRC_URI="http://dmr.ath.cx/net/darkstat/${P}.tar.bz2"

KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""
LICENSE="GPL-2"
SLOT="0"

DEPEND="net-libs/libpcap"
RDEPEND="${DEPEND}"

DARKSTAT_CHROOT_DIR=${DARKSTAT_CHROOT_DIR:-/var/lib/darkstat}

src_configure() {
	econf \
		--with-privdrop-user=darkstat \
		--with-chroot-dir="${DARKSTAT_CHROOT_DIR}"
}

src_install() {
	emake DESTDIR="${D}" install || die "installation failed."

	dodoc AUTHORS ChangeLog README NEWS || die

	newinitd "${FILESDIR}"/darkstat-init.new darkstat || die
	newconfd "${FILESDIR}"/darkstat-confd.new darkstat || die

	sed -i -e "s:__CHROOT__:${DARKSTAT_CHROOT_DIR}:g" "${D}"/etc/conf.d/darkstat
	sed -i -e "s:__CHROOT__:${DARKSTAT_CHROOT_DIR}:g" "${D}"/etc/init.d/darkstat

	keepdir "${DARKSTAT_CHROOT_DIR}"
	chown darkstat:0 "${D}${DARKSTAT_CHROOT_DIR}"
}

pkg_preinst() {
	enewuser darkstat
}

pkg_postinst() {
	# Workaround bug #141619
	DARKSTAT_CHROOT_DIR=`sed -n 's/^#CHROOT=\(.*\)/\1/p' "${ROOT}"etc/conf.d/darkstat`
	chown darkstat:0 "${ROOT}${DARKSTAT_CHROOT_DIR}"

	elog "To start different darkstat instances which will listen on a different"
	elog "interfaces create in /etc/init.d directory the 'darkstat.if' symlink to"
	elog "darkstat script where 'if' is the name of the interface."
	elog "Also in /etc/conf.d directory copy darkstat to darkstat.if"
	elog "and edit it to change default values."
	elog
	elog "darkstat's default chroot directory is: \"${ROOT}${DARKSTAT_CHROOT_DIR}\""
}