[gentoo-commits] repo/gentoo:master commit in: net-misc/modemmanager/

[Matt Turner]

commit:     b2f5ba9201f774be75f6c3b7ef20ebbe5162dd39
Author:     Craig Andrews <candrews <AT> gentoo <DOT> org>
AuthorDate: Thu Jan  7 17:50:26 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Jan  8 02:33:45 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b2f5ba92

net-misc/modemmanager: 1.14.8 version bump, EAPI=7

Closes: https://bugs.gentoo.org/710400
Signed-off-by: Craig Andrews <candrews <AT> gentoo.org>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 net-misc/modemmanager/Manifest                   |   1 +
 net-misc/modemmanager/modemmanager-1.14.8.ebuild | 130 +++++++++++++++++++++++
 2 files changed, 131 insertions(+)

diff --git a/net-misc/modemmanager/Manifest b/net-misc/modemmanager/Manifest
index d30a9df75e4..0af0f040209 100644
--- a/net-misc/modemmanager/Manifest
+++ b/net-misc/modemmanager/Manifest
@@ -1,2 +1,3 @@
 DIST ModemManager-1.10.0.tar.xz 2201468 BLAKE2B 4a572feba7d62269ed9d6066565e1b7d41db3bece5d450796ee18f43a9a91a886f76dfe0db4887c9ca13643f72f4460c93b3dd2ae7643eb4c37b01905a3ff3c4 SHA512 676b11892b284c2da587895e71903f80ec96978c66eafae5e2d90e5c0f1dae18e50efc68b704c7907f01f208d585f5a8140316cf83e093df3f782c80949c33bc
+DIST ModemManager-1.14.8.tar.xz 2255964 BLAKE2B 8f0e4e4747b3603795b533c41949ef7180922e92b7b26348145e18ffaa38f23cccbcb6662ac912216d33b4aef805c5f7ad10aef8029ffd16eb30b331fc2ca88e SHA512 2457214fecd7d4d9fef291f756ef19973b98a05d07721cd57bdaee704cd6b9e96d27f6741bd8d245a0495f1d338e65db12f19b2d9a8dd6a5cddfb050614381c6
 DIST ModemManager-1.8.2.tar.xz 2088248 BLAKE2B e53ec3dacac2b1d57191de0eba130ea575a40047e5faa1c813543f1ca17164d71a18478ec6c0392adabea94d2455ee510ceceefc16798fec6f26ec834ebbf84c SHA512 fb00ce6f3dc9795468e81ba295ad82e9586add2d7118661ea5f287a99afca97dc3aea64488393792bb1198e7abf2605bbc5ded2517980d67f8819931effdeea5

diff --git a/net-misc/modemmanager/modemmanager-1.14.8.ebuild b/net-misc/modemmanager/modemmanager-1.14.8.ebuild
new file mode 100644
index 00000000000..926d0eeec65
--- /dev/null
+++ b/net-misc/modemmanager/modemmanager-1.14.8.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 readme.gentoo-r1 systemd toolchain-funcs udev vala
+
+DESCRIPTION="Modem and mobile broadband management libraries"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/ModemManager/"
+SRC_URI="https://www.freedesktop.org/software/ModemManager/ModemManager-${PV}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0/1" # subslot = dbus interface version, i.e. N in org.freedesktop.ModemManager${N}
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="elogind +introspection mbim policykit +qmi systemd +udev vala"
+REQUIRED_USE="
+	?? ( elogind systemd )
+	vala? ( introspection )
+"
+
+DEPEND="
+	>=dev-libs/glib-2.48.0:2
+	udev? ( >=dev-libs/libgudev-230:= )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
+	mbim? ( >=net-libs/libmbim-1.24.0 )
+	policykit? ( >=sys-auth/polkit-0.106[introspection] )
+	qmi? ( >=net-libs/libqmi-1.26.0:= )
+	elogind? ( sys-auth/elogind )
+	systemd? ( >=sys-apps/systemd-209 )
+"
+RDEPEND="${DEPEND}
+	policykit? ( acct-group/plugdev )
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+S="${WORKDIR}/ModemManager-${PV}"
+
+src_prepare() {
+	DOC_CONTENTS="
+		If your USB modem shows up only as a storage device when you plug it in,
+		then you should install sys-apps/usb_modeswitch, which will automatically
+		switch it over to USB modem mode whenever you plug it in.\n"
+
+	if use policykit; then
+		DOC_CONTENTS+="\nTo control your modem without needing to enter the root password,
+			add your user account to the 'plugdev' group."
+	fi
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=(
+		--disable-Werror
+		--disable-static
+		--with-dist-version=${PVR}
+		--with-udev-base-dir="$(get_udevdir)"
+		$(use_with udev)
+		$(use_enable introspection)
+		$(use_with mbim)
+		$(use_with policykit polkit)
+		$(use_with systemd systemd-suspend-resume)
+		$(use_with systemd systemd-journal)
+		$(use_with qmi)
+		$(use_enable vala)
+	)
+	if use elogind; then
+		local pkgconfig="$(tc-getPKG_CONFIG)"
+		myconf+=(
+			--with-systemd-suspend-resume
+			LIBSYSTEMD_LOGIN_CFLAGS="$(${pkgconfig} --cflags "libelogind")"
+			LIBSYSTEMD_LOGIN_LIBS="$(${pkgconfig} --libs "libelogind")"
+		)
+	fi
+	gnome2_src_configure "${myconf[@]}"
+}
+
+src_install() {
+	gnome2_src_install
+
+	# Allow users in plugdev group full control over their modem
+	if use policykit; then
+		insinto /usr/share/polkit-1/rules.d/
+		doins "${FILESDIR}"/01-org.freedesktop.ModemManager1.rules
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	# The polkit rules file moved to /usr/share
+	old_rules="${EROOT}/etc/polkit-1/rules.d/01-org.freedesktop.ModemManager.rules"
+	if [[ -f "${old_rules}" ]]; then
+		case "$(md5sum ${old_rules})" in
+		  c5ff02532cb1da2c7545c3069e5d0992* | 5c50f0dc603c0a56e2851a5ce9389335* )
+			# Automatically delete the old rules.d file if the user did not change it
+			elog
+			elog "Removing old ${old_rules} ..."
+			rm -f "${old_rules}" || eerror "Failed, please remove ${old_rules} manually"
+			;;
+		  * )
+			elog "The ${old_rules}"
+			elog "file moved to /usr/share/polkit-1/rules.d/ in >=modemmanager-0.5.2.0-r2"
+			elog "If you edited ${old_rules}"
+			elog "without changing its behavior, you may want to remove it."
+			;;
+		esac
+	fi
+
+	if ! use udev; then
+		ewarn "You have built ModemManager without udev support. You may have to teach it"
+		ewarn "about your modem port manually."
+	fi
+
+	systemd_reenable ModemManager.service
+
+	readme.gentoo_print_elog
+}