[gentoo-commits] gentoo-x86 commit in app-text/asciidoc: asciidoc-8.6.8-r1.ebuild asciidoc-9999.ebuild ChangeLog

[Mike Gilbert (floppym)]

floppym     13/02/23 00:44:44

  Modified:             asciidoc-9999.ebuild ChangeLog
  Added:                asciidoc-8.6.8-r1.ebuild
  Log:
  Convert to python-single-r1, bug 458802 by mgorny.
  
  (Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.11                 app-text/asciidoc/asciidoc-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild?r1=1.10&r2=1.11

Index: asciidoc-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- asciidoc-9999.ebuild	27 Dec 2012 19:09:35 -0000	1.10
+++ asciidoc-9999.ebuild	23 Feb 2013 00:44:44 -0000	1.11
@@ -1,14 +1,13 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild,v 1.10 2012/12/27 19:09:35 ottxor Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild,v 1.11 2013/02/23 00:44:44 floppym Exp $
 
-EAPI="3"
+EAPI=5
 
-PYTHON_DEPEND="2:2.5"
-RESTRICT_PYTHON_ABIS="3.*"
+PYTHON_COMPAT=( python{2_5,2_6,2_7} pypy{1_9,2_0} )
 
 [ "$PV" == "9999" ] && inherit mercurial autotools
-inherit python
+inherit python-single-r1
 
 DESCRIPTION="A text document format for writing short documents, articles, books and UNIX man pages"
 HOMEPAGE="http://www.methods.co.nz/asciidoc/"
@@ -29,14 +28,16 @@
 		dev-libs/libxslt
 		graphviz? ( media-gfx/graphviz )
 		app-text/docbook-xml-dtd:4.5
-		highlight? ( || ( dev-python/pygments dev-util/source-highlight ) )
+		highlight? ( || ( dev-python/pygments[${PYTHON_USEDEP}] dev-util/source-highlight ) )
+		${PYTHON_DEPS}
 "
 DEPEND="test? ( dev-util/source-highlight
 			media-sound/lilypond
 			media-gfx/imagemagick
 			dev-texlive/texlive-latex
 			app-text/dvipng
-			media-gfx/graphviz )
+			media-gfx/graphviz
+			${PYTHON_DEPS} )
 "
 
 if [ "$PV" == "9999" ]; then
@@ -46,10 +47,6 @@
 		dev-util/source-highlight"
 fi
 
-pkg_setup() {
-	python_set_active_version 2
-}
-
 src_prepare() {
 	if ! use vim-syntax; then
 		sed -i -e '/^install/s/install-vim//' Makefile.in || die
@@ -75,32 +72,34 @@
 	default
 
 	if [ "$PV" == "9999" ]; then
-		( cd doc && aap -f main.aap ../{CHANGELOG,README,BUGS} )
+		cd doc || die
+		aap -f main.aap ../{CHANGELOG,README,BUGS} || die
 	fi
 }
 
 src_install() {
 	use vim-syntax && dodir /usr/share/vim/vimfiles
 
-	emake DESTDIR="${D}" install || die "install failed"
+	emake DESTDIR="${D}" install
 
-	python_convert_shebangs -r 2 "${D}"
+	python_fix_shebang "${ED}"/usr/bin/*.py
 
 	if use examples; then
 		# This is a symlink to a directory
 		rm examples/website/images || die
 
-		insinto /usr/share/doc/${PF}
-		doins -r examples || die
-		dosym ../../../asciidoc/images /usr/share/doc/${PF}/examples || die
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+		dosym ../../../asciidoc/images /usr/share/doc/${PF}/examples
 	fi
 
 	dodoc BUGS CHANGELOG README docbook-xsl/asciidoc-docbook-xsl.txt \
-			dblatex/dblatex-readme.txt filters/code/code-filter-readme.txt || die
+			dblatex/dblatex-readme.txt filters/code/code-filter-readme.txt
 }
 
 src_test() {
 	cd tests || die
-	ASCIIDOC_PY=../asciidoc.py "$(PYTHON)" test${PN}.py update || die
-	ASCIIDOC_PY=../asciidoc.py "$(PYTHON)" test${PN}.py run || die
+	local -x ASCIIDOC_PY=../asciidoc.py
+	"${PYTHON}" test${PN}.py update || die
+	"${PYTHON}" test${PN}.py run || die
 }



1.86                 app-text/asciidoc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/ChangeLog?rev=1.86&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/ChangeLog?rev=1.86&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/ChangeLog?r1=1.85&r2=1.86

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/asciidoc/ChangeLog,v
retrieving revision 1.85
retrieving revision 1.86
diff -u -r1.85 -r1.86
--- ChangeLog	27 Dec 2012 19:09:35 -0000	1.85
+++ ChangeLog	23 Feb 2013 00:44:44 -0000	1.86
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/asciidoc
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/asciidoc/ChangeLog,v 1.85 2012/12/27 19:09:35 ottxor Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/asciidoc/ChangeLog,v 1.86 2013/02/23 00:44:44 floppym Exp $
+
+*asciidoc-8.6.8-r1 (23 Feb 2013)
+
+  23 Feb 2013; Mike Gilbert <floppym@g.o> +asciidoc-8.6.8-r1.ebuild,
+  asciidoc-9999.ebuild:
+  Convert to python-single-r1, bug 458802 by mgorny.
 
   27 Dec 2012; Christoph Junghans <ottxor@g.o> asciidoc-8.2.6.ebuild,
   asciidoc-8.6.5.ebuild, asciidoc-8.6.7.ebuild, asciidoc-8.6.8.ebuild,



1.1                  app-text/asciidoc/asciidoc-8.6.8-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/asciidoc-8.6.8-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/asciidoc/asciidoc-8.6.8-r1.ebuild?rev=1.1&content-type=text/plain

Index: asciidoc-8.6.8-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/asciidoc/asciidoc-8.6.8-r1.ebuild,v 1.1 2013/02/23 00:44:44 floppym Exp $

EAPI=5

PYTHON_COMPAT=( python{2_5,2_6,2_7} pypy{1_9,2_0} )

[ "$PV" == "9999" ] && inherit mercurial autotools
inherit python-single-r1

DESCRIPTION="A text document format for writing short documents, articles, books and UNIX man pages"
HOMEPAGE="http://www.methods.co.nz/asciidoc/"
if [ "$PV" == "9999" ]; then
	EHG_REPO_URI="https://asciidoc.googlecode.com/hg/"
	SRC_URI=""
	KEYWORDS=""
else
	SRC_URI="mirror://sourceforge/project/${PN}/${PN}/${PV}/${P}.tar.gz"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
fi

LICENSE="GPL-2"
SLOT="0"
IUSE="examples graphviz highlight test vim-syntax"

RDEPEND=">=app-text/docbook-xsl-stylesheets-1.75
		dev-libs/libxslt
		graphviz? ( media-gfx/graphviz )
		app-text/docbook-xml-dtd:4.5
		highlight? ( || ( dev-python/pygments[${PYTHON_USEDEP}] dev-util/source-highlight ) )
		${PYTHON_DEPS}
"
DEPEND="test? ( dev-util/source-highlight
			media-sound/lilypond
			media-gfx/imagemagick
			dev-texlive/texlive-latex
			app-text/dvipng
			media-gfx/graphviz
			${PYTHON_DEPS} )
"

if [ "$PV" == "9999" ]; then
	DEPEND="${DEPEND}
		dev-util/aap
		www-client/lynx
		dev-util/source-highlight"
fi

src_prepare() {
	if ! use vim-syntax; then
		sed -i -e '/^install/s/install-vim//' Makefile.in || die
	else
		sed -i\
			-e "/^vimdir/s:@sysconfdir@/vim:${EPREFIX}/usr/share/vim/vimfiles:" \
			-e 's:/etc/vim::' \
			Makefile.in || die
	fi

	# Only needed for prefix - harmless (does nothing) otherwise
	sed -i -e "s:^CONF_DIR=.*:CONF_DIR='${EPREFIX}/etc/asciidoc':" \
		"${S}/asciidoc.py" || die

	[ "$PV" == "9999" ] && eautoconf
}

src_configure() {
	econf --sysconfdir="${EPREFIX}"/usr/share
}

src_compile() {
	default

	if [ "$PV" == "9999" ]; then
		cd doc || die
		aap -f main.aap ../{CHANGELOG,README,BUGS} || die
	fi
}

src_install() {
	use vim-syntax && dodir /usr/share/vim/vimfiles

	emake DESTDIR="${D}" install

	python_fix_shebang "${ED}"/usr/bin/*.py

	if use examples; then
		# This is a symlink to a directory
		rm examples/website/images || die

		dodoc -r examples
		docompress -x /usr/share/doc/${PF}/examples
		dosym ../../../asciidoc/images /usr/share/doc/${PF}/examples
	fi

	dodoc BUGS CHANGELOG README docbook-xsl/asciidoc-docbook-xsl.txt \
			dblatex/dblatex-readme.txt filters/code/code-filter-readme.txt
}

src_test() {
	cd tests || die
	local -x ASCIIDOC_PY=../asciidoc.py
	"${PYTHON}" test${PN}.py update || die
	"${PYTHON}" test${PN}.py run || die
}